Problems with animation?

Blitz3D Forums/Blitz3D Beginners Area/Problems with animation?

Guy Fawkes

(Posted 2012) [#1]

Hi all, ok, I coded a test demo to try and correctly get my animations working for all models. Problem is, that for some reason when i try to display the walk or run animation, for some reason, it STARTS to do the animation, but then freezes if i hold down the up or down arrow keys, or the W/S keys... Also, if I hold down control and press the space key, he attacks. but then he keeps attacking, and keeps attacking... I need him to NOT freeze, and NOT attack multiple times..

It uses Psionic's Dwarf.

Here's the code:

Graphics3D 800,600,0,2
SetBuffer BackBuffer()

Global camera=CreateCamera()
PositionEntity camera,0,1,-10

CameraViewport camera,0,0,GraphicsWidth(),GraphicsHeight()

AmbientLight 255,255,255

;********** Load Model  and Prepare Animation Sequences

Global dwarf1=LoadAnimMesh("dwarf1.b3d"); This will load All Frames into Sequence 0
Global walk=ExtractAnimSeq (dwarf1,2,14); Extract frames 2 to 14 into Sequence 1 - the value 1 is assigned to the Global walk
Global run=ExtractAnimSeq (dwarf1,16,26); Extract frames 16 to 26 into Sequence 2 - the value 2 is assigned to the Global run
Global idle=ExtractAnimSeq (dwarf1,292,325); Extract frames 292 to 325 into Sequence 3 - the value 3 is assigned to the Global idle
Global attack=ExtractAnimSeq (dwarf1,112,126); Extract frames 112 to 126 into Sequence 4 - the value 4 is assigned to the Global attack

;State values
Global s_forwardwalk            =1
Global s_backwardwalk           =2
Global s_run                    =3
Global s_attack                 =4
Global s_idle                   =5

Global state

Const transpose# = 250

;Position the model 
ScaleEntity dwarf1,.1,.1,.1
RotateEntity dwarf1,0,180,0

Global animspeed# = 0.01

Global debug=1

;************** Main Loop ***********************************
While Not KeyHit(1)

;Always be in the idle state after pressing a button or key command
state=s_idle

;Move Forwards
If KeyDown(200) Or KeyDown(17)

	state=s_forwardwalk
	
EndIf

;Move Backwards
If KeyDown(208) Or KeyDown(31)

	state=s_backwardwalk
	
EndIf

;Attack
If KeyDown(29) Or KeyDown(157)

	If KeyHit(57)<>0
	
		state=s_attack
		
	Else
	
		state=s_idle
		
	EndIf
	
EndIf

;Turn on debug
If KeyDown(29) Or KeyDown(157)

	If KeyHit(32)<>0
	
		debug=1-debug
		
	EndIf
	
EndIf

;Animate the Player
Animate_Player(state)

;Reset the keys
FlushKeys()

;Update the world
UpdateWorld
RenderWorld

;Call debug text if debug is on
If debug=1 Then get_text()

;Flip the scene into view with NO FPS cap
Flip 0

Wend

End

Function Animate_Player(state)


	;Animate the dwarf ONLY if a button is being held OR is being held and another is being pressed

If Not KeyDown(42) Or KeyDown(54)

	If state=s_forwardwalk Then Animate dwarf1,1,animspeed#,walk,transpose#
	If state=s_backwardwalk Then Animate dwarf1,1,-animspeed#,walk,transpose#

Else

	If state=s_forwardwalk Then Animate dwarf1,1,animspeed#,run,transpose#
	If state=s_backwardwalk Then Animate dwarf1,1,-animspeed#,run,transpose#

EndIf

	If state=s_attack Then Animate dwarf1,1,-animspeed#,attack,transpose# : state=s_idle

	;Set idle animation if not animating
	If Not Animating(dwarf1) Then 
	
			If state=s_idle Then Animate dwarf1,1,animspeed#,idle,transpose#
	
	End If
	
	Return state
	
End Function

Function get_text()

	Color 255,255,255
	Text GraphicsWidth()/2,GraphicsHeight()/2,"state:"+state,1,1
	Text GraphicsWidth()/2,GraphicsHeight()/2+20,"animseq:"+AnimSeq(dwarf1),1,1
	Color 255,255,255

End Function

Any help is greatly appreciated! :)

Thanks! :)

Guy Fawkes

(Posted 2012) [#2]

Anyone? This is driving me ABSOLUTELY up the wall T_T

Rob the Great

(Posted 2012) [#3]

The thing you need to understand about animating meshes is that if you repeatedly call Animate on the same sequence, the mesh will continuously start from the beginning of the animation sequence and you won't see anything except for the first frame or two. The easiest fix to this problem is to check and see if the current animation sequence is the same sequence as the one you wish to be animating, and only if they are not the same will you call Animate.

Function Animate_Player(state)


	;Animate the dwarf ONLY if a button is being held OR is being held and another is being pressed

If Not KeyDown(42) Or KeyDown(54)

	If state=s_forwardwalk
           If AnimSeq(dwarf1) <> walk
              Animate dwarf1,1,animspeed#,walk,transpose#
           EndIf
        EndIf
	If state=s_backwardwalk
           If AnimSeq(dwarf1) <> walk
              Animate dwarf1,1,-animspeed#,walk,transpose#
           EndIf
        EndIf

Else

	If state=s_forwardwalk
           If AnimSeq(dwarf1) <> run
              Animate dwarf1,1,animspeed#,run,transpose#
           EndIf
        EndIf
	If state=s_backwardwalk
           If AnimSeq(dwarf1) <> run
              Animate dwarf1,1,-animspeed#,run,transpose#
           EndIf
        EndIf

EndIf

	If state=s_attack
           If AnimSeq(dwarf1) <> attack
              Animate dwarf1,1,-animspeed#,attack,transpose#
           EndIf
           If Not Animating(dwarf1)
              state = s_idle
           EndIf
        EndIf

	;Set idle animation if not animating
	If state=s_idle
           If AnimSeq(dwarf1) <> idle
              Animate dwarf1,1,animspeed#,idle,transpose#
           EndIf
        EndIf
	
	Return state
	
End Function

Guy Fawkes

(Posted 2012) [#4]

Ugh! THANK you! It's been driving me nuts for nearly 3 days O_O