Some help with b3d animations, please?

Blitz3D Forums/Blitz3D Programming/Some help with b3d animations, please?

Newbie31

(Posted 2012) [#1]

heyo,

I'm having some trouble with changing animations [between Idle, Walk and Run].

My code is a follows:




;Set Graphics And Global Constraints

	;Set Graphics buffer
	Graphics3D 800,600,2,2
	SetBuffer BackBuffer()
	
	;Set collision type values
	PLYER=1
	CUBES=2
	SCENE=3
	OFFMAPWALL=4


	Global FreeLookXS#, FreeLookZS#, FreeLookRotXS#, FreeLookRotYS#,Pitch#
	Global gfxcrosshair
	
;IMPORTANT CREATE TYPES TO FIND SUB-ANIMATIONS FROM ROOT NODES
	
	Global Model
	Type subanim
	Field model_child
	Field anim
	End Type 
	
	Global seq% = 1
	

;------------------------------------------------------------------------------------

;------------------------------------------------------------------------------------

;Create Cameras
Global	camera01=CreateCamera()
Global	camera02=CreateCamera()

;------------------------------------------------------------------------------------

;Create Lights
	;Create Light
	Light=CreateLight()
	PositionEntity light,0,10,0
	RotateEntity light,0,0,0
	
;------------------------------------------------------------------------------------

;Create Objects
	;Create Off Map Walls
	wall_n=LoadMesh("meshesoffmapwall.3ds")
	ScaleEntity wall_n,2,2,2
	PositionEntity wall_n,0,0,145
	EntityRadius wall_n,1
	EntityType wall_n,OFFMAPWALL
	
	wall_e=LoadMesh("meshesoffmapwall.3ds")
	ScaleEntity wall_e,2,2,2
	PositionEntity wall_e,-145,0,0
	RotateEntity wall_e,0,90,0
	EntityRadius wall_e,1
	EntityType wall_e,OFFMAPWALL
	
	wall_s=LoadMesh("meshesoffmapwall.3ds")
	ScaleEntity wall_s,2,2,2
	PositionEntity wall_s,0,0,-145
	RotateEntity wall_s,0,180,0
	EntityRadius wall_s,1
	EntityType wall_s,OFFMAPWALL
	
	wall_w=LoadMesh("meshesoffmapwall.3ds")
	ScaleEntity wall_w,2,2,2
	PositionEntity wall_w,145,0,0
	RotateEntity wall_w,0,270,0
	EntityRadius wall_w,1
	EntityType wall_w,OFFMAPWALL
	
	;Create Cube
	cube1=CreateCube()
	EntityRadius cube1,2
	EntityType cube1,CUBES
	ScaleEntity cube1,2,2,2
	PositionEntity cube1,10,1,-5

	;Create Cube
	cube2=CreateCube()
	EntityRadius cube2,2
	EntityType cube2,CUBES
	ScaleEntity cube2,2,2,2
	PositionEntity cube2,-10,1,-5
	
;------------------------------------------------------------------------------------	
;Load Meshes 
	Terrain01=LoadMesh("MeshesMap01.3ds")
	ScaleEntity Terrain01,2,2,2
	EntityRadius Terrain01,1
	PositionEntity Terrain01,0,-5,0
	EntityType Terrain01,SCENE
	
;------------------------------------------------------------------------------------
;Load Player
	;Load Player LowPoly Mesh
	mesh=LoadAnimMesh("Player_anims_new.b3d")
	PositionEntity mesh,0,0,0
	RotateEntity mesh,0,0,0
	EntityRadius mesh,1
	EntityType mesh,PLYER
	
;------------------------------------------------------------------------------------

;Create pivots
	piv01=CreatePivot(mesh)
	PositionEntity piv01,0,5,0
	
	piv02=CreatePivot(mesh)
	PositionEntity piv02,5,5,0
	RotateEntity piv02,0,90,0
	
;------------------------------------------------------------------------------------
	



;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------
;-----------------------IMPORTANT COLLECTS AND ANIMATES ROOT NODES-------------------
;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------

	animx(mesh,seq%)

;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------

;Load Textures And Images
;Images
	gfxcrosshair=LoadImage("Crosshair.bmp")

;Textures
	;1 TERRAIN
	terr_grass01=LoadTexture("texturesgrass01.jpg")
	;2 CRATE
	crate=LoadTexture("wcrate.jpg")
	;3 PLAYER TEXTURE
	player_tex=LoadTexture("box.jpg")

;------------------------------------------------------------------------------------

	;Apply Textures To Entities
	EntityTexture cube1,crate
	EntityTexture cube2,crate
	EntityTexture Terrain01,terr_grass01

;------------------------------------------------------------------------------------

;Set collision method and response values
	method=2
	response=2

	
	
;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------
;-------------------------------- MAIN GAME AREA ------------------------------------
;------------------------------------------------------------------------------------


;Set Key Functions
While Not KeyDown( 1 )

	
;**************************  Animation Sequence Notes   *****************************

;do not uncomment
;mesh
; AnimSequence 0 = frames 0 to ????	[default sequence]
; AnimSequence 1 = frames 5 to 34	[idle1 sequence]
; AnimSequence 2 = frames 46 to 78	[walk sequence]
; AnimSequence 3 = frames 88 to 109	[run sequence]
; AnimSequence 4 = frames 121 To 141 [jump sequence]
	
	
;**************************        End Of Notes         *****************************

	If KeyDown( 17 )
		If AnimSeq(GetChild(mesh,1))=1 
			Animate GetChild(mesh,1),1,.5,2,0
		EndIf
	Else
		If AnimSeq(GetChild(mesh,1))=2 
			Animate GetChild(mesh,1),1,.5,1,0
		EndIf
	EndIf
	
	
;	If KeyDown( 17 )
;		seq% = 2
;	Else
;		seq% = 1
;	EndIf
	
	
	
	
;&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
;&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
;Case Select Camera 
	If KeyHit( 46 )		
		
		whichcamera% = 1-whichcamera%
	;	FreeEntity act_cam
		
		Select whichcamera%
		
			Case 0 
				HideEntity camera01
				ShowEntity camera02
			Case 1
				HideEntity camera02
				ShowEntity camera01
		End Select
		
	End If
	
	
	If EntityCollided (mesh,OFFMAPWALL)
		ec#=1
		MoveEntity mesh,0,.01,0
	Else
		ec#=0
	EndIf
	
	MoveEntity mesh,0,-0.1,0
	MoveEntity cube1,0,-0.1,0
	
;&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&

;object movement according to mouse pointer position
	FreeLook(mesh,piv01, .1)
	CamFollow(camera01,piv01,.18,8,0,0,0)
	
;object movement according to mouse pointer position
	FreeLook(mesh,piv02, .01)
	CamFollow(camera02,piv02,.18,8,0,0,0)
	
;&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&	
;Move camera
	
If KeyHit( 57 )=True Then enable=1-enable 

; Enable/disable wireframe rendering 
WireFrame enable 



;------------------------------------------------------------------------------------
;Enable Collions between type_character and type_scenery
Collisions PLYER,SCENE,method,response
Collisions PLYER,CUBES,method,response
Collisions CUBES,SCENE,method,1
Collisions PLYER,OFFMAPWALL,method,response

;------------------------------------------------------------------------------------

UpdateWorld

RenderWorld

;------------------------------------------------------------------------------------
;------------------------------------------------------------------------------------
;------------------------------- HUD {TextImages} ----------------------------------
;------------------------------------------------------------------------------------



;Set Onscreen Display

DrawImage gfxcrosshair,MouseX()-14,MouseY()-14 ; Draw the image!


;HidePointer

	Text 0,0,"Use cursor keys to move about the infinite plane" 

	Text 0,80,"Current Animation Frame : " + AnimTime(GetChild(mesh,1))
	
	Text 0,100,"Current Animation Sequence : " + seq%
	
	If ec#=1 
		Text 300,500,"Warning, you are not allowed off map"
	EndIf
	
Flip
Wend

End


;------------------------------------------------------------------------------------

;Functions


Function CamFollow(cam,ent,cspeed#,dist#,hite#,xrot#,tilt#)

TFormPoint 0,hite#,-dist#,ent,0

cx#=(TFormedX()-EntityX(cam))*cspeed#
cy#=(TFormedY()-EntityY(cam))*cspeed#
cz#=(TFormedZ()-EntityZ(cam))*cspeed#

TranslateEntity cam,cx,cy,cz

RotateEntity cam,xrot#,EntityYaw(cam),tilt#
PointEntity cam,ent
End Function

Function FreeLook(Object_Horizontal,Object_Vertical, sp# = .1)
If sp# > 0 Then
    Side_Direction=((KeyDown(32) Or KeyDown(205)) - (KeyDown(30) Or KeyDown(203)))
    Front_Direction=((KeyDown(17) Or KeyDown(200)) - (KeyDown(31) Or KeyDown(208)))
	FreeLookXS# = (FreeLookXS# + Side_Direction * (sp#/2)) * .75
	FreeLookZS# = (FreeLookZS# + Front_Direction * sp#) * .75
	MoveEntity Object_Horizontal, FreeLookXS#, 0, FreeLookZS#
EndIf

FreeLookRotXS# = ((MouseXSpeed() - FreeLookRotXS#) * .2 + FreeLookRotXS#) * .45
FreeLookRotYS# = ((MouseYSpeed() - FreeLookRotYS#) * .2 + FreeLookRotYS#) * .45
If EntityPitch(Object_Vertical) + FreeLookRotYS# < -25 Pitch# = -25 ElseIf EntityPitch(Object_Vertical) + FreeLookRotYS# > 45 Pitch# = 45 Else Pitch# = EntityPitch(Object_Vertical) + FreeLookRotYS#
yaw# = -FreeLookRotXS# + EntityYaw(Object_Horizontal)
RotateEntity Object_Horizontal, 0, yaw#, 0
RotateEntity Object_Vertical, Pitch#, 0, 0
MoveMouse GraphicsWidth() / 2, GraphicsHeight() / 2
End Function

Function animx(mesh,seq%)
;mesh Model
	For x = 1 To CountChildren(mesh)
	p.subanim = New subanim
	pmodel_child = GetChild(mesh,x)
	
	idle1 = ExtractAnimSeq(GetChild(mesh,1),5,34) ;idle animation 1 	[IDLE]
	walk1 = ExtractAnimSeq(GetChild(mesh,1),46,78);walk animation 1		[WALK]
	run1 = ExtractAnimSeq(GetChild(mesh,1),88,109);run animation 1		[RUN]	
	jump1 = ExtractAnimSeq(GetChild(mesh,1),121,141);jump animation 1	[JUMP]
	
	If AnimLength(pmodel_child)>=0 Then
		Animate pmodel_child,1,.5,seq%,0
	EndIf
	Next

End Function

This works fine, but all it does is animates an Idle animation when standing still and walking when [W] is depressed.

I tried to add a third sequence with:


;**************************        End Of Notes         *****************************

	If KeyDown( 17 )
		If AnimSeq(GetChild(mesh,1))=1 
			Animate GetChild(mesh,1),1,.5,2,0
		EndIf
	ElseIf KeyDown( 16 )
		If AnimSeq(GetChild(mesh,1))=1 Or AnimSeq(GetChild(mesh,1))=2
			Animate GetChild(mesh,1),1,.5,3,0
		EndIf
	Else
		If AnimSeq(GetChild(mesh,1))=2 
			Animate GetChild(mesh,1),1,.5,1,0
		EndIf
	EndIf

This doesn't work, it changes between animations but doesn't stop animating when the button is released.

I also tried to add a variable "seq%" in my For/next loop where I animate the root node. eg.


animx(mesh,seq%)

;......later

	If KeyDown( 17 )
		seq% = 2
	Else
		seq% = 1
	EndIf

;....later

unction animx(mesh,seq%)
;mesh Model
	For x = 1 To CountChildren(mesh)
	p.subanim = New subanim
	pmodel_child = GetChild(mesh,x)
	
	idle1 = ExtractAnimSeq(GetChild(mesh,1),5,34) ;idle animation 1 	[IDLE]
	walk1 = ExtractAnimSeq(GetChild(mesh,1),46,78);walk animation 1		[WALK]
	run1 = ExtractAnimSeq(GetChild(mesh,1),88,109);run animation 1		[RUN]	
	jump1 = ExtractAnimSeq(GetChild(mesh,1),121,141);jump animation 1	[JUMP]
	
	If AnimLength(pmodel_child)>=0 Then
		Animate pmodel_child,1,.5,seq%,0
	EndIf
	Next

End Function

but altering the "seq%" outside of the function didn't change the animseq. And if I tried to put "If Keydown()" in the function I get an error.

Any Help would be appreciated. Any Ideas?

RemiD

(Posted 2013) [#2]

Hello,

I don't have time to correct your code but i used these commands, this way :
;to load the animations of the character :

HumanMaleXMesh = LoadAnimMesh("Cosmonaut MaterialedRiggedAnimated 2012.04.03 14h49m.b3d")
ScaleEntity(HumanMaleXMesh,0.099,0.099,0.099)
PositionEntity(HumanMaleXMesh,0,0,0)
HideEntity(HumanMaleXMesh)

Global HumanMaleSeqStandIdle = ExtractAnimSeq(HumanMaleXMesh,1,1)
Global HumanMaleSeqRunForward = ExtractAnimSeq(HumanMaleXMesh,5,21)
Global HumanMaleSeqRunBackWard = ExtractAnimSeq(HumanMaleXMesh,5,21)
Global HumanMaleSeqJump = ExtractAnimSeq(HumanMaleXMesh,39,43)
Global HumanMaleSeqFall = ExtractAnimSeq(HumanMaleXMesh,43,43)
;Global HumanMaleSeqLandGravityLow = ExtractAnimSeq(HumanMaleXMesh,43,66)
Global HumanMaleSeqLand = ExtractAnimSeq(HumanMaleXMesh,43,66)
;Global HumanMaleSeqLandGravityHigh = ExtractAnimSeq(HumanMaleXMesh,43,66)
Global HumanMaleSeqPickUpItem = ExtractAnimSeq(HumanMaleXMesh,43,66)

;to init the different possible states :

;PositionState
Const OnGround% = 30
Const OnAir% = 31
Const OnWall% = 32

;MovementState
; OnGround
   Const Idle% = 40
   Const WalkForward% = 41
   Const WalkBackward% = 42
   Const RunForward% = 43
   Const RunBackward% = 44
   ;Const SprintForward% = 45
   ;Const SprintBackward% = 46
   ;Const CrouchForward% = 47 
   ;Const CrouchBackward% = 48
   ;Const SlideForward% = 49 
   ;Const SlideBackward% = 50
   Const Jump% = 51   
   ;Const Interact% = 52 ;(interuptor, Handle, furniture, Object, weapon, device, vehicle, character)
   ;Const Fight% = 53
; OnAir
   Const Fall% = 54
   Const Land% = 55 ;(slow, average, fast)
; OnWall
   Const Grab% = 56 ;(knee height, hip height, shoulder height, hands above head height)
   Const Climb% = 57 ;(flat platform,ladder, grid, net, gouti�re, poteau, trunk, rope, cable)
   Const Letgo% = 58

;to update the animations depending on the character state:

For ChaId% = 1 To CharactersCount%
  If(CharacterPositionState%(ChaId%) = OnWall%)
   ;
  ElseIf(CharacterPositionState%(ChaId%) = OnGround%)
   RotateEntity(CharacterFeet(ChaId%),0,CharacterYaw#(ChaId%),0)
   If(CharacterMovementState%(ChaId%) = Idle%)
    CharacterMovementSpeed#(ChaId%) = 0
    ;Seq StandIdle
    If(AnimSeq(CharacterMesh(ChaId%)) <> HumanMaleSeqStandIdle)
     Animate(CharacterMesh(ChaId%),1,0.1*SpeedCoeff#,HumanMaleSeqStandIdle)
    EndIf
   ElseIf(CharacterMovementState%(ChaId%) = RunForward%)
    CharacterMovementSpeed#(ChaId%) = 0.1*SpeedCoeff#
    ;Seq RunForward
    If(AnimSeq(CharacterMesh(ChaId%)) <> HumanMaleSeqRunForward)
     Animate(CharacterMesh(ChaId%),1,0.2*SpeedCoeff#,HumanMaleSeqRunForward)
    EndIf
   ElseIf(CharacterMovementState%(ChaId%) = RunBackward%)
    CharacterMovementSpeed#(ChaId%) = -0.1*SpeedCoeff#
    ;Seq RunBackward
    If(AnimSeq(CharacterMesh(ChaId%)) <> HumanMaleSeqRunBackward)
     Animate(CharacterMesh(ChaId%),1,0.2*SpeedCoeff#,HumanMaleSeqRunBackward)
    EndIf
   ElseIf(CharacterMovementState%(ChaId%) = Jump%)
    CharacterJumpState%(ChaId%) = 1
    CharacterJumpSpeed#(ChaId%) = 0.2*SpeedCoeff#  
    ;Seq Jump
    If(AnimSeq(CharacterMesh(ChaId%)) <> HumanMaleSeqJump)
     Animate(CharacterMesh(ChaId%),3,0.2*SpeedCoeff#,HumanMaleSeqJump)
    EndIf 
   ElseIf(CharacterMovementState%(PId%) = Land%)
    ;Seq Land	
    If(AnimSeq(CharacterMesh(ChaId%)) <> HumanMaleSeqLand)
     Animate(CharacterMesh(ChaId%),3,1.0*SpeedCoeff#,HumanMaleSeqLand)
    EndIf
    If(AnimTime(CharacterMesh(ChaId%)) = 23)			
     CharacterLandState%(ChaId%) = 0
    EndIf	 
   EndIf
  ElseIf(CharacterPositionState%(ChaId%) = OnAir%)
   TranslateEntity(CharacterFeet(ChaId%),CharacterVX#(ChaId%),0,CharacterVZ#(ChaId%))
   CharacterGravitySpeed#(ChaId%) = CharacterGravitySpeed#(ChaId%) - Gravity#*SpeedCoeff#
   CharacterVY#(ChaId%) = CharacterJumpSpeed#(ChaId%) + CharacterGravitySpeed#(ChaId%)
   TranslateEntity(CharacterFeet(ChaId%),0,CharacterVY#(ChaId%),0)
   ;Seq Fall
    If(AnimSeq(CharacterMesh(ChaId%)) <> HumanMaleSeqFall)
     Animate(CharacterMesh(ChaId%),3,1.0*SpeedCoeff#,HumanMaleSeqFall)
    EndIf
  EndIf
 Next

Please note this is an old code, so it can probably be improved but maybe it can help you.

PS : forget about the symbols "%" "#" "$", they are needed only when you create a new variable but not everywhere like in this code, this is an old bad habit that i had.

Last edited 2013