SHP Fluid particles for Blitz3D

Blitz3D Forums/Blitz3D Userlibs/SHP Fluid particles for Blitz3D

ZJP	(Posted 2010) [#1]

Hi,

W.I.P for Blitz3D

]

JP

Oiduts Studios

(Posted 2010) [#2]

Sweet mama flapjacks, where can I receive the power to do this?

GIB3D

(Posted 2010) [#3]

Sour papa slaphacks, you must give us this ability!

Xors Team

(Posted 2010) [#4]

Hmm.. maybe SPH (Smoothed-particle hydrodynamics)?
Any statistics about the calculation time?

puki	(Posted 2010) [#5]

I took one look at that and thought of oranges - now I have a craving to eat an orange - I cannot fulfill the craving though.

GIB3D

(Posted 2010) [#6]

If it used meta-balls that would be awesome.

ZJP	(Posted 2010) [#7]

Hmm.. maybe SPH (Smoothed-particle hydrodynamics)?

Yes. SPH. Sorry i can't edit the post title

@Puki
Lol. There is a "magical" key : 'C' ;)

@GIB3D. Yes but...Any Blitz source for?

It's not optimised yet and i'm working on a Cuda version.

JP

_PJ_	(Posted 2010) [#8]

Wow!
Looks really, impressive, but I'm guessing there's a lotta processing involved.
How's it coming along, what kinda levels of 'intensiveness' is it at the mo, and where do you hope to get it down too?

ZJP	(Posted 2010) [#9]

Hi,

I'm not a specialist. I'm try to translate the stuff of the Dr Rama HOETZLEIN in a sort of "general customizable DLL". Not really easy. Even with these mails ;)

Jp

PS :
To the webmaster :
Can you change "SHP" to "SPH" in the title please?

GIB3D

(Posted 2010) [#10]

There's a meta ball thread around here somewhere.. I'll go find it.

Edit:
Here it is http://blitzbasic.com/Community/posts.php?topic=89213#1013027

Graphics3D 800, 600, 0, 2
SetBuffer BackBuffer()

Const TRESHOLD# = 0.5

Const GRIDWIDTH = 32
Const GRIDHEIGHT = 32
Const GRIDDEPTH = 32

Dim TLT( 255, 15 )
Dim EdgeTable( 255 )
Dim VoxelData#( 0, 0, 0 )

Type TMetaBall
	Field X#
	Field Y#
	Field Z#
	
	Field VX#
	Field VY#
	Field VZ#
	
	Field Charge#
End Type

Init()

Timer = CreateTimer( 60 )

While Not KeyHit( 1 )
	Counter = MilliSecs()
	UpdateMetaballs()
	Delta = MilliSecs() - Counter
	Mesh = MarchingCubes( GRIDWIDTH, GRIDHEIGHT, GRIDDEPTH )
	Delta2 = MilliSecs() - Counter - Delta
	
	ScaleEntity Mesh, 2, 2, 2
	UpdateNormals Mesh
	
	RenderWorld
	
	FreeEntity Mesh
	
	Text 0, 0, "Berechnungszeit: Metaballs " + Delta + "ms Marching Cubes " + Delta2 + "ms"
	
	Flip 0
	WaitTimer Timer
Wend
End

Function Init()
	Cam = CreateCamera()
	PositionEntity Cam, 32, 32, -32
	
	Light = CreateLight( 2 )
	PositionEntity Light, 64, 64, 0
	LightRange Light, 32
	
	LoadTLT()
	LoadEdgeTable()
	
	SeedRnd MilliSecs()
	
	For i = 1 To 5
		MetaBall.TMetaBall = New TMetaBall
		MetaBall\X# = Rnd( 8, 24 )
		MetaBall\Y# = Rnd( 8, 24 )
		MetaBall\Z# = Rnd( 8, 24 )
		MetaBall\VX# = Rnd( -0.5, 0.5 )
		MetaBall\VY# = Rnd( -0.5, 0.5 )
		MetaBall\VZ# = Rnd( -0.5, 0.5 )
		MetaBall\Charge# = Rnd( 5, 8 )
	Next
End Function

Function UpdateMetaballs()
	Dim VoxelData#( GRIDWIDTH - 1, GRIDHEIGHT - 1, GRIDDEPTH - 1 )
	
	For MetaBall.TMetaBall = Each TMetaBall
		MetaBall\X# = MetaBall\X# + MetaBall\VX#
		MetaBall\Y# = MetaBall\Y# + MetaBall\VY#
		MetaBall\Z# = MetaBall\Z# + MetaBall\VZ#
		
		If MetaBall\X# > GRIDWIDTH - 7 Or MetaBall\X# < 7 Then MetaBall\VX# = -MetaBall\VX#
		If MetaBall\Y# > GRIDHEIGHT - 7 Or MetaBall\Y# < 7 Then MetaBall\VY# = -MetaBall\VY#
		If MetaBall\Z# > GRIDDEPTH - 7 Or MetaBall\Z# < 7 Then MetaBall\VZ# = -MetaBall\VZ#
	Next
	
	For X = 0 To GRIDWIDTH - 1
		For Y = 0 To GRIDHEIGHT - 1
			For Z = 0 To GRIDDEPTH - 1
				For MetaBall.TMetaBall = Each TMetaBall
					DistSq# = ( X - Metaball\X# )*( X - Metaball\X# ) + ( Y - Metaball\Y# )*( Y - Metaball\Y# ) + ( Z - Metaball\Z# )*( Z - Metaball\Z# )
					VoxelData( X, Y, Z ) = VoxelData( X, Y, Z ) + MetaBall\Charge/DistSQ#
				Next
			Next
		Next
	Next
End Function

Function LoadTLT()
	Restore TLT
	
	For CubeIndex = 0 To 255
		For EdgeIndex = 0 To 15
			Read TLT( CubeIndex, EdgeIndex )
		Next
	Next
End Function

Function LoadEdgeTable()
	Restore EdgeTable
	
	For CubeIndex = 0 To 255
		Read EdgeTable( CubeIndex )
	Next
End Function

Function MarchingCubes( Width, Height, Depth )
	Local EdgeX#[ 11 ], EdgeY#[ 11 ], EdgeZ#[ 11 ], VertexCount
	
	Local TriMesh = CreateMesh()
	Local TriSurf = CreateSurface( TriMesh )
	
	For Z = 0 To Depth - 2
		For X = 0 To Width - 2
			For Y = 0 To Height - 2
				Local CubeIndex = 0
				
				If VoxelData#( X + 0, Y + 1, Z + 1 ) > TRESHOLD# Then CubeIndex = CubeIndex Or %00000001
				If VoxelData#( X + 1, Y + 1, Z + 1 ) > TRESHOLD# Then CubeIndex = CubeIndex Or %00000010
				If VoxelData#( X + 1, Y + 1, Z + 0 ) > TRESHOLD# Then CubeIndex = CubeIndex Or %00000100
				If VoxelData#( X + 0, Y + 1, Z + 0 ) > TRESHOLD# Then CubeIndex = CubeIndex Or %00001000
				If VoxelData#( X + 0, Y + 0, Z + 1 ) > TRESHOLD# Then CubeIndex = CubeIndex Or %00010000
				If VoxelData#( X + 1, Y + 0, Z + 1 ) > TRESHOLD# Then CubeIndex = CubeIndex Or %00100000
				If VoxelData#( X + 1, Y + 0, Z + 0 ) > TRESHOLD# Then CubeIndex = CubeIndex Or %01000000
				If VoxelData#( X + 0, Y + 0, Z + 0 ) > TRESHOLD# Then CubeIndex = CubeIndex Or %10000000
				
				If EdgeTable( CubeIndex ) > 0 Then
					If EdgeTable( CubeIndex ) And %000000000001 Then InterpolateEdge( X + 0, Y + 1, Z + 1, X + 1, Y + 1, Z + 1, 0, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %000000000010 Then InterpolateEdge( X + 1, Y + 1, Z + 1, X + 1, Y + 1, Z + 0, 1, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %000000000100 Then InterpolateEdge( X + 1, Y + 1, Z + 0, X + 0, Y + 1, Z + 0, 2, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %000000001000 Then InterpolateEdge( X + 0, Y + 1, Z + 0, X + 0, Y + 1, Z + 1, 3, EdgeX, EdgeY, EdgeZ )
					
					If EdgeTable( CubeIndex ) And %000000010000 Then InterpolateEdge( X + 0, Y + 0, Z + 1, X + 1, Y + 0, Z + 1, 4, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %000000100000 Then InterpolateEdge( X + 1, Y + 0, Z + 1, X + 1, Y + 0, Z + 0, 5, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %000001000000 Then InterpolateEdge( X + 1, Y + 0, Z + 0, X + 0, Y + 0, Z + 0, 6, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %000010000000 Then InterpolateEdge( X + 0, Y + 0, Z + 0, X + 0, Y + 0, Z + 1, 7, EdgeX, EdgeY, EdgeZ )
					
					If EdgeTable( CubeIndex ) And %000100000000 Then InterpolateEdge( X + 0, Y + 0, Z + 1, X + 0, Y + 1, Z + 1, 8, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %001000000000 Then InterpolateEdge( X + 1, Y + 0, Z + 1, X + 1, Y + 1, Z + 1, 9, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %010000000000 Then InterpolateEdge( X + 1, Y + 0, Z + 0, X + 1, Y + 1, Z + 0, 10, EdgeX, EdgeY, EdgeZ )
					If EdgeTable( CubeIndex ) And %100000000000 Then InterpolateEdge( X + 0, Y + 0, Z + 0, X + 0, Y + 1, Z + 0, 11, EdgeX, EdgeY, EdgeZ )
					
					Local TriIndex = 0
					While TLT( CubeIndex, TriIndex ) >= 0
						V1 = AddVertex( TriSurf, EdgeX[ TLT( CubeIndex, TriIndex + 0 ) ], EdgeY[ TLT( CubeIndex, TriIndex + 0 ) ], EdgeZ[ TLT( CubeIndex, TriIndex + 0 ) ] )
						V2 = AddVertex( TriSurf, EdgeX[ TLT( CubeIndex, TriIndex + 1 ) ], EdgeY[ TLT( CubeIndex, TriIndex + 1 ) ], EdgeZ[ TLT( CubeIndex, TriIndex + 1 ) ] )
						V3 = AddVertex( TriSurf, EdgeX[ TLT( CubeIndex, TriIndex + 2 ) ], EdgeY[ TLT( CubeIndex, TriIndex + 2 ) ], EdgeZ[ TLT( CubeIndex, TriIndex + 2 ) ] )
						
						AddTriangle TriSurf, V1, V2, V3
						
						TriIndex = TriIndex + 3
						VertexCount = VertexCount + 3
					Wend
					
					If VertexCount > 65000 Then TriSurf = CreateSurface( TriMesh ) ;Die Vertexbuffer von DX sollten wir nicht sprengen
				EndIf
			Next
		Next
	Next
	
	Return TriMesh
End Function

Function InterpolateEdge( X1, Y1, Z1, X2, Y2, Z2, Index, EdgeX#[ 11 ], EdgeY#[ 11 ], EdgeZ#[ 11 ] )
	Ratio# = ( TRESHOLD# - VoxelData#( X1, Y1, Z1 ) )/( VoxelData#( X2, Y2, Z2 ) - VoxelData#( X1, Y1, Z1 ) )
	
	EdgeX[ Index ] = X1 + Ratio#*( X2 - X1 )
	EdgeY[ Index ] = Y1 + Ratio#*( Y2 - Y1 )
	EdgeZ[ Index ] = Z1 + Ratio#*( Z2 - Z1 )
End Function

.EdgeTable ;Die Seiten des Würfels, die geschnitten werden
Data $000, $109, $203, $30A, $406, $50F, $605, $70C
Data $80C, $905, $A0F, $B06, $C0A, $D03, $E09, $F00
Data $190, $099, $393, $29A, $596, $49F, $795, $69C
Data $99C, $895, $B9F, $A96, $D9A, $C93, $F99, $E90
Data $230, $339, $033, $13A, $636, $73F, $435, $53C
Data $A3C, $B35, $83F, $936, $E3A, $F33, $C39, $D30
Data $3A0, $2A9, $1A3, $0AA, $7A6, $6AF, $5A5, $4AC
Data $BAC, $AA5, $9AF, $8A6, $fAA, $EA3, $DA9, $CA0
Data $460, $569, $663, $76A, $066, $16F, $265, $36C
Data $C6C, $D65, $E6F, $F66, $86A, $963, $A69, $B60
Data $5F0, $4F9, $7F3, $6FA, $1F6, $0FF, $3F5, $2FC
Data $DFC, $CF5, $FFF, $EF6, $9FA, $8F3, $BF9, $AF0
Data $650, $759, $453, $55A, $256, $35F, $055, $15C
Data $E5C, $F55, $C5F, $D56, $A5A, $B53, $859, $950
Data $7C0, $6C9, $5C3, $4CA, $3C6, $2CF, $1C5, $0CC
Data $FCC, $EC5, $DCF, $CC6, $BCA, $AC3, $9C9, $8C0
Data $8C0, $9C9, $AC3, $BCA, $CC6, $DCF, $EC5, $FCC
Data $0CC, $1C5, $2CF, $3C6, $4CA, $5C3, $6C9, $7C0
Data $950, $859, $B53, $A5A, $D56, $C5F, $F55, $E5C
Data $15C, $055, $35F, $256, $55A, $453, $759, $650
Data $AF0, $BF9, $8F3, $9FA, $EF6, $FFF, $CF5, $DFC
Data $2FC, $3F5, $0FF, $1F6, $6FA, $7F3, $4F9, $5F0
Data $B60, $A69, $963, $86A, $F66, $E6F, $D65, $C6C
Data $36C, $265, $16F, $066, $76A, $663, $569, $460
Data $CA0, $DA9, $EA3, $FAA, $8A6, $9AF, $AA5, $BAC
Data $4AC, $5A5, $6AF, $7A6, $0AA, $1A3, $2A9, $3A0
Data $D30, $C39, $F33, $E3A, $936, $83F, $B35, $A3C
Data $53C, $435, $73F, $636, $13A, $033, $339, $230
Data $E90, $F99, $C93, $D9A, $A96, $B9F, $895, $99C
Data $69C, $795, $49F, $596, $29A, $393, $099, $190
Data $F00, $E09, $D03, $C0A, $B06, $A0F, $905, $80C
Data $70C, $605, $50F, $406, $30A, $203, $109, $000


.TLT ;Triangle Lookup Table
Data -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 3, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 1, 9, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 8, 3, 9, 8, 1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 10, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 3, 1, 2, 10, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 9, 2, 10, 0, 2, 9, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 2, 8, 3, 2, 10, 8, 10, 9, 8, -1, -1, -1, -1, -1, -1, -1
Data 3, 11, 2, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 11, 2, 8, 11, 0, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 9, 0, 2, 3, 11, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 11, 2, 1, 9, 11, 9, 8, 11, -1, -1, -1, -1, -1, -1, -1
Data 3, 10, 1, 11, 10, 3, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 10, 1, 0, 8, 10, 8, 11, 10, -1, -1, -1, -1, -1, -1, -1
Data 3, 9, 0, 3, 11, 9, 11, 10, 9, -1, -1, -1, -1, -1, -1, -1
Data 9, 8, 10, 10, 8, 11, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 7, 8, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 3, 0, 7, 3, 4, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 1, 9, 8, 4, 7, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 1, 9, 4, 7, 1, 7, 3, 1, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 10, 8, 4, 7, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 3, 4, 7, 3, 0, 4, 1, 2, 10, -1, -1, -1, -1, -1, -1, -1
Data 9, 2, 10, 9, 0, 2, 8, 4, 7, -1, -1, -1, -1, -1, -1, -1
Data 2, 10, 9, 2, 9, 7, 2, 7, 3, 7, 9, 4, -1, -1, -1, -1
Data 8, 4, 7, 3, 11, 2, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 11, 4, 7, 11, 2, 4, 2, 0, 4, -1, -1, -1, -1, -1, -1, -1
Data 9, 0, 1, 8, 4, 7, 2, 3, 11, -1, -1, -1, -1, -1, -1, -1
Data 4, 7, 11, 9, 4, 11, 9, 11, 2, 9, 2, 1, -1, -1, -1, -1
Data 3, 10, 1, 3, 11, 10, 7, 8, 4, -1, -1, -1, -1, -1, -1, -1
Data 1, 11, 10, 1, 4, 11, 1, 0, 4, 7, 11, 4, -1, -1, -1, -1
Data 4, 7, 8, 9, 0, 11, 9, 11, 10, 11, 0, 3, -1, -1, -1, -1
Data 4, 7, 11, 4, 11, 9, 9, 11, 10, -1, -1, -1, -1, -1, -1, -1
Data 9, 5, 4, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 9, 5, 4, 0, 8, 3, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 5, 4, 1, 5, 0, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 8, 5, 4, 8, 3, 5, 3, 1, 5, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 10, 9, 5, 4, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 3, 0, 8, 1, 2, 10, 4, 9, 5, -1, -1, -1, -1, -1, -1, -1
Data 5, 2, 10, 5, 4, 2, 4, 0, 2, -1, -1, -1, -1, -1, -1, -1
Data 2, 10, 5, 3, 2, 5, 3, 5, 4, 3, 4, 8, -1, -1, -1, -1
Data 9, 5, 4, 2, 3, 11, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 11, 2, 0, 8, 11, 4, 9, 5, -1, -1, -1, -1, -1, -1, -1
Data 0, 5, 4, 0, 1, 5, 2, 3, 11, -1, -1, -1, -1, -1, -1, -1
Data 2, 1, 5, 2, 5, 8, 2, 8, 11, 4, 8, 5, -1, -1, -1, -1
Data 10, 3, 11, 10, 1, 3, 9, 5, 4, -1, -1, -1, -1, -1, -1, -1
Data 4, 9, 5, 0, 8, 1, 8, 10, 1, 8, 11, 10, -1, -1, -1, -1
Data 5, 4, 0, 5, 0, 11, 5, 11, 10, 11, 0, 3, -1, -1, -1, -1
Data 5, 4, 8, 5, 8, 10, 10, 8, 11, -1, -1, -1, -1, -1, -1, -1
Data 9, 7, 8, 5, 7, 9, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 9, 3, 0, 9, 5, 3, 5, 7, 3, -1, -1, -1, -1, -1, -1, -1
Data 0, 7, 8, 0, 1, 7, 1, 5, 7, -1, -1, -1, -1, -1, -1, -1
Data 1, 5, 3, 3, 5, 7, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 9, 7, 8, 9, 5, 7, 10, 1, 2, -1, -1, -1, -1, -1, -1, -1
Data 10, 1, 2, 9, 5, 0, 5, 3, 0, 5, 7, 3, -1, -1, -1, -1
Data 8, 0, 2, 8, 2, 5, 8, 5, 7, 10, 5, 2, -1, -1, -1, -1
Data 2, 10, 5, 2, 5, 3, 3, 5, 7, -1, -1, -1, -1, -1, -1, -1
Data 7, 9, 5, 7, 8, 9, 3, 11, 2, -1, -1, -1, -1, -1, -1, -1
Data 9, 5, 7, 9, 7, 2, 9, 2, 0, 2, 7, 11, -1, -1, -1, -1
Data 2, 3, 11, 0, 1, 8, 1, 7, 8, 1, 5, 7, -1, -1, -1, -1
Data 11, 2, 1, 11, 1, 7, 7, 1, 5, -1, -1, -1, -1, -1, -1, -1
Data 9, 5, 8, 8, 5, 7, 10, 1, 3, 10, 3, 11, -1, -1, -1, -1
Data 5, 7, 0, 5, 0, 9, 7, 11, 0, 1, 0, 10, 11, 10, 0, -1
Data 11, 10, 0, 11, 0, 3, 10, 5, 0, 8, 0, 7, 5, 7, 0, -1
Data 11, 10, 5, 7, 11, 5, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 10, 6, 5, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 3, 5, 10, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 9, 0, 1, 5, 10, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 8, 3, 1, 9, 8, 5, 10, 6, -1, -1, -1, -1, -1, -1, -1
Data 1, 6, 5, 2, 6, 1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 6, 5, 1, 2, 6, 3, 0, 8, -1, -1, -1, -1, -1, -1, -1
Data 9, 6, 5, 9, 0, 6, 0, 2, 6, -1, -1, -1, -1, -1, -1, -1
Data 5, 9, 8, 5, 8, 2, 5, 2, 6, 3, 2, 8, -1, -1, -1, -1
Data 2, 3, 11, 10, 6, 5, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 11, 0, 8, 11, 2, 0, 10, 6, 5, -1, -1, -1, -1, -1, -1, -1
Data 0, 1, 9, 2, 3, 11, 5, 10, 6, -1, -1, -1, -1, -1, -1, -1
Data 5, 10, 6, 1, 9, 2, 9, 11, 2, 9, 8, 11, -1, -1, -1, -1
Data 6, 3, 11, 6, 5, 3, 5, 1, 3, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 11, 0, 11, 5, 0, 5, 1, 5, 11, 6, -1, -1, -1, -1
Data 3, 11, 6, 0, 3, 6, 0, 6, 5, 0, 5, 9, -1, -1, -1, -1
Data 6, 5, 9, 6, 9, 11, 11, 9, 8, -1, -1, -1, -1, -1, -1, -1
Data 5, 10, 6, 4, 7, 8, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 3, 0, 4, 7, 3, 6, 5, 10, -1, -1, -1, -1, -1, -1, -1
Data 1, 9, 0, 5, 10, 6, 8, 4, 7, -1, -1, -1, -1, -1, -1, -1
Data 10, 6, 5, 1, 9, 7, 1, 7, 3, 7, 9, 4, -1, -1, -1, -1
Data 6, 1, 2, 6, 5, 1, 4, 7, 8, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 5, 5, 2, 6, 3, 0, 4, 3, 4, 7, -1, -1, -1, -1
Data 8, 4, 7, 9, 0, 5, 0, 6, 5, 0, 2, 6, -1, -1, -1, -1
Data 7, 3, 9, 7, 9, 4, 3, 2, 9, 5, 9, 6, 2, 6, 9, -1
Data 3, 11, 2, 7, 8, 4, 10, 6, 5, -1, -1, -1, -1, -1, -1, -1
Data 5, 10, 6, 4, 7, 2, 4, 2, 0, 2, 7, 11, -1, -1, -1, -1
Data 0, 1, 9, 4, 7, 8, 2, 3, 11, 5, 10, 6, -1, -1, -1, -1
Data 9, 2, 1, 9, 11, 2, 9, 4, 11, 7, 11, 4, 5, 10, 6, -1
Data 8, 4, 7, 3, 11, 5, 3, 5, 1, 5, 11, 6, -1, -1, -1, -1
Data 5, 1, 11, 5, 11, 6, 1, 0, 11, 7, 11, 4, 0, 4, 11, -1
Data 0, 5, 9, 0, 6, 5, 0, 3, 6, 11, 6, 3, 8, 4, 7, -1
Data 6, 5, 9, 6, 9, 11, 4, 7, 9, 7, 11, 9, -1, -1, -1, -1
Data 10, 4, 9, 6, 4, 10, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 10, 6, 4, 9, 10, 0, 8, 3, -1, -1, -1, -1, -1, -1, -1
Data 10, 0, 1, 10, 6, 0, 6, 4, 0, -1, -1, -1, -1, -1, -1, -1
Data 8, 3, 1, 8, 1, 6, 8, 6, 4, 6, 1, 10, -1, -1, -1, -1
Data 1, 4, 9, 1, 2, 4, 2, 6, 4, -1, -1, -1, -1, -1, -1, -1
Data 3, 0, 8, 1, 2, 9, 2, 4, 9, 2, 6, 4, -1, -1, -1, -1
Data 0, 2, 4, 4, 2, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 8, 3, 2, 8, 2, 4, 4, 2, 6, -1, -1, -1, -1, -1, -1, -1
Data 10, 4, 9, 10, 6, 4, 11, 2, 3, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 2, 2, 8, 11, 4, 9, 10, 4, 10, 6, -1, -1, -1, -1
Data 3, 11, 2, 0, 1, 6, 0, 6, 4, 6, 1, 10, -1, -1, -1, -1
Data 6, 4, 1, 6, 1, 10, 4, 8, 1, 2, 1, 11, 8, 11, 1, -1
Data 9, 6, 4, 9, 3, 6, 9, 1, 3, 11, 6, 3, -1, -1, -1, -1
Data 8, 11, 1, 8, 1, 0, 11, 6, 1, 9, 1, 4, 6, 4, 1, -1
Data 3, 11, 6, 3, 6, 0, 0, 6, 4, -1, -1, -1, -1, -1, -1, -1
Data 6, 4, 8, 11, 6, 8, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 7, 10, 6, 7, 8, 10, 8, 9, 10, -1, -1, -1, -1, -1, -1, -1
Data 0, 7, 3, 0, 10, 7, 0, 9, 10, 6, 7, 10, -1, -1, -1, -1
Data 10, 6, 7, 1, 10, 7, 1, 7, 8, 1, 8, 0, -1, -1, -1, -1
Data 10, 6, 7, 10, 7, 1, 1, 7, 3, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 6, 1, 6, 8, 1, 8, 9, 8, 6, 7, -1, -1, -1, -1
Data 2, 6, 9, 2, 9, 1, 6, 7, 9, 0, 9, 3, 7, 3, 9, -1
Data 7, 8, 0, 7, 0, 6, 6, 0, 2, -1, -1, -1, -1, -1, -1, -1
Data 7, 3, 2, 6, 7, 2, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 2, 3, 11, 10, 6, 8, 10, 8, 9, 8, 6, 7, -1, -1, -1, -1
Data 2, 0, 7, 2, 7, 11, 0, 9, 7, 6, 7, 10, 9, 10, 7, -1
Data 1, 8, 0, 1, 7, 8, 1, 10, 7, 6, 7, 10, 2, 3, 11, -1
Data 11, 2, 1, 11, 1, 7, 10, 6, 1, 6, 7, 1, -1, -1, -1, -1
Data 8, 9, 6, 8, 6, 7, 9, 1, 6, 11, 6, 3, 1, 3, 6, -1
Data 0, 9, 1, 11, 6, 7, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 7, 8, 0, 7, 0, 6, 3, 11, 0, 11, 6, 0, -1, -1, -1, -1
Data 7, 11, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 7, 6, 11, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 3, 0, 8, 11, 7, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 1, 9, 11, 7, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 8, 1, 9, 8, 3, 1, 11, 7, 6, -1, -1, -1, -1, -1, -1, -1
Data 10, 1, 2, 6, 11, 7, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 10, 3, 0, 8, 6, 11, 7, -1, -1, -1, -1, -1, -1, -1
Data 2, 9, 0, 2, 10, 9, 6, 11, 7, -1, -1, -1, -1, -1, -1, -1
Data 6, 11, 7, 2, 10, 3, 10, 8, 3, 10, 9, 8, -1, -1, -1, -1
Data 7, 2, 3, 6, 2, 7, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 7, 0, 8, 7, 6, 0, 6, 2, 0, -1, -1, -1, -1, -1, -1, -1
Data 2, 7, 6, 2, 3, 7, 0, 1, 9, -1, -1, -1, -1, -1, -1, -1
Data 1, 6, 2, 1, 8, 6, 1, 9, 8, 8, 7, 6, -1, -1, -1, -1
Data 10, 7, 6, 10, 1, 7, 1, 3, 7, -1, -1, -1, -1, -1, -1, -1
Data 10, 7, 6, 1, 7, 10, 1, 8, 7, 1, 0, 8, -1, -1, -1, -1
Data 0, 3, 7, 0, 7, 10, 0, 10, 9, 6, 10, 7, -1, -1, -1, -1
Data 7, 6, 10, 7, 10, 8, 8, 10, 9, -1, -1, -1, -1, -1, -1, -1
Data 6, 8, 4, 11, 8, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 3, 6, 11, 3, 0, 6, 0, 4, 6, -1, -1, -1, -1, -1, -1, -1
Data 8, 6, 11, 8, 4, 6, 9, 0, 1, -1, -1, -1, -1, -1, -1, -1
Data 9, 4, 6, 9, 6, 3, 9, 3, 1, 11, 3, 6, -1, -1, -1, -1
Data 6, 8, 4, 6, 11, 8, 2, 10, 1, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 10, 3, 0, 11, 0, 6, 11, 0, 4, 6, -1, -1, -1, -1
Data 4, 11, 8, 4, 6, 11, 0, 2, 9, 2, 10, 9, -1, -1, -1, -1
Data 10, 9, 3, 10, 3, 2, 9, 4, 3, 11, 3, 6, 4, 6, 3, -1
Data 8, 2, 3, 8, 4, 2, 4, 6, 2, -1, -1, -1, -1, -1, -1, -1
Data 0, 4, 2, 4, 6, 2, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 9, 0, 2, 3, 4, 2, 4, 6, 4, 3, 8, -1, -1, -1, -1
Data 1, 9, 4, 1, 4, 2, 2, 4, 6, -1, -1, -1, -1, -1, -1, -1
Data 8, 1, 3, 8, 6, 1, 8, 4, 6, 6, 10, 1, -1, -1, -1, -1
Data 10, 1, 0, 10, 0, 6, 6, 0, 4, -1, -1, -1, -1, -1, -1, -1
Data 4, 6, 3, 4, 3, 8, 6, 10, 3, 0, 3, 9, 10, 9, 3, -1
Data 10, 9, 4, 6, 10, 4, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 9, 5, 7, 6, 11, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 3, 4, 9, 5, 11, 7, 6, -1, -1, -1, -1, -1, -1, -1
Data 5, 0, 1, 5, 4, 0, 7, 6, 11, -1, -1, -1, -1, -1, -1, -1
Data 11, 7, 6, 8, 3, 4, 3, 5, 4, 3, 1, 5, -1, -1, -1, -1
Data 9, 5, 4, 10, 1, 2, 7, 6, 11, -1, -1, -1, -1, -1, -1, -1
Data 6, 11, 7, 1, 2, 10, 0, 8, 3, 4, 9, 5, -1, -1, -1, -1
Data 7, 6, 11, 5, 4, 10, 4, 2, 10, 4, 0, 2, -1, -1, -1, -1
Data 3, 4, 8, 3, 5, 4, 3, 2, 5, 10, 5, 2, 11, 7, 6, -1
Data 7, 2, 3, 7, 6, 2, 5, 4, 9, -1, -1, -1, -1, -1, -1, -1
Data 9, 5, 4, 0, 8, 6, 0, 6, 2, 6, 8, 7, -1, -1, -1, -1
Data 3, 6, 2, 3, 7, 6, 1, 5, 0, 5, 4, 0, -1, -1, -1, -1
Data 6, 2, 8, 6, 8, 7, 2, 1, 8, 4, 8, 5, 1, 5, 8, -1
Data 9, 5, 4, 10, 1, 6, 1, 7, 6, 1, 3, 7, -1, -1, -1, -1
Data 1, 6, 10, 1, 7, 6, 1, 0, 7, 8, 7, 0, 9, 5, 4, -1
Data 4, 0, 10, 4, 10, 5, 0, 3, 10, 6, 10, 7, 3, 7, 10, -1
Data 7, 6, 10, 7, 10, 8, 5, 4, 10, 4, 8, 10, -1, -1, -1, -1
Data 6, 9, 5, 6, 11, 9, 11, 8, 9, -1, -1, -1, -1, -1, -1, -1
Data 3, 6, 11, 0, 6, 3, 0, 5, 6, 0, 9, 5, -1, -1, -1, -1
Data 0, 11, 8, 0, 5, 11, 0, 1, 5, 5, 6, 11, -1, -1, -1, -1
Data 6, 11, 3, 6, 3, 5, 5, 3, 1, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 10, 9, 5, 11, 9, 11, 8, 11, 5, 6, -1, -1, -1, -1
Data 0, 11, 3, 0, 6, 11, 0, 9, 6, 5, 6, 9, 1, 2, 10, -1
Data 11, 8, 5, 11, 5, 6, 8, 0, 5, 10, 5, 2, 0, 2, 5, -1
Data 6, 11, 3, 6, 3, 5, 2, 10, 3, 10, 5, 3, -1, -1, -1, -1
Data 5, 8, 9, 5, 2, 8, 5, 6, 2, 3, 8, 2, -1, -1, -1, -1
Data 9, 5, 6, 9, 6, 0, 0, 6, 2, -1, -1, -1, -1, -1, -1, -1
Data 1, 5, 8, 1, 8, 0, 5, 6, 8, 3, 8, 2, 6, 2, 8, -1
Data 1, 5, 6, 2, 1, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 3, 6, 1, 6, 10, 3, 8, 6, 5, 6, 9, 8, 9, 6, -1
Data 10, 1, 0, 10, 0, 6, 9, 5, 0, 5, 6, 0, -1, -1, -1, -1
Data 0, 3, 8, 5, 6, 10, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 10, 5, 6, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 11, 5, 10, 7, 5, 11, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 11, 5, 10, 11, 7, 5, 8, 3, 0, -1, -1, -1, -1, -1, -1, -1
Data 5, 11, 7, 5, 10, 11, 1, 9, 0, -1, -1, -1, -1, -1, -1, -1
Data 10, 7, 5, 10, 11, 7, 9, 8, 1, 8, 3, 1, -1, -1, -1, -1
Data 11, 1, 2, 11, 7, 1, 7, 5, 1, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 3, 1, 2, 7, 1, 7, 5, 7, 2, 11, -1, -1, -1, -1
Data 9, 7, 5, 9, 2, 7, 9, 0, 2, 2, 11, 7, -1, -1, -1, -1
Data 7, 5, 2, 7, 2, 11, 5, 9, 2, 3, 2, 8, 9, 8, 2, -1
Data 2, 5, 10, 2, 3, 5, 3, 7, 5, -1, -1, -1, -1, -1, -1, -1
Data 8, 2, 0, 8, 5, 2, 8, 7, 5, 10, 2, 5, -1, -1, -1, -1
Data 9, 0, 1, 5, 10, 3, 5, 3, 7, 3, 10, 2, -1, -1, -1, -1
Data 9, 8, 2, 9, 2, 1, 8, 7, 2, 10, 2, 5, 7, 5, 2, -1
Data 1, 3, 5, 3, 7, 5, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 7, 0, 7, 1, 1, 7, 5, -1, -1, -1, -1, -1, -1, -1
Data 9, 0, 3, 9, 3, 5, 5, 3, 7, -1, -1, -1, -1, -1, -1, -1
Data 9, 8, 7, 5, 9, 7, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 5, 8, 4, 5, 10, 8, 10, 11, 8, -1, -1, -1, -1, -1, -1, -1
Data 5, 0, 4, 5, 11, 0, 5, 10, 11, 11, 3, 0, -1, -1, -1, -1
Data 0, 1, 9, 8, 4, 10, 8, 10, 11, 10, 4, 5, -1, -1, -1, -1
Data 10, 11, 4, 10, 4, 5, 11, 3, 4, 9, 4, 1, 3, 1, 4, -1
Data 2, 5, 1, 2, 8, 5, 2, 11, 8, 4, 5, 8, -1, -1, -1, -1
Data 0, 4, 11, 0, 11, 3, 4, 5, 11, 2, 11, 1, 5, 1, 11, -1
Data 0, 2, 5, 0, 5, 9, 2, 11, 5, 4, 5, 8, 11, 8, 5, -1
Data 9, 4, 5, 2, 11, 3, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 2, 5, 10, 3, 5, 2, 3, 4, 5, 3, 8, 4, -1, -1, -1, -1
Data 5, 10, 2, 5, 2, 4, 4, 2, 0, -1, -1, -1, -1, -1, -1, -1
Data 3, 10, 2, 3, 5, 10, 3, 8, 5, 4, 5, 8, 0, 1, 9, -1
Data 5, 10, 2, 5, 2, 4, 1, 9, 2, 9, 4, 2, -1, -1, -1, -1
Data 8, 4, 5, 8, 5, 3, 3, 5, 1, -1, -1, -1, -1, -1, -1, -1
Data 0, 4, 5, 1, 0, 5, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 8, 4, 5, 8, 5, 3, 9, 0, 5, 0, 3, 5, -1, -1, -1, -1
Data 9, 4, 5, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 11, 7, 4, 9, 11, 9, 10, 11, -1, -1, -1, -1, -1, -1, -1
Data 0, 8, 3, 4, 9, 7, 9, 11, 7, 9, 10, 11, -1, -1, -1, -1
Data 1, 10, 11, 1, 11, 4, 1, 4, 0, 7, 4, 11, -1, -1, -1, -1
Data 3, 1, 4, 3, 4, 8, 1, 10, 4, 7, 4, 11, 10, 11, 4, -1
Data 4, 11, 7, 9, 11, 4, 9, 2, 11, 9, 1, 2, -1, -1, -1, -1
Data 9, 7, 4, 9, 11, 7, 9, 1, 11, 2, 11, 1, 0, 8, 3, -1
Data 11, 7, 4, 11, 4, 2, 2, 4, 0, -1, -1, -1, -1, -1, -1, -1
Data 11, 7, 4, 11, 4, 2, 8, 3, 4, 3, 2, 4, -1, -1, -1, -1
Data 2, 9, 10, 2, 7, 9, 2, 3, 7, 7, 4, 9, -1, -1, -1, -1
Data 9, 10, 7, 9, 7, 4, 10, 2, 7, 8, 7, 0, 2, 0, 7, -1
Data 3, 7, 10, 3, 10, 2, 7, 4, 10, 1, 10, 0, 4, 0, 10, -1
Data 1, 10, 2, 8, 7, 4, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 9, 1, 4, 1, 7, 7, 1, 3, -1, -1, -1, -1, -1, -1, -1
Data 4, 9, 1, 4, 1, 7, 0, 8, 1, 8, 7, 1, -1, -1, -1, -1
Data 4, 0, 3, 7, 4, 3, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 4, 8, 7, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 9, 10, 8, 10, 11, 8, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 3, 0, 9, 3, 9, 11, 11, 9, 10, -1, -1, -1, -1, -1, -1, -1
Data 0, 1, 10, 0, 10, 8, 8, 10, 11, -1, -1, -1, -1, -1, -1, -1
Data 3, 1, 10, 11, 3, 10, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 2, 11, 1, 11, 9, 9, 11, 8, -1, -1, -1, -1, -1, -1, -1
Data 3, 0, 9, 3, 9, 11, 1, 2, 9, 2, 11, 9, -1, -1, -1, -1
Data 0, 2, 11, 8, 0, 11, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 3, 2, 11, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 2, 3, 8, 2, 8, 10, 10, 8, 9, -1, -1, -1, -1, -1, -1, -1
Data 9, 10, 2, 0, 9, 2, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 2, 3, 8, 2, 8, 10, 0, 1, 8, 1, 10, 8, -1, -1, -1, -1
Data 1, 10, 2, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 1, 3, 8, 9, 1, 8, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 9, 1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data 0, 3, 8, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1
Data -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1

Blitzplotter

(Posted 2010) [#11]

Sweet mother of a lurvly thing. That looks good! Gawd I'm glad I'm over my animating a clucking train in (aaargh) 2D for my studies.....

Oiduts Studios

(Posted 2010) [#12]

Metaballs would be REALLY impressive with this but the code posted above is pretty slow even when you mess with the threshold, around 10 balls and it gets slow on my computer. Anyone tried to optimize it yet?

Rroff

(Posted 2010) [#13]

Make sure you have debug off - I can get upto 60 balls before performance seriously starts to drop off with my 3.825gig Q9550, with debug on it hits about 400ms.

ZJP	(Posted 2010) [#14]

Hi,

For now, the demos are hard-coded into the DLL. Next step: Setting the parameters (from Blitz3d) for building your own scenes;)

Post your config and FPS please.

JP

_PJ_	(Posted 2010) [#15]

Im pretty sure my GPU isn't CUDA capable,
Anywho...

ATI HD4350 (1Gb)
3.0GHz Athlon quad-core
Windows XP (SP3)
4Gb RAM (of which 3.2 G accessible)

I got quite a varied fps display, between 26 up to 50 with a modal value around 30 (capped at 60)

ZJP	(Posted 2010) [#16]

Btw, the B3d source. ;)
For CUDA, replace
Fluid_Init with Fluid_CUDA_Init
Fluid_SetPart with Fluid_CUDA_SetPart etc... See the .DECLS

JP

AppTitle "FluidSHP (c) 2010 ZJP. test solo"

Const RRED   = 16
Const RGREEN = 8
Const RBLUE  = 0	

Global PartMax%=4000

Graphics3D 800,600,32,2
SetBuffer BackBuffer() 
AmbientLight 200,200,200

demo%=7

camera=CreateCamera()
CameraClsColor camera,0,0,250
PositionEntity camera, 0,50,-50
RotateEntity camera,45,0,0

Global FPS_TimeTarget
Global FPS_Count
Global FPS_FPS

Global posx# = 0
Global posy# = 0
Global posz# = 0

light=CreateLight() 
RotateEntity light,90,0,0 

Dim Part(PartMax%)

Fluid_Init(PartMax)

Particule = CreateSphere(3) 
ScaleEntity  Particule,1.4,1.4,1.4
EntityFX particule,17 ; or ???

For i=0 To PartMax%-1
	Part(i) = CopyEntity(Particule)
	Fluid_SetPart(i,Part(i)); Need the entity pointer.
Next

Fluid_Demo(demo)

While Not KeyDown( 1 ) 

	If KeyHit(32) Then
		demo%=demo%+1
		If demo%>10 Then demo%=0
		Fluid_Demo(demo)
	EndIf
	
	
	If KeyDown(205 ) Then posx= 1 : Fluid_POS(posx#,posy#,posz#)
	If KeyDown(203 ) Then posx=-1 : Fluid_POS(posx#,posy#,posz#)

	If KeyDown(200 ) Then posy= 1 : Fluid_POS(posx#,posy#,posz#)
	If KeyDown(208 ) Then posy=-1 : Fluid_POS(posx#,posy#,posz#)

	If KeyDown(201 ) Then posz= 1 : Fluid_POS(posx#,posy#,posz#)
	If KeyDown(209 ) Then posz=-1 : Fluid_POS(posx#,posy#,posz#)

	Fluid_Run ; Compute and move DIRECTLY the entitys. Peek/poke ;) ;)

	; Color Get. Loose 10fps only. 
	For i=0 To PartMax%-1
		co=Fluid_GetColor(i)
		EntityColor Part(i),RColor(co,RRED  ),RColor(co,RGREEN ),RColor(co,RBLUE )
	Next 

	RenderWorld 
	;Cls

	Text 10,10,"[D] next demo. Arrows move emitter"
	Text 10,30,FPS_Get%()

	Flip 0
Wend 

End 

Function FPS_Get%()	
	If MilliSecs() < FPS_TimeTarget Then
		FPS_Count	= FPS_Count + 1
	Else
		FPS_TimeTarget	= MilliSecs() + 1000
		FPS_FPS		= FPS_Count
		FPS_Count	= 0
	EndIf
	Return FPS_FPS
End Function

Function RColor%(c%,d%) ; thx Nilium
	Return c Shr d And 255 Shl 0
End Function

Jiffy

(Posted 2010) [#17]

I don't understand. What would be the point of this 'source'? to re-skin the hard-coded demo in the dll?
You've released so much neat code before I'm wondering who hacked your account and posted this. Keep it secret, or not- this 'in-between thing' is not exactly useful. I guess 'thanks' just the same.

This based off FLUIDS v.2?

Just wondering as I'm impressed how well it converted- though how much you did outside of blitz would be interesting to know.

puki	(Posted 2010) [#18]

He's French - you get used to them doing stuff 'arse about face'.

ZJP	(Posted 2010) [#19]

For now, the demos are hard-coded into the DLL. Next step: Setting the parameters (from Blitz3d) for building your own scenes;)

This is a w.i.p projet. :)

I'm wondering who hacked your account and posted this....

It's me :)

This based off FLUIDS v.2?

Yes. FluidS V2 by Dr Rama Hoetzlein.
This is one mail i'm sending to him

Hello Mr. Hoetzlein.     


I made a DLL from your source fluids V2 (here: http://forum.unity3d.com/viewtopic.php?t=46371)
 and I must confess that I NOT understand this part ...etc etc..


Response

Hi Jean-Pierre,

You call this function, CreateExample, with a number indicating which
demo to run. Each case sets up a particular demo by setting simulation
paramers.

The example you want to try, with the hole, is case #8.. You can cycle
through each demo using the '[' and ']' keys.. Notice that the boundary
conditions are hard-coded into the simulator, so you can't currently set
up arbitrary scenes and collision. Here is the line below thats important:
  m_Toggle [ DRAIN_BARRIER ] = true;
This tells the simulator to turn on a horizontal plane boundary with a
hole in it.. Sorry i dont have an documentation yet. The other
parameters adjust different aspects of the simulation.

Hope this helps,
-Rama

..how much you did outside of blitz would be interesting to know...

a) Send the entity pointer to the Dll with these lines

For i=0 To PartMax%-1
	Part(i) = CopyEntity(Particule)
	Fluid_SetPart(i,Part(i)); The DLL need the entity pointer.
Next

b)
Update the blitz3D entity position with these lines

	buf = Entity[n] + 64; // Blit3D Entity PosX
	pos = p->pos.x; // Fluid particle PosX
	(*(float *)(buf) = (pos)); // poke float

	buf = Entity[n] + 68; //  Blit3D Entity PosY
	pos = p->pos.z; // Y and Z inversed !!!!
	(*(float *)(buf) = (pos));

	buf = Entity[n] + 72; // Blit3D Entity PosZ
	pos = p->pos.y;
	(*(float *)(buf) = (pos));

	buf = Entity[n] + 44; // Valid the move. Blitz3D stuff
	(*(int *)(buf) = (3)); // poke int

He's French - you get used to them doing stuff 'arse about face'.

Indee (Teal'c)

JP

Jiffy

(Posted 2010) [#20]

Ah, Ok. Sounds good- was just wondering, as it didn't seem your usual 'style'.
(nod)

ZJP	(Posted 2010) [#21]

;)

Oiduts Studios

(Posted 2010) [#22]

I love this thing. I kind of messed around with it.

GIB3D

(Posted 2010) [#23]

Looks like it's a Waterverse or Water Galaxy.

ZJP	(Posted 2010) [#24]

Nice BM ;)

New version. ALL others version are removed. Sorry.
+++++++++++++++++++++++++++++++++++++++++++++++
http://www.zinfo972.net/avatar/FluidB3D_DLL.ZIP
+++++++++++++++++++++++++++++++++++++++++++++++
Parameterizing scenes possible. (W.I.P)

I renamed the DLL, because there will be 3 basic versions :

1) A Blitz3D version (FluidSHP_B3D.dll) that alters directly the positions of Blitz3D entities

2) A Unity3D version (FluidSHP_UNI.dll) that alters directly the positions of Unity3D's particles

2) A general version (FluidSHP.dll) for all other engine. The position of the particles can be set with a sort of

        For i = 0 To MaxPart
            Particle(i).PosX = FluidSHP_GetX(i)
            Particle(i).PosY = FluidSHP_GetY(i)
            Particle(i).PosZ = FluidSHP_GetZ(i)
        Next

I am also working on a CUDA version. The performance will by 60% ;)

JP


AppTitle "FluidSHP B3D no CUDA version"

Const RRED   = 16 ; Global for the Nilium color routine ;)
Const RGREEN = 8
Const RBLUE  = 0	

Global PartMax% = 5000 ; 100 to 10000

Graphics3D 800,600,32,2
SetBuffer BackBuffer() 

camera = CreateCamera()
CameraClsColor camera, 0,0,200
PositionEntity camera, 0,70,-35
RotateEntity   camera, 45,0,0

Global FPS_TimeTarget ; Global for FPS routine
Global FPS_Count
Global FPS_FPS

Global posx# = 0 ; global for emitter
Global posy# = 0
Global posz# = 0

Dim Part(PartMax%)

FluidB3D_Init(PartMax) ; Init the engine

cube=CreateCube()
ScaleEntity    cube,1,20,1
; Particle. sphere or other. Quad?!?
Particule = CreateSphere(2) 
PositionEntity Particule,0,0,0
ScaleEntity    Particule,1.6,1.6,1.6 
MoveEntity     Particule,1000,1000,1000

EntityFX particule,1

; For the B3D Dll version. Need the handle for each particle. The Dll can move directly the B3D entity. ;)
For i=0 To PartMax%-1
	Part(i) = CopyEntity(Particule)
	FluidB3D_SetPart(i,Part(i))
Next
;create scene parameter. W.I.P!!!!!
Const SPH_RESET        = 0 ; IMPORTANT. FIRST PARAMETER !!!!!
Const SPH_READY        = 100 ; IMPORTANT. LAST PARAMETER !!!!!
Const SPH_VOLMIN       = 1
Const SPH_VOLMAX       = 2
Const SPH_INITMIN      = 3
Const SPH_INITMAX      = 4
Const FORCE_XMIN_SIN   = 5
Const BOUND_ZMIN_SLOPE = 6
Const PLANE_GRAV_DIR   = 7
Const FORCE_XMAX_SIN   = 8
Const EMIT_POS         = 9
Const EMIT_RATE        = 10
Const EMIT_ANG         = 11
Const WALL_BARRIER     = 13
Const WRAP_X           = 14

; Wave pool scene
;FluidB3D_Scene(SPH_RESET        ,   0,  0,   0) ; Reset the scene
;FluidB3D_Scene(SPH_VOLMIN       , -30,  0, -40) ; boundary of the scene X Y Z
;FluidB3D_Scene(SPH_VOLMAX       ,  40, 40,  40)
;FluidB3D_Scene(SPH_INITMIN      , -30, 10, -36) ; boundary of the "init drop flow"
;FluidB3D_Scene(SPH_INITMAX      ,  30, 40,  36)
;FluidB3D_Scene(FORCE_XMIN_SIN   ,   8,  0,   0) ; Force apply to -X
;FluidB3D_Scene(BOUND_ZMIN_SLOPE ,   0.03,  0,   0) ; Plane Inclination
;FluidB3D_Scene(PLANE_GRAV_DIR   ,   0,-9.8,   0) ; Gravity X Y Z
;FluidB3D_Scene(SPH_READY        ,   0,  0,   0) ; Scene is ready


;Dam break scene
;FluidB3D_Scene(SPH_RESET        ,   0,   0,   0) ; Reset the scene
;FluidB3D_Scene(SPH_VOLMIN       , -30,   0, -14)
;FluidB3D_Scene(SPH_VOLMAX       ,  30,  60,  14)
;FluidB3D_Scene(SPH_INITMIN      ,   0,   0, -13)
;FluidB3D_Scene(SPH_INITMAX      ,  29,  30,  13)
;FluidB3D_Scene(PLANE_GRAV_DIR   ,   0,-9.8,   0) ; Gravity X Y Z
;FluidB3D_Scene(SPH_READY        ,   0,   0,   0) ; Scene is ready


; Dual Wave pool scene
;FluidB3D_Scene(SPH_RESET        ,   0,   0,  0) ; Reset the scene
;FluidB3D_Scene(SPH_VOLMIN       , -60,   0, -5)
;FluidB3D_Scene(SPH_VOLMAX       ,  60,  50,  5)
;FluidB3D_Scene(SPH_INITMIN      , -46,   0, -5)
;FluidB3D_Scene(SPH_INITMAX      ,  46,  15,  5)
;FluidB3D_Scene(FORCE_XMIN_SIN   ,   8,   0,  0) ; Force apply to -X
;FluidB3D_Scene(FORCE_XMAX_SIN   ,  15,   0,  0) ; Force apply to X
;FluidB3D_Scene(PLANE_GRAV_DIR   ,   0,-9.8,  0)
;FluidB3D_Scene(SPH_READY        ,   0,   0,  0) ; Scene is ready


; Swirl Stream
;FluidB3D_Scene(SPH_RESET        ,   0,   0,   0) ; Reset the scene
;FluidB3D_Scene(SPH_VOLMIN       , -30,   0, -30)
;FluidB3D_Scene(SPH_VOLMAX       ,  30,  50,  30)
;FluidB3D_Scene(SPH_INITMIN      , -30,   0, -30)
;FluidB3D_Scene(SPH_INITMAX      ,  30,  40,  30)
;FluidB3D_Scene(EMIT_POS         ,   -10,  10,   0) ; Flow emitter POS
;FluidB3D_Scene(EMIT_RATE        ,   1,   0,   5) ; Freq,,Nb Stream
;FluidB3D_Scene(EMIT_ANG         ,   0,   2, 120) ; Emit Angle
;FluidB3D_Scene(PLANE_GRAV_DIR   ,   0,-9.8,   0)
;FluidB3D_Scene(SPH_READY        ,   0,   0,   0) ; Scene is ready

; Shockwave not finish yet !!!!
FluidB3D_Scene(SPH_RESET        ,   0,   0,   0) ; Reset the scene
FluidB3D_Scene(SPH_VOLMIN       , -60,   0, -15)
FluidB3D_Scene(SPH_VOLMAX       ,  60,  50,  15)
FluidB3D_Scene(SPH_INITMIN      , -59,   0, -14)
FluidB3D_Scene(SPH_INITMAX      ,  59,  30,  14)
FluidB3D_Scene(WALL_BARRIER    ,   1,   0,   0)
FluidB3D_Scene(WRAP_X           ,   1,   8,   0) ; Left Wrap and 
FluidB3D_Scene(PLANE_GRAV_DIR   ,   0,-9.8,   0)
FluidB3D_Scene(SPH_READY        ,   0,   0,   0) ; Scene is ready

FluidB3D_SetColorMode(1); Color of the particle. 0 = Pressure, other = Velocity

While Not KeyDown( 1 ) 

	If KeyDown(205 ) Then posx= 1 : FluidB3D_POS(posx#,posy#,posz#)
	If KeyDown(203 ) Then posx=-1 : FluidB3D_POS(posx#,posy#,posz#)

	If KeyDown(200 ) Then posy= 1 : FluidB3D_POS(posx#,posy#,posz#)
	If KeyDown(208 ) Then posy=-1 : FluidB3D_POS(posx#,posy#,posz#)

	If KeyDown(201 ) Then posz= 1 : FluidB3D_POS(posx#,posy#,posz#)
	If KeyDown(209 ) Then posz=-1 : FluidB3D_POS(posx#,posy#,posz#)
	If KeyDown(57) Then FluidB3D_Scene(PLANE_GRAV_DIR ,0,0,0)

	FluidB3D_Run ; Advance the calcul and PositionEntity by the Dll.

	; Get color
	For i=0 To PartMax%-1
		co=FluidB3D_GetColor(i) ; Get color of each particle. 
		EntityColor Part(i),RColor(co,RRED  ),RColor(co,RGREEN ),RColor(co,RBLUE )
	Next 

	RenderWorld 
	;Cls
	Text 10,10,"Fps  : "+FPS_Get%()
	Text 10,30,"Tris : "+TrisRendered()
	Flip 0
Wend 

End 
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Function FPS_Get%()	
	If MilliSecs() < FPS_TimeTarget Then
		FPS_Count	= FPS_Count + 1
	Else
		FPS_TimeTarget	= MilliSecs() + 1000
		FPS_FPS		= FPS_Count
		FPS_Count	= 0
	EndIf
	Return FPS_FPS
End Function
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++
; Nilium Function color
Function RColor%(c%,d%)
	Return (c Shr d And 255 Shl 0)
End Function
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

Noobody

(Posted 2010) [#25]

Metaballs would be REALLY impressive with this but the code posted above is pretty slow even when you mess with the threshold

As Ross C already pointed out, Debug mode has to be disabled. But still, metaballs are clearly not an option for 3D SPH. There are simply too many particles to polygonize. As I stated in the other thread, I never really intended the metaballs code for real-time use, rather than for a fancy little demo.

As for rendering, I'd recommend a point splatting approach. It *should* still look nice while computational overhead is kept minimal. The only problem is that the particles have to be sorted back-to-front, and I'm not sure if there are algorithms out there capable of doing that in realtime. But I guess it's worth a shot :)