max2d in a panel?

BlitzMax Forums/Brucey's Modules/max2d in a panel?

slenkar

(Posted 2009) [#1]

How do you put a max2d canvas into a panel instead of a new window?

_Skully

(Posted 2009) [#2]

Parent the Panel to the window and then parent the canvas to the panel

Global WinG_Main:TGadget=CreateWindow("App",0,0,ScreenWidth,ScreenHeight)
Global Panel_ToolBar:TGadget=CreatePanel(0,0,WinG_Main.ClientWidth(),WinG_Main.ClientHeight(),WinG_Main)
Global Canvas:TGadget = CreateCanvas(0,0,Panel_ToolBar.ClientWidth(),Panel_ToolBar.ClientHeight(),Panel_ToolBar,0)
Canvas.setlayout 1,1,1,1

{edit} oops... are you referring to wx?

Wiebo

(Posted 2009) [#3]

You will need a wxGLcanvas, and draw to it using SetGraphics CanvasGraphics2D( Self )

There are 2 demo's:
wx.mod/samples/graphics_tests/
wx.mod/samples/glmax2d.bmx

slenkar

(Posted 2009) [#4]

yes Wx :)

I got it to work now with the clock example but when I load an image it says its null
Is there a special way to load images?

Brucey

(Posted 2009) [#5]

Is there a special way to load images?

Think of it as a normal Max2D graphics context.

Anything you can do with Max2D, you can do here.
Remember though that you'll have to have a "live" graphics instance for images to "load".

One way around the issue of only being able to load images after you create your "Graphics" is to pre-load them into Pixmaps, then you can LoadImage(mypixmap) instead.

slenkar

(Posted 2009) [#6]

heres the code:

SuperStrict

Framework wx.wxApp
Import wx.wxPanel
Import wx.wxFrame
Import wx.wxButton
Import wx.wxTextCtrl
Import wx.wxListBox
Import wx.wxNotebook
Import wx.wxABoutBox
Import wx.wxtimer
Import wx.wxglmax2D


Type MyApp Extends wxApp

	Field frame:MyFrame

	Method OnInit:Int()

		frame = MyFrame(New MyFrame.Create(Null, -1, "myapp", 200, 200))
		
		SetTopWindow(frame)
		
		frame.show()
	
		Return True
	
	End Method

End Type


Type MyFrame Extends wxFrame

	Field notebook:wxNotebook
	Field listbox:wxListBox
	Field textlog:wxTextCtrl
	Field canvas:Mycanvas
	
	Const BOOKCTRL:Int = 100
	Const BUTTON1:Int = 101
	Const BUTTON2:Int = 102
	Const LISTBOX1:Int = 103
	Const TEXTBOX1:Int = 104
	Const FILE_QUIT:Int = wxID_EXIT
	Const HELP_ABOUT:Int = wxID_ABOUT

	Method OnInit()

		Local fileMenu:wxMenu = wxMenu.CreateMenu()
		Local helpMenu:wxMenu = wxMenu.CreateMenu()
		Local menuBar:wxMenuBar = wxMenuBar.CreateMenuBar()
		
		helpMenu.Append(HELP_ABOUT, "&About...~tF1", "Show about dialog")
		fileMenu.Append(FILE_QUIT, "E&xit~tAlt-X", "Quit this program")
		
		menuBar.Append(fileMenu, "&File")
		menuBar.Append(helpMenu, "&Help")

		SetMenuBar(menuBar)

		CreateStatusBar(2)
		SetStatusText("So far so good.", 0)
		SetStatusText("Welcome!", 1)


		' the notebook
		notebook = wxNotebook.CreateNotebook(Self, BOOKCTRL)
		
		' a panel
		Local panel:wxPanel = wxPanel.CreatePanel(notebook)
		
		' the first page
		notebook.AddPage(panel, "Tab1", True)
		
		' add buttons to the panel
		wxButton.CreateButton(panel, BUTTON1, "Button &1", 50, 30, 100, 30)
		wxButton.CreateButton(panel, BUTTON2, "Button &2", 50, 80, 100, 30)

		' a new panel
		panel = wxPanel.CreatePanel(notebook)
		
		
		canvas = MyCanvas(New MyCanvas.Create(panel, -1, GRAPHICS_BACKBUFFER|GRAPHICS_DEPTHBUFFER, 0,0, 350, 320))
		' add the second page
		notebook.AddPage(panel, "Tab2", False)
		
		' another new panel
		panel = wxPanel.CreatePanel(notebook)

		Local mysizer:wxBoxSizer = wxBoxSizer.CreateBoxSizer(wxVERTICAL)
		panel.SetSizer(mysizer)
		
		textlog = wxTextCtrl.CreateTextCtrl(panel, TEXTBOX1, "Log~n", 0, 250, 100, 50, wxTE_MULTILINE)
		mysizer.Add(textlog, 1, wxEXPAND | wxALL, 5)
		
		notebook.AddPage(panel, "Tab3", False)


		Connect(FILE_QUIT, wxEVT_COMMAND_MENU_SELECTED, OnQuit)
		Connect(HELP_ABOUT, wxEVT_COMMAND_MENU_SELECTED, OnAbout)
		Connect(BUTTON1, wxEVT_COMMAND_BUTTON_CLICKED, OnButton1)
		Connect(BUTTON2, wxEVT_COMMAND_BUTTON_CLICKED, OnButton2)
		Connect(LISTBOX1, wxEVT_COMMAND_LISTBOX_DOUBLECLICKED, OnListBoxDoubleClick)
	End Method	

	Function OnQuit(event:wxEvent)
		' true is to force the frame to close
		wxWindow(event.parent).Close(True)
	End Function
	
	
	Function OnButton1(event:wxEvent)
		wxMessageBox("Click1", "Click", wxOK | wxICON_INFORMATION, wxWindow(event.parent))
	End Function

	Function OnButton2(event:wxEvent)
		wxMessageBox("Click2 !!", "Click", wxOK | wxICON_INFORMATION, wxWindow(event.parent))
	End Function
	
	Function OnListBoxDoubleClick(event:wxEvent)
		MyFrame(event.parent).textlog.AppendText("ListBox Double click String is: ~n" + ..
			wxCommandEvent(event).GetString() + "~n")
	End Function
	
End Type

Type MyCanvas Extends wxGLCanvas

	Field map_pix:TPixmap
	Field map_img:TImage
	Field timer:wxTimer

	Method OnInit()
		SetBackgroundStyle(wxBG_STYLE_CUSTOM)
		
		DebugLog "init program"
		
		Local file$="armorback.jpg"
		
		If FileType(file)=1
		map_pix=LoadPixmap(file)
		DebugLog "loading "+file
		Else
		RuntimeError "file isnt there "+file
		EndIf
		
		If map_pix=Null 
		RuntimeError("pixmap didnt load "+file)
		EndIf
		
		timer = New wxTimer.Create(Self)
		ConnectAny(wxEVT_TIMER, OnTick)
		timer.Start(30)

	End Method

	Method OnPaint(event:wxPaintEvent)
		Local canvas:MyCanvas = MyCanvas(event.parent)

		SetGraphics CanvasGraphics2d(Self)
		
		SetColor(0, 0, 0)
		
		Cls

		canvas.drawmap()
		
		Flip

	EndMethod

	Function OnTick(event:wxEvent)
		wxWindow(event.parent).Refresh()
	End Function
	
	
	Method drawmap()
	DrawPixmap(map_pix,5,5)
	DebugLog "drawing pixmap"
	
	If map_img=Null
	DebugLog "loading image"
	map_img=LoadImage(map_pix)
	Else
	DrawImage(map_img,50,50)
	DebugLog "drawing image"
	EndIf
	
	End Method



End Type


New MyApp.run()

It doesnt seem to want to load a pixmap, map_pix is always NULL after trying to load a pixmap

Brucey

(Posted 2009) [#7]

Ah... yes.

You'll need to :

Import BRL.JPGLoader

Or whatever image loader you normally use (eg. BRL.PNGLoader, BaH.Magick, etc)

Brucey

(Posted 2009) [#8]

A small explanation about how "loaders" work.

At startup (of your application), each "loader" module announces itself to BlitzMax, and is added to a list of available loaders.

When it comes time to load something, each is tried in turn until one is able to successfully load the image.
If there are no loaders, or none of them can load the image, then the result of LoadPixmap/LoadImage is Null.

slenkar

(Posted 2009) [#9]

oops sorry about that, Im just not used to using a framework

EDIT- I tried changing the framework command to Import
but then it complained about some C++ header files

Brucey

(Posted 2009) [#10]

Practise makes perfect ;-)