Texturing one side at a time?

Blitz3D Forums/Blitz3D Beginners Area/Texturing one side at a time?

Polarix

(Posted 2016) [#1]

is this possible? thanks

RemiD

(Posted 2016) [#2]

Texturing what ?

Polarix

(Posted 2016) [#3]

say i am making something like a building, i don't want the roof to look like the walls

RemiD

(Posted 2016) [#4]

Ok.
The usual way is to unwrap/uvmap different parts (groups of triangles) of your mesh so that some parts will be colored with some colors of the texture.

You will have to learn about unwrapping/uvmapping...

You can also do the same thing in code if you don't need complex shapes for your buildings. (See vertextexcoords http://www.blitzbasic.com/b3ddocs/command.php?name=VertexTexCoords )

Polarix

(Posted 2016) [#5]

is there anyway to do this in code?

RemiD

(Posted 2016) [#6]

Yes, i just gave you the necessary function.

You can also do it this way if you build the mesh in code :
AddVertex(Surface,x,y,z,u,v)
or
VI% = AddVertex(Surface,x,y,z)
VertexTexCoords(Surface,VI,u,v)

Bobysait

(Posted 2016) [#7]

Or the easy way :
Create a different surface for the roof, with a second material using a second texture.

At least you'll be able to "tile" the texture which is not possible with texture atlas (or, you'd need to create a quad for each tile, which is both boring to do and not accurate at all)

Theory is simple :

tex1 = LoadTexture("wall tex file.jpg/png/etc..")
tex2 = LoadTexture("roof tex file.jpg/png/etc..")
brush1 = CreateBrush()
Brushtexture brush1, tex1
brush2 = CreateBrush()
Brushtexture brush2, tex2
mesh = CreateMesh()
surf1 = CreateSurface(mesh, brush1)
;Add the vertices and triangle for the walls on this surface
surf2 = CreateSurface(mesh, brush2)
;Add the vertices and triangle for the roof on this surface

Main difference is : You don't texture the entity (or the mesh), you texture a material that you apply directly on the surface.

Bobysait

(Posted 2016) [#8]

Graphics3D 800,600,0,2
SetBuffer BackBuffer()

Local cam = CreateCamera()
	MoveEntity cam, 0,0,-20
Local light = CreateLight(3, cam)

Local TexWall = CreateTexture(32,32)
	SetBuffer TextureBuffer (TexWall)
		Color 100,090,030 : Rect 0,0,32,32, 1 ; concrete background
		Color 070,015,005 : Rect 0,0,20,14, 0 : Rect 22,0,10,14,0 : Rect 0,17,10,14, 0 : Rect 12,17,20,14, 0 ; bricks shadow
		Color 090,030,010 : Rect 0,1,19,12, 1 : Rect 23,1, 9,12,1 : Rect 0,18, 9,12, 1 : Rect 13,18,19,12, 1 ; bricks
		Color 160,090,040 : Rect 0,0,20, 1, 1 : Rect 22,0,10, 1,1 : Rect 0,17,10, 1, 1 : Rect 12,17,20, 1, 1 ; bircks highlight
		; some random noise
		For i = 0 To Sqr( 2 * TextureWidth(TexWall)*TextureHeight(TexWall) )
			c = Rand(-5,5)
			Color 70+c,20+c,6+c
			Plot Rand(0,TextureWidth(TexWall)-1), Rand(0,TextureHeight(TexWall)-1)
		Next
	SetBuffer BackBuffer()
	
Local TexRoof = CreateTexture(128,128)
	SetBuffer TextureBuffer (TexRoof)
		Color 150,140,100 : Rect 0,0,TextureWidth(TexRoof),TextureHeight(TexRoof),1 ; background concrete
		; some noise
		For i = 0 To Sqr( 8 * TextureWidth(TexRoof)*TextureHeight(TexRoof) )
			c = Rand(-20,20)
			Local x = Rand(0,TextureWidth(TexRoof)-1), y = Rand(0,TextureHeight(TexRoof)-1)
			Color 130+c,120+c,90+c : Plot x,y
			Color 130+20,120+15,90+10 : Plot x,y-1
			Color 130-20,120-20,90-20 : Plot x,y+1
			Color 130-10,120-5,90 : Plot x-1,y : Plot x+1,y
		Next
	SetBuffer BackBuffer()
	
	ScaleTexture TexWall, .1,.1
	ScaleTexture TexRoof, .5,.5

Local brushWall = CreateBrush() : BrushTexture brushWall, TexWall
Local brushRoof = CreateBrush() : BrushTexture brushRoof, TexRoof

Local Mesh = CreateMesh()
Local surfWall = CreateSurface(Mesh, brushWall)
	AddVertex surfWall, -10,6,-5,  0,6 : VertexNormal surfWall, 0, 0,0,-1
	AddVertex surfWall, +10,6,-5, 20,6 : VertexNormal surfWall, 1, 0,0,-1
	AddVertex surfWall, +10,0,-5, 20,0 : VertexNormal surfWall, 2, 0,0,-1
	AddVertex surfWall, -10,0,-5,  0,0 : VertexNormal surfWall, 3, 0,0,-1
	AddTriangle surfWall, 0,1,2
	AddTriangle surfWall, 0,2,3
	
Local surfConcrete = CreateSurface(Mesh, brushRoof)
	
	; 0 *--------------------------------------* 1
	;   | +  +   +   +     +     +    +     +  |  <- Top Line
	;   |    4  +  +      +  +      +     7    |
	; 3 *----*----------------------------*----* 2
	;   | + +|                            |   +|
	;   |  + |                            | +  |
	;   |+  +|                            |  + |
	;   | + +|                            |+   |
	;   *----*----------------------------*----* 
	;   6    5                            9    8
	;     ^                                 ^
	;     |                                 |
	;     .. . . . . . . . . . . . . . . . ..
	;                   Borders
	
	; top line
	AddVertex surfConcrete, -11,7,-5,  0,7 : VertexNormal surfConcrete, 0, 0,0,-1
	AddVertex surfConcrete, +11,7,-5, 22,7 : VertexNormal surfConcrete, 1, 0,0,-1
	AddVertex surfConcrete, +11,6,-5, 22,6 : VertexNormal surfConcrete, 2, 0,0,-1
	AddVertex surfConcrete, -11,6,-5,  0,6 : VertexNormal surfConcrete, 3, 0,0,-1
	AddTriangle surfConcrete, 0,1,2
	AddTriangle surfConcrete, 0,2,3
	; borders
	AddVertex surfConcrete, -10,6,-5, 1,7 : VertexNormal surfConcrete, 4, 0,0,-1
	AddVertex surfConcrete, -10,0,-5, 1,0 : VertexNormal surfConcrete, 5, 0,0,-1
	AddVertex surfConcrete, -11,0,-5, 0,0 : VertexNormal surfConcrete, 6, 0,0,-1
	AddTriangle surfConcrete, 3,4,5
	AddTriangle surfConcrete, 3,5,6
	AddVertex surfConcrete,  10,6,-5, 21,7 : VertexNormal surfConcrete, 7, 0,0,-1
	AddVertex surfConcrete,  11,0,-5, 22,0 : VertexNormal surfConcrete, 8, 0,0,-1
	AddVertex surfConcrete,  10,0,-5, 21,0 : VertexNormal surfConcrete, 9, 0,0,-1
	AddTriangle surfConcrete, 7,2,8
	AddTriangle surfConcrete, 7,8,9

RenderWorld()
Flip True
WaitKey()
End

Blitzplotter

(Posted 2016) [#9]

Ultimate Unwrap3D is a good tool for doing it via an IDE.

Dan	(Posted 2016) [#10]

bobysait, there is an error in your code:

AddVertex surfBorderGraphics3D 800,600,0,2
SetBuffer BackBuffer()

Bobysait

(Posted 2016) [#11]

Weird, part of the code has been copy/paste overriding itself
code updated (I hope).

Dan	(Posted 2016) [#12]

Thanks, it is working now :)