Adjust animationspeed in realtime?

Blitz3D Forums/Blitz3D Beginners Area/Adjust animationspeed in realtime?

AJirenius

(Posted 2006) [#1]

Are there any ways to actually alter the animationspeed while the animation is playing without restarting the animationsequence?
I got a thing spinning around on my mesh (animated with the mesh) and it will sping around the mesh faster sometimes without the program restarting the animationsequence.

stayne

(Posted 2006) [#2]

Global animspeed# = 1.0

If Not Animating (model)
Animate model,1,animspeed#,1
End If

Alter the speed whenever you need to?

AJirenius

(Posted 2006) [#3]

No, not what I was looking for. I need to alter the speed meanwhile its already animating in a loop.
I cannot call Animate again because the sequence will then start over from frame 0 so I wonder if there are any other way to alter the animation speed meanwhile the animation is already playing.

Pongo

(Posted 2006) [#4]

I use SetAnimTime instead. That way you need to track the progress of the animation, but it works great for this.

Edit: see code posted below for example of how to use SetAnimTime to adjust an animation speed on the fly.

stayne

(Posted 2006) [#5]

You don't have to call Animate again. Just alter animspeed# and it should pick it up? Maybe not, I'm not able to test it at the moment.

Pongo

(Posted 2006) [#6]

here is some code I didn't have time to post earlier.

You will need to replace your own animated mesh in the code to make this run.

; Control animation speed on the fly

Graphics3D 800, 600, 0, 2
SetBuffer BackBuffer()

master=CreatePivot()

; replace your own animated mesh here
playermesh=LoadAnimMesh( "gfx/btb_pedal01.b3d",master)

Global frame#=0
Global frameinc#=1

light=CreateLight(2)
PositionEntity light,200,500,0

cam = CreateCamera()
PositionEntity cam, 0, 150, -300

;PointEntity cam,playermesh

SetBuffer BackBuffer()

While Not KeyHit(1)
	
	;rotate mesh with mouse
	TurnEntity master,0,MouseXSpeed(),0
		
	;Adjust animation playback based on arrow keys	
	If KeyDown(200) Then frameinc=frameinc+.01	;up arrow
	If KeyDown(208) Then frameinc=frameinc-.01	;down arrow
	frame=frame+frameinc	
	
	SetAnimTime playermesh,frame

	UpdateWorld 
	RenderWorld
	
	Text 50,50,"Arrow up/down to change speed"
	Text 50,64,"animspeed=" + frameinc
	
	Flip 

Wend

End

Ice9	(Posted 2006) [#7]

UpdateWorld DeltaTime#

Matty

(Posted 2006) [#8]

Ice9 - that will affect all entities animation which is not what I think he is after.

Pongo is correct - you will need to use SetAnimTime. It gives you far more control over animations in any case but there is a little more work involved.

AJirenius

(Posted 2006) [#9]

Thank you very much y'all!
Especially you, pongo. I don't understand how the brain is functioning. I was looking for exactly such a command in the helpdocuments, ESPECIALLY in the Animationcategory but still I couldn't see it even if it was right there...

Anyway thanks a lot!!!

jhocking

(Posted 2006) [#10]

I was gonna point out the animation speed parameter for UpdateWorld, but ice beat me to it.

SetAnimTime is so cool for stuff like scrubbing back and forth in an animation. I'm so glad Mark implemented that a couple years ago when I bunch of us requested that.