Saving Debuglog Contents

Blitz3D Forums/Blitz3D Programming/Saving Debuglog Contents

asdfasdf

(Posted 2005) [#1]

Is there any way to save the debuglog's contents after an error or when the game shutsdown? I don't really want any extra code with the debuglog cammand.

Beaker

(Posted 2005) [#2]

This is the only way:

Global debugfile

Debug "testing"
Debug "testing2"

Function Debug(txt$)
	DebugLog txt
	If Not debugfile
		debugfile = WriteFile("mydebug.txt")
		If Not debugfile Then RuntimeError "Can't record debug"
	EndIf
	WriteLine debugfile,txt
End Function

Filax

(Posted 2009) [#3]

Sorry to bump :)

;=======================================================================================
; Code : Inc_Debugger
; Project Title : 
; Author : Philippe Agnisola
; Email :                    
; Version : 1.0.0
; Date :              
; Notes : Permet la gestion des debug sous la forme de texte             
;                   
;=======================================================================================

Type tDebug
	
	Field caption$

End Type

Global DebugCounter%=0
Global DebugModeOn%=0
Global DebugFileId%=0
Global DebugFileName$


;InitDebugLog("Test.log")
;
;AddDebugLog("----------------")
;AddDebugLog("This is a test 1")
;AddDebugLog("----------------")
;AddDebugLog("")
;AddDebugLog("Eole est tétu ! si si...")
;AddDebugLog("Signé Filax")
;AddDebugLog("")
;
;RefreshDebugLog()
;
;AddDebugLog("----------------")
;AddDebugLog("This is a test 2")
;AddDebugLog("----------------")
;AddDebugLog("")
;AddDebugLog("Filax est relou ! si si...")
;AddDebugLog("Signé Eole")
;
;RefreshDebugLog()
;
;AddDebugLog("----------------")
;AddDebugLog("This is a test 3")
;AddDebugLog("----------------")
;AddDebugLog("")
;AddDebugLog("Le problème provient, qu'en cours de route une cible peut etre detrite")
;AddDebugLog("Signé Bob")
;
;RefreshDebugLog()
;
;DeleteDebugLog()

; -----------------
; Init the debugger
; -----------------
Function InitDebugLog(filename$)
	
	DebugFileName$=filename$
	DebugFileId%=WriteFile(filename$)
	DebugModeOn%=True

End Function

; --------------------------------
; Write the debug log informations
; --------------------------------
Function AddDebugLog(caption$)
	
	If DebugModeOn%=True Then
		t.tDebug=New tDebug
		t\caption$=caption$
		
		RefreshDebugLog()
	EndIf

End Function

; --------------------
; Refresh the debugger
; --------------------
Function RefreshDebugLog()
	
	If DebugFileId%<>0 Then
		
		If DebugModeOn%=True Then

			For d.tDebug=Each tDebug

				DebugCounter%=DebugCounter%+1

				Local CounterString$="000000"
				Local LineCounter$=Left(CounterString$,Len(CounterString$)-Len(DebugCounter%))
				
				WriteLine DebugFileId%,LineCounter$+DebugCounter%+" : "+d\caption$
	
				Delete d
			
			Next

		EndIf

	Else
	
		RuntimeError "RefreshDebugLog() : Please InitDebugLog(filename$) before !"

	EndIf

End Function

; ------------------
; Purge the debugger
; ------------------
Function PurgeDebugLog()
	
	For d.tDebug=Each tDebug

		Delete d
	
	Next

	DebugCounter%=0

End Function

; ------------------
; Close the debugger
; ------------------
Function CloseDebugLog()

	If DebugModeOn%=True Then	
		RefreshDebugLog()
		CloseFile(DebugFileId%)
	
		DebugFileId%=0
		DebugFileName$=""
		DebugModeOn%=False
		DebugCounter%=0
	EndIf

End Function

Beaker

(Posted 2009) [#4]

OMG! How embarressing!