Moving the camera around with the mouse

Blitz3D Forums/Blitz3D Programming/Moving the camera around with the mouse

A51M15X

(Posted 2009) [#1]

I'm making an fps and this is the code i'm using to move the camera, but whenever i look up or down too fast the camera turns upside down.
I'm not sure how to fix this though.

TurnEntity player, 0, -MouseXSpeed()/6.0, 0
TurnEntity camera, MouseYSpeed()/6.0, 0, 0

If EntityPitch(camera) < -80
RotateEntity camera, -80, EntityYaw(camera), EntityRoll(camera)
EndIf
If EntityPitch(camera) > 80
RotateEntity camera, 80, EntityYaw(camera), EntityRoll(camera)
EndIf

GIB3D

(Posted 2009) [#2]

After all of that put

RotateEntity camera,EntityPitch(camera),EntityYaw(camera),EntityRoll(camera);Doesn't work right

Edit:

RotateEntity camera,EntityPitch(camera),0,0;Works

EntityPitch will stop it from flipping.

A51M15X

(Posted 2009) [#3]

I entered that and now whenever i look up or down at all the camera goes upside down no matter what speed the mouse is going.

AJ00200

(Posted 2009) [#4]

Is there any other code controling the camera?
(Or did you figure this out?)

GIB3D

(Posted 2009) [#5]

Hmm I just tried it myself even though I know I've used it before... this time it didn't work. I'll go check and see whats wrong hopefully I'll find it.

Warner

(Posted 2009) [#6]

Pitch, yaw and roll affect each other. Maybe it is safer to use a variable instead?

x# = x# + MouseXSpeed()/6.0
y# = y# + MouseYSpeed()/6.0

If y < -80 Then y = -80
If y > 80 then y = 80

RotateEntity camera, y, 0, 0
RotateEntity player, 0, -x, 0

GIB3D

(Posted 2009) [#7]

Well I figured it out, we weren't supposed to have the EntityYaw and EntityRoll when using RotateEntity

InitGraphics()

Global Light = CreateLight()
	
Global Pivot = CreatePivot()
Global Camera = CreateCamera(Pivot)
	PositionEntity Camera,0,0,-5
	
	CreateCube()
	PositionEntity CreateCube(),0,-8,0,0
	PositionEntity CreateSphere(),0,8,0,0
	
While Not KeyDown(1)
	
	TurnCamera(Camera,Pivot,1)
	
	UpdateWorld
	RenderWorld
	
	Flip
	
Wend
End

Function InitGraphics(w = 1024, h = 768,title$="Blitz3D Program",exit_message$="")
	Graphics3D w, h, 32, 2
	SetBuffer BackBuffer()
	SeedRnd MilliSecs()
	
	If exit_message <> ""
		AppTitle title,exit_message
			Else
				AppTitle title
	EndIf
End Function

Function TurnCamera(camera,pivot,speed_multiplier#=1)
	TurnEntity pivot,0,-MouseXSpeed()*speed_multiplier,0
	TurnEntity camera,MouseYSpeed()*speed_multiplier,0,0
	RotateEntity camera,EntityPitch(camera),0,0
	
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
End Function

A51M15X

(Posted 2009) [#8]

I meant for an FPS not moving the camera around an object.

A51M15X

(Posted 2009) [#9]

I tried this code from Warner and it stops the camera from turning upside down, but i still can't look left and right.

 
x# = x# + MouseXSpeed()/6.0
y# = y# + MouseYSpeed()/6.0

If y < -80 Then y = -80
If y > 80 then y = 80

RotateEntity camera, y, 0, 0
RotateEntity player, 0, -x, 0

GIB3D

(Posted 2009) [#10]

Um, my way IS for FPS. It's not moving around an object, the cubes and spheres are just there so you can tell if you're flipping or not. But I'm pretty sure every FPS game that allows you to look up, down, left and right use a Camera parented to a Pivot.

A51M15X

(Posted 2009) [#11]

k i guess my code is just messed up thx for the help anyway tho

AJ00200

(Posted 2009) [#12]

The code from Warner needs to be

RotateEntity camera,y,x,0

GIB3D

(Posted 2009) [#13]

What's with the odd names?
A51M15X
AJ00200

Zethrax

(Posted 2009) [#14]

EntityPitch returns dodgy values, unless you're using it in combination with the other 'get rotation' commands

http://www.blitzbasic.com/b3ddocs/command.php?name=EntityPitch&ref=3d_cat

To fix that, you need to cache the pitch value in a variable. I also tend to use a gimbal approach, with different pivots used for yaw and pitch.

http://www.blitzbasic.com/codearcs/codearcs.php?code=1137

Rroff

(Posted 2009) [#15]

Function freelook(camera)
	Local msX#, msY#, p#
	Local multi#

	multi = 0.125
	
	msX=MouseXSpeed()*multi
	msY=MouseYSpeed()*multi
	
	MoveMouse GraphicsWidth()/2, GraphicsHeight()/2

	p = EntityPitch(camera)-msY ; invert
	
	If p>85 Then
		p=85
	EndIf
	If p < -85 Then
		p=-85
	EndIf

	RotateEntity camera,p,EntityYaw(camera)-msX,0
	
End Function

Working freelook - pulled out some sample code somewhere can't remember where the original source was.

Bobysait

(Posted 2009) [#16]

Maybe this code could help.

Graphics3D 800,600,0,2
SetBuffer BackBuffer()


; Mini scene setup
Local Light		=	CreateLight		( 2 )
					MoveEntity		( Light, 200,80,150 )
					LightRange		( Light, 200 )

Local plane		=	CreatePlane		( 8 )

Local n%=0,Cube%=0
For n = 1 To 50
	Cube		=	CreateCube		( )
					MoveEntity		( Cube, Rand(-150,150),1,Rand(-150,150) )
Next

; Player Setup
Local Vel#		=	.6
Local CoefStraff#=	.7

Local Player%	=	CreatePivot		( )
Local PivPitch%	=	CreatePivot		( Player )
Local Camera%	=	CreateCamera	( PivPitch )

					MoveEntity		( Player, 0,2,0 )

; Time Setup
Local st%		=	MilliSecs()
Local mt%		=	0
Local lt%		=	0
Local dt#		=	0
Local AppCoef#	=	1.0
Local AppFPS#	=	60.0

; Mouse Setup
Local msx#		=	0.0
Local msy#		=	0.0

; init mouse -> reset mouse speed to prevent initial rotation
	MouseXSpeed():MouseYSpeed()


Repeat
	; update timing
	lt=mt
	mt=MilliSecs()-st
	dt=(mt-lt)
	If dt<1 dt=1
	AppCoef=dt*AppFPS/1000

	; update mouse
	WrapMouse()
	msx=MouseXSpeed()/6.0
	msy=MouseYSpeed()/6.0
	
	; update player (rotation, then translation)
	UpdateViewFPS	( Player, PivPitch, msy,-msx ,80,AppCoef )
	UpdateFPSPlayer	( Player, Vel,CoefStraff, AppCoef )


	RenderWorld
	Text 10,10,EntityPitch(PivPitch)
	Flip

Until KeyHit(1)
End



Function UpdateViewFPS ( Pivot_Player%, Pivot_Pitch%, RotX#, RotY#, AngMax#=80.0 , Coef#=1.0 )

	TurnEntity Pivot_Player,0,RotY,0
	TurnEntity Pivot_Pitch,RotX,0,0

	; due to gimbal lock sometime roll goes to -180 or 180... so we have to wrap this to pitch.
	If Abs(EntityRoll(Pivot_Pitch))=180
		RotateEntity Pivot_Pitch,-Sgn(EntityPitch(Pivot_Pitch,False))*EntityPitch(Pivot_Pitch,False),0,0,False
	EndIf

	; prevent pitch to go out boundaries
	If EntityPitch(Pivot_Pitch,False)<-AngMax	Then RotateEntity Pivot_Pitch,-AngMax,0,0,False
	If EntityPitch(Pivot_Pitch,False)>+AngMax	Then RotateEntity Pivot_Pitch,+AngMax,0,0,False

End Function



Function UpdateFPSPlayer(Pivot_Player, Vel#,Straff#,Coef#)

	Local Mov_UD#=Float(KeyDown(200)-KeyDown(208))*Vel*Coef
	Local Mov_LR#=Float(KeyDown(205)-KeyDown(203))*Vel*Straff*Coef
	MoveEntity Pivot_Player,Mov_LR,0,Mov_UD

End Function



Function WrapMouse(BorderSize%=50)

	Local wrap=False
	Local mx=MouseX()
	Local my=MouseY()
	; Border Positions
		Local B1x=BorderSize
		Local B2x=GraphicsWidth()-BorderSize
		Local B1y=BorderSize
		Local B2y=GraphicsHeight()-BorderSize
	; check if mouse goes out of border
		If mx<B1x Then mx=B2x-10:wrap=True
		If mx>B2x Then mx=B1x+10:wrap=True
		If my<B1y Then my=B2y-10:wrap=True
		If my>B2y Then my=B1y+10:wrap=True
	; if so, wrap it into the screen.
		If wrap
			; wrap mouse coordinates
			MoveMouse mx,my
			; reset mouse speed
			MouseXSpeed()
			MouseYSpeed()
		EndIf

End Function

AJ00200

(Posted 2009) [#17]

Whats with the odd names?

Whats with your name? Its -ugh- Normal

Mine is a LONG STORY

GIB3D

(Posted 2009) [#18]

Your name is a LONG STORY but if I spelt out my user name in full, it would be wayyy too LONG. GIA in GIA_Green_Fire_ comes from 3 things.
G = Favorite color(Green)
I = Somewhat prefer it over fire(Ice)
A = I like it(Archer)

I just stuck those three things together and made GIA. Then for some random reason I put _Green_Fire_ after it. I don't know why I don't just use Green Ice Archer or G.I.A. for everything.

Ishm7920

(Posted 2016) [#19]

Thank you Bobysait