TextAreaUndo mod

BlitzMax Forums/MaxGUI Module/TextAreaUndo mod

JoshK

(Posted 2007) [#1]

This was extremely difficult and time-consuming. It works just like it should, though:
http://www.leadwerks.com/index.php?page=downloads.htm&subbar=blank.htm

TextAreaUndo:Int(gadget:TGadget)
TextAreaRedo:Int(gadget:TGadget)
TextAreaCanUndo:Int(gadget:TGadget)
TextAreaCanRedo:Int(gadget:TGadget)
Function TextAreaFlushUndos:Int(gadget:TGadget)
TextAreaCreateUndoState()

If you manually alter the text area text with SetTextAreaText(), you must call TextAreaCreateUndoState() after the alterations, or your undos will be messed up. With this, TextAreas will only return a GADGETACTION event when they really have changed. EventData() will contain the length of the changed text, and may be a positive or negative number.

This only alters the changed text, so it has low memory usage, and is compatible with syntax highlighting.

Example program:

Import leadwerks.textareaundo

Strict 

Global window:TGadget
Global textarea:TGadget
Local menu:TGadget

window=CreateWindow("TextAreaUndo",200,200,640,480,,15|WINDOW_ACCEPTFILES)
textarea=CreateTextArea(0,0,ClientWidth(window),ClientHeight(window),window)
SetGadgetLayout textarea,1,1,1,1
ActivateGadget textarea
menu=CreateMenu("Edit",0,WindowMenu(window))
Global menuundo:TGadget=CreateMenu("Undo",1,menu,KEY_Z,MODIFIER_COMMAND)
Global menuredo:TGadget=CreateMenu("Redo",2,menu,KEY_Z,MODIFIER_COMMAND|MODIFIER_OPTION)
UpdateWindowMenu window

While WaitEvent()
	UpdateMenu()
	Select EventID()
		Case EVENT_MENUACTION
			Select EventData()
				Case 1
					TextAreaUndo textarea
				Case 2
					TextAreaRedo textarea
			EndSelect
		Case EVENT_WINDOWCLOSE
			End
		Case EVENT_APPTERMINATE
			End
	End Select
Wend

Function UpdateMenu()
	If TextAreaCanUndo(textarea)
		EnableMenu menuundo
	Else
		DisableMenu menuundo
	EndIf
	If TextAreaCanRedo(textarea)
		EnableMenu menuredo
	Else
		DisableMenu menuredo
	EndIf
	UpdateWindowMenu window
EndFunction

Mousey

(Posted 2007) [#2]

Just noticed this... many thanks Josh, a great piece of work.

JoshK

(Posted 2007) [#3]

Source:

'Rem
Module leadwerks.textareaundo

Import BRL.FileSystem
Import BRL.System
Import BRL.Win32MaxGUI
Import BRL.Retro


'EndRem

Private

Type TUndoContext
	Global list:TList=New TList
	
	Field link:TLink
	Field gadget:TGadget
	Field undostates:TList=New TList
	Field current:TUndoState
	Field change
	Field disabled

	Method New()
		link=list.addlast(Self)
	EndMethod
	
	Method CreateUndoState:TUndostate(force=0)
		If current current.clearafter
		undostate:TUndoState=New TUndoState
		undostate.context=Self
		undostate.link=undostates.addlast(undostate)
		undostate.selpos=TextAreaCursor(gadget)
		undostate.sellen=TextAreaSelLen(gadget)
		undostate.update
		undostate.force=force
		current=undostate
		Return undostate
	EndMethod
		
	Method CanUndo:TUndoState(undostate:TUndoState=Null)
		If undostate=Null undostate=current
		If undostate
			If undostate.link.prevlink()
				prevundostate:TUndoState=TUndoState(undostate.link.prevlink().value())
				If prevundostate.force=-1
					Return TUndoState(prevundostate.link.prevlink().value())
				Else
					Return prevundostate
				EndIf
			EndIf
		EndIf
		Return Null
	EndMethod
	
	Method CanRedo:TUndoState(undostate:TUndoState=Null)
		If undostate=Null undostate=current
		If undostate
			If undostate.link.nextlink()
				nextundostate:TUndoState=TUndoState(undostate.link.nextlink().value())
				If nextundostate.force=1
					Return TUndoState(nextundostate.link.nextlink().value())
				Else
					Return nextundostate
				EndIf
			EndIf
		EndIf
		Return Null
	EndMethod

	Method Undo:Int()
		If current
			If canundo()
				current.undo
				current=canundo()
				Return True
			EndIf
		EndIf
		Return False
	EndMethod

	Method Redo:Int()
		undostate:TUndoState=CanRedo()
		If undostate
			undostate.redo
			current=undostate
			Return True
		EndIf
		Return False
	EndMethod

	Method Flush()
		For undostate:TUndoState=EachIn undostates
			undostate.kill
		Next
		undostates.clear
		current=Null
		createundostate
	EndMethod
	
	Method Kill()
		flush
		undostates=Null
		gadget=Null
		RemoveLink link
		link=Null
	EndMethod

	Function Callback:Object(id:Int,data:Object,context:Object)
		Local event:TEvent=TEvent(data)
		Select event.id
			
			Case EVENT_GADGETSELECT
				For undocontext:TUndoContext=EachIn TUndoContext.list
					If event.source=undocontext.gadget
						If undocontext.current
							If Not undocontext.disabled
								If undocontext.current.text=TextAreaText(undocontext.gadget)
									undocontext.current.selpos=TextAreaCursor(undocontext.gadget)
									undocontext.current.sellen=TextAreaSelLen(undocontext.gadget)
									undocontext.current.removetext=TextAreaText(undocontext.gadget,undocontext.current.selpos,undocontext.current.sellen)
								EndIf
							EndIf
						EndIf
						Exit
					EndIf
				Next
			
			Case EVENT_GADGETACTION
				For undocontext:TUndoContext=EachIn TUndoContext.list
					If event.source=undocontext.gadget
						If Not undocontext.disabled
							If undocontext.current
								If undocontext.current.text=TextAreaText(undocontext.gadget) Return Null
							EndIf
							undostate:TUndoState=undocontext.createundostate()
							event.data=undostate.change
						EndIf
						Exit
					EndIf
				Next
				
		EndSelect
		Return data
	EndFunction
	
EndType

Function CreateUndoContext:TUndocontext(gadget:TGadget)
	undocontext:TUndoContext=New TUndoContext
	undocontext.gadget=gadget
	undocontext.createundostate
	Return undocontext
EndFunction

Type TUndostate
	Field link:TLink
	Field context:TUndoContext
	Field text$
	Field undotext$
	Field redotext$
	Field selpos
	Field sellen
	Field undolen
	Field undopos
	Field change
	Field force
	
	Field removetext$
	Field removeposition
	
	Field addtext$
	Field addposition

	Method Update()
		text$=TextAreaText(context.gadget)
		selpos=TextAreaCursor(context.gadget)
		sellen=TextAreaSelLen(context.gadget)
		
		removetext=TextAreaText(context.gadget,selpos,sellen)
		
		lastundostate:TUndoState=context.canundo(Self)
		If lastundostate
			change=text.length-lastundostate.text.length
			change=change+lastundostate.sellen
		Else
			change=text.length
		EndIf
				
		If change<0
			undopos=selpos
			undolen=-change
			If lastundostate
				undotext=Mid(lastundostate.text,undopos+1,-change)
			EndIf
		Else
			undopos=selpos-change
			undolen=change
			If lastundostate
				undotext=Mid(text,undopos+1,change)
			EndIf
		EndIf

	EndMethod

	Method Undo()
		start=TextAreaCursor(context.gadget)
		prevundostate:TUndoState=context.canundo(Self)
		nextundostate:TUndoState=context.canredo(Self)
		LockTextArea context.gadget
		If change>0
			SetTextAreaText context.gadget,"",undopos,undolen
		Else
			SetTextAreaText context.gadget,undotext,undopos,0
		EndIf
		UnlockTextArea context.gadget
		prevundostate:TUndoState=context.canundo(Self)
		If prevundostate		
			SetTextAreaText context.gadget,prevundostate.removetext,prevundostate.selpos,0
			SelectTextAreaText context.gadget,prevundostate.selpos,prevundostate.sellen
		Else
			SelectTextAreaText context.gadget,0,0
		EndIf
		
		stop=TextAreaCursor(context.gadget)
		size=Abs(start-stop)+TextAreaSelLen(context.gadget)
		context.disabled=True
		EmitEvent CreateEvent(EVENT_GADGETACTION,context.gadget,size)
		context.disabled=False
	EndMethod
	
	Method Redo()
		start=TextAreaCursor(context.gadget)
		prevundostate:TUndoState=context.canundo(Self)
		nextundostate:TUndoState=context.canredo(Self)
		LockTextArea context.gadget
		If change<0
			SetTextAreaText context.gadget,"",undopos,undolen
		Else
			If prevundostate l=prevundostate.sellen
			SetTextAreaText context.gadget,undotext,undopos,l
		EndIf
		UnlockTextArea context.gadget
		SelectTextAreaText context.gadget,selpos,sellen
		
		stop=TextAreaCursor(context.gadget)
		size=Abs(start-stop)+TextAreaSelLen(context.gadget)
		context.disabled=True
		EmitEvent CreateEvent(EVENT_GADGETACTION,context.gadget,size)
		context.disabled=False
	EndMethod
	
	Method ClearAfter()
		Local sublink:TLink
		Local nextsublink:TLink
		sublink=link.nextlink()
		While sublink
			nextsublink=sublink.nextlink()
			TUndoState(sublink.value()).kill
			sublink=nextsublink			
		Wend
	EndMethod
	
	Method Kill()
		If link.prevlink()
			current=TUndostate(link.prevlink().value())
		Else
			current=Null
		EndIf
		RemoveLink link
		link=Null
	EndMethod

EndType

AddHook EmitEventHook,TUndoContext.Callback

Function FindUndoContext:TUndoContext(gadget:TGadget)
	For undocontext:TUndoContext=EachIn TUndoContext.list
		If undocontext.gadget=gadget Return undocontext
	Next
	undocontext=CreateUndoContext(gadget)
	Return undocontext
EndFunction

Public

'Helper Functions
Function TextAreaUndo:Int(gadget:TGadget)
	Return FindUndoContext(gadget).undo()
EndFunction

Function TextAreaRedo:Int(gadget:TGadget)
	Return FindUndoContext(gadget).redo()
EndFunction

Function TextAreaCanUndo:Int(gadget:TGadget)
	Return (FindUndoContext(gadget).canundo()<>Null)
EndFunction

Function TextAreaCanRedo:Int(gadget:TGadget)
	Return (FindUndoContext(gadget).canredo()<>Null)
EndFunction

Function TextAreaFlushUndos:Int(gadget:TGadget)
	FindUndoContext(gadget).flush()
EndFunction

Function TextAreaCreateUndoState()
	FindUndoContext(gadget).createundostate
EndFunction