Effects of sun rays

Blitz3D Forums/Blitz3D Beginners Area/Effects of sun rays

Xero	(Posted 2012) [#1]

Hi, I'm fairly new to blitz and my question is how to make a sunburst effect, as I've seen in screenshots Yue working project.

Yasha

(Posted 2012) [#2]

~~Yue's using~~ You can use the FastExtension library. Costs extra, but is very easy to use (sun rays are an included example).

EDIT: Sorry Yue, I really thought you were using it. Shows how good your screenshots are! (How did you do DOF in pure B3D?)

Last edited 2012

Yue	(Posted 2012) [#3]

Hi!, Initially you can use external libraries like Ashadow or FASTEXT, but the method we use is based on codificaicón of Blitz3D, so for lack of money.

The codebase with things to do is this:


Graphics3D 800,600,32,2
SetBuffer BackBuffer()


camera=CreateCamera()
TranslateEntity camera,0,0,-12


wall=CreateCube()
walltex=LoadTexture("stone19.jpg")
EntityTexture wall,walltex
EntityColor wall,110,110,110 
ScaleEntity wall,7,6,7
TranslateEntity wall,6.9,0,0
FlipMesh wall 



window=CreateSunbeams("churchwin3.jpg",40,5,5,1.0,-1.0,10.0,1,1)
ScaleEntity window,1,4,2



EntityParent wall,window
While Not KeyDown(1)
 ang#=(ang#+1) Mod 180
 RotateEntity window,0,ang-180,0
 RenderWorld()
 Text 0,0,"Tris Rendered: "+TrisRendered()
 Flip
Wend
End





Function CreateSunbeams(texpath$,transp=40,numsurfx#=5,numsurfy#=5,zoom#=1.0,height#=-1.0,lenght#=3.0,vertical_on=1,horizontal_on=1)

	tex=LoadTexture(texpath$) 
	tex2=LoadTexture(texpath$,2) 

	
 SetBuffer TextureBuffer(tex2)
 LockBuffer()
 For j=0 To TextureHeight(tex2)-1
  For i=0 To TextureWidth(tex2)-1
   rgb=ReadPixelFast(i,j) And $FFFFFF
   r=(rgb And $FF0000) Shr 16
   g=(rgb And $FF00) Shr 8
   b=(rgb And $FF)
   minv=128
   If r>minv Or g>minv Or b>minv Then
    a = transp Shl 24
   Else
    a=0 
   EndIf
   r=r*3
   g=g*3
   b=b*3
   If r>255 Then r=255  
   If g>255 Then g=255  
   If b>255 Then b=255  
   argb=a Or (r Shl 16) Or (g Shl 8) Or b
   WritePixelFast i,j,argb
  Next
 Next
 UnlockBuffer()
 SetBuffer BackBuffer()


 win=CreateQuad()
 EntityTexture win,tex
 EntityFX win,1


 mesh=CreateMesh()
 surf=CreateSurface(mesh)


 If vertical_on
  For i=0 To numsurfx#
   where#=(((Float(i)-numsurfx)/numsurfx)*2.0)+1.0
   wherev#=(where#+1.0)/2.0
   v0=AddVertex(surf,-1.0,-1.0,where#,wherev,1.0 )
   v1=AddVertex(surf, 1.0*lenght,-1.0+height,where#,wherev,1.0)
   v2=AddVertex(surf, 1.0*lenght,1.0+height,where#,wherev,0.0)
   v3=AddVertex(surf,-1,1.0,where#,wherev,0.0 )
   VertexColor surf,v0, 255,255,255,1
   VertexColor surf,v1, 0,0,0,0
   VertexColor surf,v2, 0,0,0,0
   VertexColor surf,v3, 255,255,255,1
   AddTriangle(surf,v0,v1,v2)
   AddTriangle(surf,v2,v3,v0)
  Next
 EndIf


 If horizontal_on
  For i=0 To numsurfy#
   where#=(((Float(i)-numsurfy)/numsurfy)*2.0)+1.0
   wherev#=(where#+1.0)/2.0
   v0=AddVertex(surf,-1.0,where#,-1,1,-wherev )
   v1=AddVertex(surf, 1.0*lenght,where#*zoom+height,-1,1,-wherev )
   v2=AddVertex(surf, 1.0*lenght,where#*zoom+height,1,0,-wherev )
   v3=AddVertex(surf,-1.0,where#, 1,0,-wherev )
   VertexColor surf,v0, 255,255,255,1
   VertexColor surf,v1, 0,0,0,0
   VertexColor surf,v2, 0,0,0,0
   VertexColor surf,v3, 255,255,255,1
   AddTriangle(surf,v0,v1,v2)
   AddTriangle(surf,v2,v3,v0)
  Next
 EndIf

 UpdateNormals mesh
 EntityFX mesh,16 Or 1 Or 2
 EntityTexture mesh,tex2

 TranslateEntity mesh,1,0,0
 EntityParent mesh,win
 Return win
End Function



Function CreateQuad()
	
  mesh=CreateMesh()
  surf=CreateSurface(mesh)
  v0=AddVertex(surf,0, -1.0,  -1.0, 0,1 )
  v1=AddVertex(surf,0,  1.0,  -1.0, 0,0 )
  v2=AddVertex(surf,0,  1.0,   1.0, 1,0 )
  v3=AddVertex(surf,0, -1.0,   1.0, 1,1 )
  AddTriangle(surf,v0,v1,v2)
  AddTriangle(surf,v2,v3,v0)
  UpdateNormals mesh
  Return mesh
End Function

Result:

Gretins

Edit: Yasha XD!

Last edited 2012

Yue	(Posted 2012) [#4]

the effect is done with the tutorials I've found the community to implement the bloom and the doof, I think I am not much of a problem as soon as I had a slow computer, of course not that I know very well implement all, this is rather it is to take code from other people who are experts and accommodate my needs.

Last edited 2012

Xero	(Posted 2012) [#5]

This is harder than I thought, I think that there would be good results faster FasExt acquire library.

So I'll start by simple things.

Thank you

Mikorians

(Posted 2012) [#6]

Would you mind if your example were added to my library of functions? It's awesome and I'm going to post a freeware engine here eventually.

I have a bad habit of hodgepodging stuff together.
But I think this information should be consolidated and made available to the general public.

Credit: Yue

Last edited 2012