ReadData Question

BlitzMax Forums/BlitzMax Beginners Area/ReadData Question

QuickSilva

(Posted 2009) [#1]

Hi,

I have a list of different music files in a list of DefData statements at the bottom of my program, for example,

#Level01
DefData "Level01"

# Level02
DefData "Level02"

and so forth...

I want to be able to select my label, like RestoreData Level01, read the data statement, to get the song to play and then play it.

Currently I am doing this,

Local Music:String
RestoreData Level01
ReadData Music

Select Music
    Case "Level01"
         PlaySound(Level01)
    Case "Level02"
         PlaySound(Level02)
End Select

Is there a simpler way so that I do not have to use the Select part. Can I just do a PlaySound(Music) somehow?

Thanks for any advice.
Jason.

GfK	(Posted 2009) [#2]

Probably a TMap would be best in this scenario.

More here.

plash

(Posted 2009) [#3]

Do your maps load/save from a file? You really should define things like that outside of code (not hardcoded).

In any case:

SuperStrict

Framework brl.blitz
Import brl.standardio
Import brl.map


' Create some levels
Local level01:TLevel = New TLevel.Create("level01")
Local level02:TLevel = New TLevel.Create("level02")
Local level03:TLevel = New TLevel.Create("level03")

' Create associations
Local ascmap:TMusicMap = New TMusicMap.Create()
ascmap.InsertAssociation(level01.GetName(), "level01_ms.ogg")
ascmap.InsertAssociation(level02.GetName(), "level02_ms.ogg")
ascmap.InsertAssociation(level03.GetName(), "level03_ms.ogg")

Print("Music file for level01: '" + ascmap.GetFileForLevelByName(level01.GetName()) + "'")
Print("Music file for level02: '" + ascmap.GetFileForLevelByName(level02.GetName()) + "'")
Print("Music file for level03: '" + ascmap.GetFileForLevelByName(level03.GetName()) + "'")

Type TLevel
	
	Field m_name:String
		
		Method New()
		End Method
		
		Method Create:TLevel(name:String)
			
			SetName(name)
			
			Return Self
			
		End Method
		
		Method SetName(name:String)
			
			m_name = name
			
		End Method
		
		Method GetName:String()
			
			Return m_name
			
		End Method
		
End Type

Type TMusicMap
	
	Field m_map:TMap
		
		Method New()
			
			m_map = New TMap
			
		End Method
		
		Method Create:TMusicMap()
			
			Return Self
			
		End Method
		
		Method InsertAssociation(levelname:String, musicfile:String)
			
			m_map.Insert(levelname, musicfile)
			
		End Method
		
		Method GetFileForLevelByName:String(levelname:String)
			
			Return String(m_map.ValueForKey(levelname))
			
		End Method
		
End Type

Obviously that could be automated, and you could even then use this technique to load the associations from a file.

QuickSilva

(Posted 2009) [#4]

I`m just experimenting at the moment. If I were making a real game then yes, I would load my resources from outside of my code.

Thanks for the example though Plash and thanks for the TMap link GfK, I`ll check it out.

Jason.