3d running and jumping code almost finished

Blitz3D Forums/Blitz3D Beginners Area/3d running and jumping code almost finished

fox95871

(Posted 2009) [#1]

I managed to put together a pretty good walking jump, then I got it to work in 8 directions, then I got it to have a fixed path so you can't move unrealistically in midair. But now I'm stuck on getting all that to work on both walking and running jumps. Crazy stuff happens when you try to do that!

;setup
Graphics3D 640,480,32,1
SetBuffer BackBuffer()
SeedRnd MilliSecs()
Const fps=30
blitz=LoadFont("blitz",10,1,0,0)
SetFont blitz
Color 100,100,100
ClearTextureFilters
period=1000/fps
time=MilliSecs()-period
elapsed%=0
ticks%=0
tween#=0
rt%=0

;character variables
Global characterposition#=0
Global characterheight#=6
Global characterdistance#=-5
Global facing$="right"
Global facing2$=""
Global walking$=""
Global walking2$=""
Global running$=""
Global running2$=""
Global positionspeed#=0
Global heightspeed#=0
Global distancespeed#=0

;collision variables
Global charactercollider%=1
Global levelcollider%=2
Global collisionmethod%=2
;1=sphere
;2=mesh
;3=box
Global collisionresponse%=3
;1=stick
;2=slide
;3=slide but not down 

;camera creation
Global camera=CreateCamera()
CameraZoom camera,1.6
RotateEntity camera,10,0,0
PositionEntity camera,0,10,-25
CameraClsColor camera,0,0,0

;light creation
Global light=CreateLight(1)
RotateEntity light,40,-70,0

;level creation
;/ground
Global ground=CreateCube()
EntityColor ground,90,80,50
EntityType ground,levelcollider
ScaleMesh ground,20,1,20
NameEntity ground,"ground"
;/hill on the left
Global hill=CreateCube()
ScaleMesh hill,10,10,5
RotateMesh hill,-1,0,30
PositionMesh hill,-8,-4,-2
AddMesh hill,ground
FreeEntity hill
;/base of thing on the right
Global platformbottom=CreateCone(8)
ScaleMesh platformbottom,7,100,7
RotateMesh platformbottom,180,0,0
PositionMesh platformbottom,7,-95,0
EntityType platformbottom,levelcollider
AddMesh platformbottom,ground
FreeEntity platformbottom
;/top of thing on the right
Global platformtop=CreateCone(8)
ScaleMesh platformtop,7,2,7
PositionMesh platformtop,7,7,0
EntityType platformtop,levelcollider
AddMesh platformtop,ground
FreeEntity platformtop

;character creation
;/character
Global character=CreateCube()
EntityType character,charactercollider
EntityRadius character,.05,2
EntityColor character,30,40,70
ScaleEntity character,1,1.5,1
arrow=CreateCone()
ScaleMesh arrow,.5,.5,.5
RotateMesh arrow,90,0,0
PositionMesh arrow,0,0,2
AddMesh arrow,character
FreeEntity arrow
EntityAlpha character,0
;/eight meshes facing different ways
Global characterup=CopyEntity(character,character)
Global characterupright=CopyEntity(character,character)
RotateEntity characterupright,0,-45,0
Global characterright=CopyEntity(character,character)
RotateEntity characterright,0,-90,0
Global characterdownright=CopyEntity(character,character)
RotateEntity characterdownright,0,-135,0
Global characterdown=CopyEntity(character,character)
RotateEntity characterdown,0,-180,0
Global characterdownleft=CopyEntity(character,character)
RotateEntity characterdownleft,0,-225,0
Global characterleft=CopyEntity(character,character)
RotateEntity characterleft,0,-270,0
Global characterupleft=CopyEntity(character,character)
RotateEntity characterupleft,0,-315,0
PositionEntity character,characterposition,characterheight,characterdistance
;/initial facing, based on facing$ in character variables
If facing="up"        EntityAlpha characterup,       1
If facing="upright"   EntityAlpha characterupright,  1
If facing="right"     EntityAlpha characterright,    1
If facing="downright" EntityAlpha characterdownright,1
If facing="down"      EntityAlpha characterdown,     1
If facing="downleft"  EntityAlpha characterdownleft, 1
If facing="left"      EntityAlpha characterleft,     1
If facing="upleft"    EntityAlpha characterupleft,   1

;collision setup
Collisions charactercollider,levelcollider,collisionmethod,collisionresponse

;moving variables
Global runstate$=""

;jumping variables
Global ascentspeed#=0

;timer variables
Global timenow=0
Global starttime=0
Global timerstate$=""

While Not KeyHit(1)
Cls
Repeat
elapsed=MilliSecs()-time
Until elapsed
ticks=elapsed/period
tween#=Float(elapsed Mod period)/Float(period)
For rt=1 To ticks
time=time+period
If rt=ticks Then CaptureWorld

;blitz3d functions
RunCheck()
JumpControl()
FacingAndMovingControlActivator()
FacingEffects()
WalkingEffects()
RunningEffects()
Gravity()

UpdateWorld
Next
RenderWorld tween

;blitz2d functions
DebugText()

Flip
Wend
End

;make a record of if run is being held down or not
Function RunCheck()
If KeyDown(203)
runstate="on"
Else
runstate="off"
EndIf
End Function

;trying to delineate WalkingJump() from RunningJump() somehow < - HELP NEEDED HERE MAYBE
Function JumpControl()
If runstate="off" WalkingJump()
If runstate="om"  RunningJump()
End Function

;walking jump code, working fine
Function WalkingJump()
;if you're on the ground and press jump, start a timer
If EntityCollided(character,levelcollider)>0 And KeyHit(205)  
timerstate="jumpstarted"
starttime=RSet(MilliSecs(),4)
;prevent accidental flight
If starttime>9850 And starttime<9999
starttime=9850
EndIf
EndIf
;for the short time the timer's running, rise a lot
If timerstate="jumpstarted"
timenow=RSet(MilliSecs(),4)
ascentspeed=1
EndIf
;gradually decrease height whenever you're off the ground
If EntityCollided(character,levelcollider)=0
For x = 1 To 20
ascentspeed=ascentspeed-.005
Next
;when the timer stops, no longer rise, letting the above For/Next play out
;til you touch the ground
ElseIf timerstate="stopped"
ascentspeed=0
EndIf
;carry out all the above graphically
heightspeed=ascentspeed
TranslateEntity character,positionspeed,heightspeed,distancespeed
;setting for the timer
If timenow>starttime+100
timerstate="stopped"
EndIf
End Function

;running jump code, not working right
Function RunningJump()
;if you're on the ground and press jump, start a timer
If EntityCollided(character,levelcollider)>0 And KeyHit(205)  
timerstate="jumpstarted"
starttime=RSet(MilliSecs(),4)
;prevent accidental flight
If starttime>9850 And starttime<9999
starttime=9850
EndIf
EndIf
;for the short time the timer's running, rise a lot
If timerstate="jumpstarted"
timenow=RSet(MilliSecs(),4)
ascentspeed=2
EndIf
;gradually decrease height whenever you're off the ground
If EntityCollided(character,levelcollider)=0
For x = 1 To 20
ascentspeed=ascentspeed-.005
Next
;when the timer stops, no longer rise, letting the above For/Next play out
;til you touch the ground
ElseIf timerstate="stopped"
ascentspeed=0
EndIf
;carry out all the above graphically
heightspeed=ascentspeed
TranslateEntity character,positionspeed,heightspeed,distancespeed
;setting for the timer
If timenow>starttime+100
timerstate="stopped"
EndIf
End Function

;removes control while midair. I got this totally by luck. Never knock
;the power of trial and error!
Function FacingAndMovingControlActivator()
If EntityCollided(character,levelcollider)>0
FacingAndMovingControl()
EndIf
End Function

;nate the great's code. This has been a good foundation for just about
;everything
Function FacingAndMovingControl()
;/walking
If     KeyDown(200):facing="up"    :walking= "up"
ElseIf KeyDown(208):facing="down"  :walking= "down"
Else               :facing=""      :walking= ""     :running=""
EndIf
If KeyDown(45)     :facing2="right":walking2="right"
ElseIf KeyDown(44) :facing2="left" :walking2="left"
Else               :facing2=""     :walking2=""     :running2=""
EndIf
;/running
If     KeyDown(200) And KeyDown(203):facing= "up"   :running= "up"    :walking=""
ElseIf KeyDown(208) And KeyDown(203):facing= "down" :running= "down"  :walking=""
Else                                                 running=""
EndIf
If     KeyDown(45)  And KeyDown(203):facing2="right":running2="right" :walking2=""
ElseIf KeyDown(44)  And KeyDown(203):facing2="left" :running2="left"  :walking2=""
Else                                                 running2=""
EndIf
;/prevariables 
walking=walking$+walking2$
running=running$+running2$
facing=facing$+facing2$
End Function

;move the character at normal speed
Function WalkingEffects()
Select walking
Case "up":distancespeed=+.2:positionspeed=0
Case "upright":distancespeed=+.2:positionspeed=+.2
Case "right":positionspeed=+.2:distancespeed=0
Case "downright":distancespeed=-.2:positionspeed=+.2
Case "down":distancespeed=-.2:positionspeed=0
Case "downleft":distancespeed=-.2:positionspeed=-.2
Case "left":positionspeed=-.2:distancespeed=0
Case "upleft":distancespeed=+.2:positionspeed=-.2
Case "":positionspeed=0:heightspeed=0:distancespeed=0
End Select
TranslateEntity character,positionspeed,heightspeed,distancespeed
End Function

;move the character a little faster if run is being held
Function RunningEffects()
Select running
Case "up":distancespeed=+.4:positionspeed=0
Case "upright":distancespeed=+.4:positionspeed=+.4
Case "right":positionspeed=+.4:distancespeed=0
Case "downright":distancespeed=-.4:positionspeed=+.4
Case "down":distancespeed=-.4:positionspeed=0
Case "downleft":distancespeed=-.4:positionspeed=-.4
Case "left":positionspeed=-.4:distancespeed=0
Case "upleft":distancespeed=+.4:positionspeed=-.4
Case "":positionspeed=0:heightspeed=0:distancespeed=0
End Select
TranslateEntity character,positionspeed,heightspeed,distancespeed
End Function

;hide 7 meshes and show 1 depending on the direction chosen. all other
;methods just rotate a mesh, causing visible midpoint frames
Function FacingEffects()
Select facing
Case "up"
EntityAlpha characterup,       1
EntityAlpha characterupright,  0
EntityAlpha characterright,    0
EntityAlpha characterdownright,0
EntityAlpha characterdown     ,0
EntityAlpha characterdownleft ,0
EntityAlpha characterleft     ,0
EntityAlpha characterupleft   ,0
Case "upright"
EntityAlpha characterupright,  1
EntityAlpha characterup,       0
EntityAlpha characterright,    0
EntityAlpha characterdownright,0
EntityAlpha characterdown     ,0
EntityAlpha characterdownleft ,0
EntityAlpha characterleft     ,0
EntityAlpha characterupleft   ,0
Case "right"
EntityAlpha characterright,    1
EntityAlpha characterup,       0
EntityAlpha characterupright,  0
EntityAlpha characterdownright,0
EntityAlpha characterdown     ,0
EntityAlpha characterdownleft ,0
EntityAlpha characterleft     ,0
EntityAlpha characterupleft   ,0
Case "downright"
EntityAlpha characterdownright,1
EntityAlpha characterup,       0
EntityAlpha characterupright,  0
EntityAlpha characterright,    0
EntityAlpha characterdown     ,0
EntityAlpha characterdownleft ,0
EntityAlpha characterleft     ,0
EntityAlpha characterupleft   ,0
Case "down"
EntityAlpha characterdown     ,1
EntityAlpha characterup,       0
EntityAlpha characterupright,  0
EntityAlpha characterright,    0
EntityAlpha characterdownright,0
EntityAlpha characterdownleft ,0
EntityAlpha characterleft     ,0
EntityAlpha characterupleft   ,0
Case "downleft"
EntityAlpha characterdownleft ,1
EntityAlpha characterup,       0
EntityAlpha characterupright,  0
EntityAlpha characterright,    0
EntityAlpha characterdownright,0
EntityAlpha characterdown     ,0
EntityAlpha characterleft     ,0
EntityAlpha characterupleft   ,0
Case "left"
EntityAlpha characterleft     ,1
EntityAlpha characterup,       0
EntityAlpha characterupright,  0
EntityAlpha characterright,    0
EntityAlpha characterdownright,0
EntityAlpha characterdown     ,0
EntityAlpha characterdownleft ,0
EntityAlpha characterupleft   ,0
Case "upleft"
EntityAlpha characterupleft   ,1
EntityAlpha characterup,       0
EntityAlpha characterupright,  0
EntityAlpha characterright,    0
EntityAlpha characterdownright,0
EntityAlpha characterdown     ,0
EntityAlpha characterdownleft ,0
EntityAlpha characterleft     ,0
End Select
End Function

;nothing too fancy. mostly this is just to prevent the "on the ground/not on the ground"
;flicker bug
Function Gravity()
TranslateEntity character,0,-1,0
End Function

;your basic mental breakdown saving readouts
Function DebugText()
Text 0,00,"Controls: up down z x, left and right 
Text 0,30,"facing " +facing
Text 0,45,"walking " +walking
Text 0,60,"running " +running
Text 0,75,"positionspeed " +positionspeed
Text 0,90,"distancespeed " +distancespeed
Text 0,105,"ascentspeed " +ascentspeed
Text 0,120,"runstate " +runstate
If     EntityCollided(character,levelcollider)=0
Text 0,135,"Player1 is not on the ground"
ElseIf EntityCollided(character,levelcollider)>0
Text 0,135,"Player1 is on the "+EntityName(EntityCollided(character,levelcollider))
EndIf
Text 0,150,"timerstate " +timerstate
Text 0,165,"millisecs " +RSet(MilliSecs(),4)
Text 0,180,"timenow   " +timenow
Text 0,195,"starttime " +starttime
End Function
















;

I really tried this time to do as much of the work as I could before posting, but now I don't know what to do. Please help if you can. I thought I'd never get around to this part of my engine, and now it's almost done!

GIB3D

(Posted 2009) [#2]

Hey I'll try to help you with this. I have to change the code that I have so it's all one file but hey, RossC helped me with jump code, so I'll help you. The jumping code I have came from RossC and it's pretty simple. Just wait a lil bit and I'll smack it up on here soon.

Hehe it's gettin me all gitty tryin to figure out which project I should extract the jumping code from.

Edit: Ok here it is, it didn't take long. I tried making a sort of FPS engine which didn't go very far, but I have jumping! Just look at the UpdatePlayers function and try to understand how the status is set up, copy it all if you want to.

Global Graphics_Set%=0
Global Gravity# = .4
Local Timer = CreateTimer(60)

Set3DGraphics(1024,768,32,0)

;Collision Setup
Global MaxCol = MaxCollisions(3)
Dim Col(MaxCol)
CollisionSetup()

SceneSetup()

Global MenuBackground,QuitButton
LoadMenuItems()
Graphics_Set = 1

Global Mine.Player = CreatePlayer(1, 0,20,-20, 0,0,0, Float(Input("Choose Player Width = ")),Float(Input("Choose Player Height = ")),Float(Input("Choose Player Depth = ")))

While Not KeyDown(1)

If KeyHit(21) MainMenu(1)
If KeyHit(22) MainMenu(0)

WaitTimer(Timer)

	If Graphics_Set = 1
		PlayerControls(Mine,KeyDown(17),KeyDown(31),KeyDown(30),KeyDown(32),KeyDown(57),KeyDown(18) ,KeyDown(20))
		
		UpdatePlayers()
		
		DrawWorld()
		Color 255,255,255
		
		;Text 0,0,"X Velocity "+Mine\X_Velo
		;Text 0,20,"Y Velocity "+Mine\Y_Velo
		;Text 0,40,"Z Velocity "+Mine\Z_Velo
		
		;Text 0,70,"X Momentum "+Mine\X_Mome
		;Text 0,90,"Y Momentum "+Mine\Y_Mome
		;Text 0,110,"Z Momentum "+Mine\Z_Mome
		
		;Text 0,150,"Radius " + Mine\Radius
		
		;Text 0,170,"Jump Angle " + Mine\Jump_Angle
		
		;TFormPoint 0,0,.1,Mine\Pivot,0
		;Text 0,200,"TFormedX " + TFormedX()
		;Text 0,220,"TFormedY " + TFormedY()
		;Text 0,240,"TFormedZ " + TFormedZ()	
		
		;Text 0,270,"GroundAirStatus " + Mine\GroundAirStatus
		;Text 0,290,"Colliding " + CountCollisions(Mine\Pivot)
		
		;Text 0,340,"Speed " + Mine\Speed
		
		;Select Mine\A_SuperJump
		;	Case True
		;		Text 0,370,"Press R to toggle super jumping = On"
		;	Case False
		;		Text 0,370,"Press R to toggle super jumping = Off"
		;End Select
		
		
		
		Flip
	EndIf

Wend
End

Function DrawWorld()
	UpdateWorld
	RenderWorld
End Function

Function Set3DGraphics(width%=800,height%=600,depth%=0,mode%=2)
	Graphics_Set = 0
		Graphics3D width,height,depth,mode
		SetBuffer BackBuffer()
	Graphics_Set = 1
End Function

Function MaxCollisions(number%)
	Return number
End Function

Function CollisionSetup()
	For mc = 2 To MaxCol
		Col(mc) = mc
		Col(1) = 1
		Collisions Col(1),Col(mc),2,2
	Next
End Function

Function CenterCursor()
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
End Function

Function FlushInput()
	FlushKeys
	FlushMouse
End Function

Function SceneSetup()
;Lighting
SceneLight = CreateLight()
	
		groundtexture=CreateTexture(32,32,1+8)
		
		SetBuffer TextureBuffer(groundtexture)
		
		Color 80,80,80
		Rect 0,0,32,32,1
		
		Color 100,100,100
		Rect 0,0,32,32,0
		
		ScaleTexture groundtexture,2,2
		
		SetBuffer BackBuffer()
		Color 255,255,255
	
pl=CreatePlane()
	PositionEntity pl,0,-1,0
	EntityTexture pl,groundtexture
	EntityPickMode pl,2
	EntityType pl,Col(2)
	EntityColor pl,255,255,255
	
cube=CreateCube(cpiv)
	PositionEntity  cube,0,5,0,1
	ScaleEntity cube,8,1,8
	EntityPickMode cube,2
	EntityType cube,Col(2)
	EntityColor cube,53,35,24
	EntityShininess cube,1
End Function

Function MainMenu(enable%=1)
If enable = True
	Graphics_Set = 2
		ElseIf enable = False
			CenterCursor()
			Graphics_Set = 1
EndIf
End Function

Function LoadMenuItems()
	
	MenuBackground = CreateImage(GraphicsWidth(),GraphicsHeight())
	
	SetBuffer ImageBuffer(MenuBackground)
		For frames = 0 To 72
			Color 0,(5*frames),0
			Rect frames,frames,GraphicsWidth()-(frames*2),GraphicsHeight()-(frames*2)
		Next
	SetBuffer BackBuffer()
	
	QuitButton = CreateImage(GraphicsWidth()/6.25,GraphicsHeight()/12.5)
	
	SetBuffer ImageBuffer(QuitButton)
		For frames = 0 To 8
			Color 0,(5*frames),0
			Rect frames,frames,(GraphicsWidth()/6.25)-(frames*2),(GraphicsHeight()/12.5)-(frames*2)
		Next
	SetBuffer BackBuffer()
	
	MidHandle QuitButton
	
	Color 255,255,255
End Function


;Player type
Type Player
	Field Pivot,Model,Camera
	
	;Position
	Field X_Pos#
	Field Y_Pos#
	Field Z_Pos#
	
	;Rotation
	Field Pitch#
	Field Yaw#
	Field Roll#
	
	;Size
	Field Width#
	Field Height#
	Field Depth#
	
	;Collision
	Field Radius#
	
	;Speed
	Field X_Accel#
	Field Y_Accel#
	Field Z_Accel#
	
	Field X_Damp#
	Field Y_Damp#
	Field Z_Damp#
	
	Field X_Velo#
	Field Y_Velo#
	Field Z_Velo#
	
	Field X_Mome#
	Field Y_Mome#
	Field Z_Mome#
	
		Field Pitch_Accel#
		Field Yaw_Accel#
		Field Roll_Accel#
		
		Field Pitch_Damp#
		Field Yaw_Damp#
		Field Roll_Damp#
		
		Field Pitch_Velo#
		Field Yaw_Velo#
		Field Roll_Velo#
		
			Field Speed#
	
	;Jumping
	Field Jump_Angle#
	Field Jump_Speed#
	Field Jump_Height#
	
	;Other
	Field GroundAirStatus
	
	;Keys
	Field KForward,KBackward
	Field KLeft,KRight
	Field KJump,KUse
	
	;Mouse
	Field MousePitchSensitivity#
	Field MouseYawSensitivety#
	
	Field MousePitch#
	Field MouseYaw#
	
	;Abilities
	Field A_SuperJump
	
End Type

Function CreatePlayer.Player(modelnumber%=1,x#=0,y#=0,z#=0,pitch#=0,yaw#=0,roll#=0,width#=1,height#=1,depth#=1)
	Local p.Player = New Player ;Creates a new Player Type
	
	p\Pivot = CreatePivot()
		PositionEntity p\Pivot,x,y,z,1
		RotateEntity p\Pivot,pitch,yaw,roll,1
		
	p\Model = CreateCube()
		ScaleEntity p\Model,width,height,depth,1
		
	p\Camera = CreateCamera(p\Pivot)
		PositionEntity p\Camera,0,(Abs(height)*.8),(Abs(depth)*.8);PositionEntity p\Camera,0,4+(Abs(height)*.8),-6-(Abs(depth)*.8)
		RotateEntity p\Camera,DeltaPitch(p\Camera,p\Pivot)*.5,0,0
		CameraClsColor p\Camera,2,10,9 
		
		
	p\X_Pos = x
	p\Y_Pos = y
	p\Z_Pos = z
	
	p\Pitch = pitch
	p\Yaw = yaw
	p\Roll = roll
	
	p\Width = width
	p\Height = height
	p\Depth = depth

	p\Radius = Sqr((width^2)+(height^2)+(depth^2))
	EntityType p\Pivot,Col(1)
	EntityRadius p\Pivot,p\Radius,p\Height
	CameraRange p\Camera,(p\Radius*.01),1000
	
	p\X_Velo = 0
	p\Y_Velo = 0
	p\Z_Velo = 0
		
		p\X_Damp = 0.98
		p\Y_Damp = 0.6
		p\Z_Damp = 0.98
		
		p\Pitch_Damp = 0.8
		p\Yaw_Damp = 0.8
		p\Roll_Damp = 0.94
		
	p\MousePitchSensitivity = .1
	p\MouseYawSensitivety = .1
	
	p\Jump_Angle = 0
	p\Jump_Speed = (4)/p\Radius
	p\Jump_Height = .05
	
	;Define Abilities Here
	p\A_SuperJump = True
	
	
	Return p
End Function

Function UpdatePlayers()
	Local p.Player
	
	For p.Player = Each Player
	
		Select p\GroundAirStatus
			Case 0 ; On Ground
				;Collision
					EnablePlayerJump(p)
					
				;Moving
					ChangePlayerVelocity(p)
					ChangePlayerVelocityWithMouse(p)
					MovePlayer(p)
					TurnPlayer(p)
					
				;Collision
					BumpPlayerSides(p)
					
			Case 1 ; Going Up ^

				;Moving
					ChangePlayerVelocity(p)
					ChangePlayerVelocityWithMouse(p)
					MovePlayer(p)
					TurnPlayer(p)
					
				;Collision
					BumpPlayerSides(p)
					HitPlayerHead(p)
					PlayerJumpUp(p)
					
					
			Case 2 ; Going Down v
				
				;Collision
					PlayerFall(p)
					EnablePlayerJump(p)
				
				;Moving
					ChangePlayerVelocity(p)
					ChangePlayerVelocityWithMouse(p)
					MovePlayer(p)
					TurnPlayer(p)
					
				;Collision
					BumpPlayerSides(p)
					
			Case 3 ; Wall Climbing!
				;Moving
					ChangePlayerVelocity(p)
					ChangePlayerVelocityWithMouse(p)
					MovePlayer(p)
					TurnPlayer(p)
					
				;Collision
					BumpPlayerSides(p)
					HitPlayerHead(p)
		End Select
	Next
End Function

Function PlayerControls(p.Player,forwardkey%,backwardkey%,leftkey%,rightkey%,jumpkey%,usekey%,saveteleport)
	p\KForward = forwardkey
	p\KBackward = backwardkey
	p\KLeft = leftkey
	p\KRight = rightkey
	p\KJump = jumpkey
	p\KUse = usekey
End Function

Function DefaultPlayerControls(p.Player)
	p\KForward = 17
	p\KBackward = 31
	p\KLeft = 30
	p\KRight = 32
	p\KJump = 57
	p\KUse = 18
End Function

Function ChangePlayerVelocity(p.Player)
	If p\KForward = True
		FlushInput
		TFormVector 0,0,0.0025,p\Pivot,0
		
		p\X_Accel = TFormedX()
		p\Z_Accel = TFormedZ()
	EndIf
	
	If p\KBackward = True
		FlushInput
		TFormVector 0,0,-0.0025,p\Pivot,0
		
		p\X_Accel = TFormedX()
		p\Z_Accel = TFormedZ()
	EndIf
	
	If p\KLeft = True
		FlushInput
		TFormVector -0.0015,0,0,p\Camera,0
		
		p\X_Accel = p\X_Accel+TFormedX()
		p\Z_Accel = p\Z_Accel+TFormedZ()
	EndIf
	
	If p\KRight = True
		FlushInput
		TFormVector 0.0015,0,0,p\Camera,0
		
		p\X_Accel = p\X_Accel+TFormedX()
		p\Z_Accel = p\Z_Accel+TFormedZ()
	EndIf
	
		If p\KJump = True
			
			If p\KUse = False
				If p\A_SuperJump = True
					FlushInput
					PlayerJump(p)
				EndIf
				
				If p\A_SuperJump = False
					FlushInput
					PlayerJump(p)
					If p\GroundAirStatus = 1
						p\Jump_Angle = p\Jump_Angle + p\Jump_Speed*(p\Radius/2)
					EndIf
				EndIf
			EndIf
				ElseIf p\GroundAirStatus = 1
					If p\KJump = False
						p\Jump_Angle = p\Jump_Angle + p\Jump_Speed*(p\Radius/2)
					EndIf									
		EndIf
End Function

Function ChangePlayerVelocityWithMouse(p.Player)
	p\MousePitch = MouseYSpeed()
	p\MouseYaw = -MouseXSpeed()
	
	CenterCursor()
	
	p\Pitch_Accel = p\MousePitch*p\MousePitchSensitivity
	p\Yaw_Accel = p\MouseYaw*p\MouseYawSensitivety
End Function

Function MovePlayer(p.Player)
	p\X_Velo = p\X_Velo + p\X_Accel
	p\Y_Velo = p\Y_Velo + p\Y_Accel
	p\Z_Velo = p\Z_Velo + p\Z_Accel
	
	p\X_Mome = (p\Radius * p\X_Velo)
	p\Y_Mome = (p\Radius * p\Y_Velo)
	p\Z_Mome = (p\Radius * p\Z_Velo)

	TranslateEntity p\Pivot,p\X_Velo+p\X_Mome,p\Y_Velo+p\Y_Mome,p\Z_Velo+p\Z_Mome
	
	If p\GroundAirStatus = 0
		p\X_Velo = p\X_Velo * p\X_Damp
		p\Y_Velo = p\Y_Velo * p\Y_Damp
		p\Z_Velo = p\Z_Velo * p\Z_Damp
			Else
				p\X_Velo = p\X_Velo * .999
				p\Y_Velo = p\Y_Velo * p\Y_Damp
				p\Z_Velo = p\Z_Velo * .999
	EndIf
		
	p\Speed = Sqr( (p\X_Velo*p\X_Velo) + (p\Y_Velo*p\Y_Velo) + (p\Z_Velo*p\Z_Velo)  +  (p\X_Mome*p\X_Mome) + (p\Y_Mome*p\Y_Mome) + (p\Z_Mome*p\Z_Mome) )
	
	p\X_Accel = 0
	p\Y_Accel = 0
	p\Z_Accel = 0
End Function

Function TurnPlayer(p.Player)
	p\Pitch_Velo = p\Pitch_Velo + p\Pitch_Accel
	p\Yaw_Velo = p\Yaw_Velo + p\Yaw_Accel
	p\Roll_Velo = p\Roll_Velo + p\Roll_Accel

	TurnEntity p\Pivot,0,p\Yaw_Velo,p\Roll_Velo
	TurnEntity p\Camera,p\Pitch_Velo,0,0
	RotateEntity p\Camera,EntityPitch(p\Camera),p\Yaw_Velo*2,p\Yaw_Velo
		
	p\Pitch_Velo = p\Pitch_Velo * p\Pitch_Damp
	p\Yaw_Velo = p\Yaw_Velo * p\Yaw_Damp
	p\Roll_Velo = p\Roll_Velo * p\Roll_Damp
	
	p\Pitch_Accel = 0
	p\Yaw_Accel = 0
	p\Roll_Accel = 0
End Function

Function EnablePlayerJump(p.Player)
	LinePick(EntityX(p\Pivot,1),EntityY(p\Pivot,1),EntityZ(p\Pivot,1),0,-(p\Radius+.1),0,.3)
	
	If PickedEntity() <> 0
		If PickedNY() => 0.0 Then
			p\Y_Accel = 0
			p\GroundAirStatus = 0
		End If
	Else
		If p\GroundAirStatus = 0 Then
			EnablePlayerFalling(p)
		EndIf
	EndIf
End Function

Function EnablePlayerFalling(p.Player)
	p\GroundAirStatus = 2
	p\Jump_Angle = 90
End Function

Function PlayerJumpUp(p.Player)
	p\Jump_Angle = p\Jump_Angle + p\Jump_Speed
	If p\Jump_Angle > 90 Then
		p\GroundAirStatus = 2
	End If
	p\Y_Accel = Cos(p\Jump_Angle)*p\Jump_Height
End Function

Function PlayerJump(p.Player)
	If p\GroundAirStatus = 0 Then
		If p\Jump_Angle > 90
			p\GroundAirStatus = 1
			p\Jump_Angle = 0
		EndIf
	End If
End Function

Function HitPlayerHead(p.Player)
	LinePick (EntityX(p\Pivot,True),EntityY(p\Pivot,True),EntityZ(p\Pivot,True),0,(p\Radius+.1),0,.3)
	
	If PickedEntity() <> 0 Then
		If PickedNY() = -1 Then
			If p\GroundAirStatus = 1
				p\GroundAirStatus = 0
			EndIf
		EndIf
	EndIf
End Function

Function BumpPlayerSides(p.Player)
	For sidecollisions = 1 To CountCollisions(p\Pivot)
		If CollisionNX(p\Pivot,sidecollisions) <> 0 Then
			p\X_Velo = p\X_Velo * .92
			p\Z_Velo = p\Z_Velo * .92
				ElseIf CollisionNZ(p\Pivot,sidecollisions) <> 0
					p\X_Velo = p\X_Velo * .92
					p\Z_Velo = p\Z_Velo * .92
		EndIf
	Next
End Function

Function PlayerFall(p.Player)
	p\Jump_Angle = p\Jump_Angle + p\Jump_Speed
	If p\Jump_Angle > 180 Then
		p\Jump_Angle = 180 ; don't want to start moving back up :o)
	End If
	p\Y_Accel = Cos(p\Jump_Angle)*Gravity
End Function

Oh by the way I saw this error in your code

Function JumpControl()
If runstate="off" WalkingJump()
If runstate="om"  RunningJump()
End Function

Shouldn't it be "on" not "om"?

WERDNA

(Posted 2009) [#3]

Shouldn't it be "on" not "om"?

Its always the dumb stuff in programming that gets you.
If I ever have a serious problem, I look VERY carefully over
all sections of code that are causing the error to make sure
that I didn't misspell a variable.
About 50% of the time I did :D

GIB3D

(Posted 2009) [#4]

I often make really retarded mistakes too. BUT I don't look for them like you do. Depending on the situation, I see what's going on with the variable or what ever is causing the problem and then backtrack sort of. Sometimes I use DebugLog to find certain problems, it's really helpful.

fox95871

(Posted 2009) [#5]

Fixing the om should help, thanks Werdna. Gia, looking forward to trying what you did as always.

fox95871

(Posted 2009) [#6]

Oh, Gia noticed the om. Anyway, Gia, do you think you could work your magic on my actual code? I tried the one you put up and that's not really what I want. Mine's like one step away anyway, I just don't know what that step is. I fixed the om, but as you can see... yeah, not exactly desirable results on the running jump. I'm not looking for flight.

I will of course continue to try to fix this myself, but I thought I'd ask you since there are quite a few places in my engine now that say ;gias code

GIB3D

(Posted 2009) [#7]

I might try at some point, but not at the moment.