Draw over image with background...?

BlitzMax Forums/BlitzMax Beginners Area/Draw over image with background...?

Arowx

(Posted 2010) [#1]

Would I be able to take a circular chunk out of a square image..

E.g.

Square bit of cheese
Mouse takes circular bite out of cheese

Now if I grab a square of the background image and mask it with a circular image I should be able to draw a chunk of the background over the cheese, making it look like a bite was taken out of it?

Midimaster

(Posted 2010) [#2]

I would suggest to lock the image with LockImage() to get a TPixMap. Now you can manipulte the picture. E.g. change the Pixels of the "eaten" parts to transparent (Color=0) WritePixel(). At the end you unlock the picture with UnlockImage().

In the next drawing the transparent part of the image will show the background.

Graphics 640,480,0,60

' example needs any picture (>50x50 pix)
Image:TImage=LoadImage(".....
PixMapImage:TPixmap=LockImage(Image)

For Rad%=0 To 180
	Local Sinus#,Cosin#
	Sinus=Sin(Rad)*10
	Cosin=Cos(Rad)*10
    For X%=0 To sinus
		WritePixel(PixMapImage, X, 20+Cosin, 0)
    Next
Next
UnlockImage(Image)


Setcolor 255,0,0
DrawRect 0,0,640,480
Setcolor 255,255,255
DrawImage Image,10,10
Flip
WaitKey

Arowx

(Posted 2010) [#3]

The plan was not to alter the image of the cheese just to draw over it in the shape of a bite with the background pattern aligned.

I can grasp how this would be done in theory with a polygon shaped bite and the background texture applied or a mask/stenciled image?

MGE	(Posted 2010) [#4]

At the root of your question is basically "terrain deformation". But since Bmax still doesn't have "reliable" render to texture for both dx and ogl, you're left with doing things a bit harder. Rather then re-inventing the wheel, there's a good discussion with ideas, tips, etc, here:

http://www.blitzbasic.com/Community/posts.php?topic=82438#929874

Midimaster

(Posted 2010) [#5]

What should be the sense of drawing again something on front of a cheese, what is already behind the cheese?

e.g if the cheese moves, you will have to do a lot of painting in your method. While the transparent way still works without doing anything.

What would be the disadvantage of my way in your game? Perhaps I did not understand the traget you follow...

Arowx

(Posted 2010) [#6]

What if there are multiple 'cheeses' and they regrow over time?

Zeke	(Posted 2010) [#7]

use multiple images

i made simple demo:

SuperStrict

SeedRnd MilliSecs()
Graphics 800, 600
SetClsColor 50, 50, 200

Global Cheese:TImage[5] '5 cheeses
Global Selected:Int 'Selected cheese

'Create Cheeses
for Local i:Int = 0 to 4
	Cheese[i] = CreateImage(Rand(80, 180), Rand(80, 180))
	local pix:TPixmap = lockimage(cheese[i])
	pix.ClearPixels($ffffff00) 'ARGB 255,255,255,0 Yellow
	UnlockImage(Cheese[i])
Next

While not (KeyHit(key_escape) or AppTerminate())
	
	for Local key:Int = key_1 to key_4
		if KeyHit(key) Then Selected = key - key_1 ; Exit
	Next
	
	if KeyHit(key_space) Then 'Bite
		Local side:Int = rand(0, 2) '0=left,1=top,2=right
		Local size:Int = rand(10, 20) 'bite size
		Local x:Int, y:Int 'bite position
		
		Select side 'set bite positions
			Case 0 'left
				x = -(size / 2) + Rand(1, size - 1)
				y = Rand(0, ImageHeight(Cheese[Selected]) - 1)
			Case 1 'top
				x = Rand(0, ImageWidth(Cheese[selected]) - 1)
				y = -(size / 2) + Rand(1, size - 1)
			Case 2 'right
				x = ImageWidth(Cheese[Selected]) + (size / 2) - Rand(1, size - 1)
				y = Rand(0, ImageHeight(Cheese[Selected]) - 1)
		End Select
	
		'Bite
		Local pix:TPixmap = lockimage(Cheese[selected])
		For Local rad:Int = 0 To 360
			Local Sinus# , cosin#
			sinus = Sin(rad) * size
			cosin = Cos(rad) * size
			For Local _x:Int = -sinus To sinus
				if x + _x < 0 or y + cosin < 0 Then continue
				if x + _x >= pix.width or y + cosin >= pix.height Then Continue
				Local col:Int = pix.ReadPixel(x + _x, y + cosin)
				pix.WritePixel (x + _x, y + Cosin, col & $00FFFFFF) 'Reset alpha value to 0, keep color info
			Next
		Next	
		UnlockImage(Cheese[Selected])
	End If
	
	if KeyHit(key_enter) 'Reset cheeses pixels alpha value back to 255
		for Local i:Int = 0 to 4
			Local pix:TPixmap = lockimage(cheese[i])
			for Local y:Int = 0 until pix.height
				for Local x:Int = 0 until pix.width
					Local col:Int = pix.ReadPixel(x, y)
					if (col shr 24) = 0 then pix.WritePixel(x, y, col + $FF000000) 'Set Alpha to 255
				Next
			Next
			unlockimage(Cheese[i])
		Next
	End If
	
	if KeyHit(key_r)
		for Local i:Int = 0 to 4
			Cheese[i] = CreateImage(Rand(80, 180), Rand(80, 180))
			local pix:TPixmap = lockimage(cheese[i])
			pix.ClearPixels($ffffff00) 'ARGB 255,255,255,0 Yellow
			UnlockImage(Cheese[i])
		Next
	End If
	
	cls
	'DrawFloor
	SetColor 100, 100, 100
	DrawRect 0, 500, 800, 100
	
	SetColor 255, 255, 255
	DrawText "1-5 = Select cheese", 10, 10
	DrawText "Space = Bite", 10, 30
	DrawText "Enter = Reset Bites", 10, 50
	DrawText "R = Re-Create Cheeses", 10, 70
	DrawText "ESC = Exit", 10, 90
	
	'DrawCheeses
	SetColor 255, 255, 255
	for Local i:Int = 0 to 4
		DrawImage (Cheese[i], 20 + i * 200, 500 - ImageHeight(Cheese[i]))
		DrawText (i + 1), 80 + 200 * i, 300
		if i = Selected Then DrawText "Selected", 80 + 200 * i - TextWidth("Selected") / 2, 280
	Next
	Flip
	Delay 5
WEnd

This is almost same as Midimaster's code, but here i just reset pixels alpha value, so when you need to show pixel again. just set pixel alpha to 255.

matibee

(Posted 2010) [#8]

I had an idea for deformable terrain tonight so I knocked this together.

It could easily be modified to handle textures. In that code I only subtract but addition would be easy too. The tricky bit would be if you needed to handle rotation.