Spinner proxy gadget...advanced number editor

BlitzMax Forums/MaxGUI Module/Spinner proxy gadget...advanced number editor

JoshK

(Posted 2009) [#1]

This is probably one of the nicest pieces of code I have ever written:
http://blitzmax.com/codearcs/codearcs.php?code=2514

Maybe this can go in the official module?

Grisu

(Posted 2009) [#2]

Screenshots please... :D

degac

(Posted 2009) [#3]

I agree, made it officialy in the Proxygadgets

I've update your code with
- SetColor method
- SetEnable (for enable/disable the gadget)
- fixed SetSpinnerValue (you missed a '_' in the SetValue function)

I've tested on Win32, FLTK (win32 based) and they works as expected (they use 'standard' MaxGUI code, not OS specific calls)

SuperStrict

Import MaxGui.drivers'fltkmaxgui'Drivers

Local window:TGadget

window=CreateWindow("Spinner Example",40,40,320,240)

Local spinner:TSpinner
Local label:TGadget
Local x:Int=2,y:Int=2

label=CreateLabel("Float spinner:",x,y,200,18,window)
SetGadgetLayout label,1,0,1,0
y:+18
spinner=CreateSpinner(x,y,80,20,window)
SetSpinnerRange(spinner,0,1,2)
SetGadgetLayout spinner,1,1,1,0
y:+22

label=CreateLabel("Integer spinner with trackbar:",x,y,200,18,window)
SetGadgetLayout label,1,0,1,0
y:+18
spinner=CreateSpinner(x,y,300,20,window,SPINNER_TRACKBAR)
SetSpinnerRange(spinner,-1,1,0)
SetGadgetLayout spinner,1,1,1,0
y:+22
SetGadgetColor spinner,200,20,20

spinner=CreateSpinner(x,y,300,20,window,SPINNER_TRACKBAR)
SetSpinnerRange(spinner,-10,10,0)
SetSpinnerValue(spinner,-3)
SetGadgetLayout spinner,1,1,1,0

DisableGadget spinner

While True
	WaitEvent 
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	End Select
Wend




'-------------------------------------------------------------------

Const SPINNER_TRACKBAR:Int=1

Type TSpinner Extends TProxygadget
	
	Const SliderWidth:Int=18
	Const Div:Int=80
	
	Field panel:TGadget
	Field textfield:TGadget
	Field slider:TGadget
	Field trackbar:TGadget
	Field value:Double
	Field range:Double[2]
	Field accuracy:Int=1
	Field floatitemmultiplier:Double=10
	
	Method SetRange_(minimum:Double,maximum:Double,accuracy:Int=1)
		Self.accuracy=accuracy
		floatitemmultiplier=10.0^Double(accuracy)
		range[0]=minimum*floatitemmultiplier
		range[1]=maximum*floatitemmultiplier-range[0]+1
		SetSliderRange slider,1,range[1]
		If trackbar
			SetSliderRange trackbar,1,range[1]
		EndIf
		SetValue_(value)
	EndMethod
	
	Method SetColor(r:Int=255,g:Int=255,b:Int=255)
		SetGadgetColor textfield,r,g,b
	End Method
	
	Method SetEnabled(sta:Int=True)
		If sta=False
			DisableGadget panel
			DisableGadget textfield
			DisableGadget slider
			If trackbar DisableGadget trackbar
		Else
			EnableGadget panel
			EnableGadget textfield
			EnableGadget slider
			If trackbar EnableGadget trackbar
		End If
		
	End Method

	
	Method Cleanup()
		RemoveHook(EmitEventHook,EventHook,Self)
		Super.Cleanup()
	EndMethod
	
	Function Create:TSpinner(x:Int,y:Int,width:Int,height:Int,group:TGadget,flags:Int=0)
		Local spinner:TSpinner
		Local w:Int
		
		spinner=New TSpinner
				
		spinner.panel=CreatePanel(x,y,width,height,group)
		spinner.setproxy(spinner.panel)
		
		w=spinner.panel.ClientWidth()
		If (SPINNER_TRACKBAR & flags)
			w=div
			If w>spinner.panel.ClientWidth() w=spinner.panel.ClientWidth()
		EndIf
		
		spinner.textfield=CreateTextField(0,0,w-SliderWidth,spinner.panel.ClientHeight(),spinner.panel)
		If (SPINNER_TRACKBAR & flags)
			SetGadgetLayout spinner.textfield,1,0,1,1
		Else
			SetGadgetLayout spinner.textfield,1,1,1,1
		EndIf
		
		spinner.slider=CreateSlider(w-SliderWidth,0,SliderWidth,spinner.panel.ClientHeight(),spinner.panel,SLIDER_VERTICAL)		
		If (SPINNER_TRACKBAR & flags)
			SetGadgetLayout spinner.slider,1,0,1,1
		Else
			SetGadgetLayout spinner.slider,0,1,1,1
		EndIf
		AddHook(EmitEventHook,EventHook,spinner)
		
		If (SPINNER_TRACKBAR & flags)
			spinner.trackbar=CreateSlider(w,0,spinner.panel.ClientWidth()-w,spinner.panel.ClientHeight(),spinner.panel,SLIDER_TRACKBAR|SLIDER_HORIZONTAL)
			SetGadgetLayout spinner.trackbar,1,1,1,1
		EndIf
		
		spinner.SetRange_(0,1)
		Return spinner
	EndFunction
	
	Method SetValue_(i:Double)
		i=Max(i,range[0])
		i=Min(i,range[1])
		i=Round(i*floatitemmultiplier)/floatitemmultiplier
		i:*floatitemmultiplier
		If i<range[0] i=range[0]
		If i>range[0]+range[1]-1 i=range[0]+range[1]-1
		SetGadgetText textfield,FloatToString(i/floatitemmultiplier,accuracy)
		SetSliderValue slider,range[1]-(i-range[0]+1)
		If trackbar SetSliderValue trackbar,i-range[0]+1
		value=i
	EndMethod
	
	Function EventHook:Object(id:Int,data:Object,context:Object)
		Local event:TEvent
		Local spinner:TSpinner
		Local i:Int
		
		event=TEvent(data)
		If event
			spinner=TSpinner(context)
			If spinner
				Select event.id
				Case EVENT_GADGETLOSTFOCUS
					If event.source=spinner.textfield
						spinner.SetValue_(Double(GadgetText(spinner.textfield)))
						EmitEvent CreateEvent(EVENT_GADGETACTION,spinner)
						Return Null
					EndIf				
				Case EVENT_GADGETACTION
					Select event.source
					Case spinner.trackbar
						If spinner.trackbar
							i=(SliderValue(spinner.trackbar)+spinner.range[0]-1)
							spinner.SetValue_(i/spinner.floatitemmultiplier)
						EndIf
					Case spinner.textfield
						Return Null
					Case spinner.slider
						i=spinner.range[1]-(SliderValue(spinner.slider)-spinner.range[0]+1)
						spinner.SetValue_(Double(i)/spinner.floatitemmultiplier)
						EmitEvent CreateEvent(EVENT_GADGETACTION,spinner)
						Return Null
					EndSelect
				EndSelect
			EndIf
		EndIf
		Return data
	EndFunction
	
	Function Round:Int(val:Double)
		Local dec#
		dec#=val-Floor(val)
		If dec<0.5 Return Floor(val) Else Return Ceil(val)
	EndFunction	
	
	Function FloatToString:String(value:Float,places:Int=3)
		Local sign:Int=Sgn(value)
		value=Abs(value)
		Local i:Int=Round(value*10^places)
		Local ipart:Int=Int(i/10^places)
		Local dpart:Int=i-ipart*10^places
		Local si$=ipart
		Local di$
		If dpart>0
			di=dpart
			While di.length<places
				di="0"+di
			Wend
			di="."+di
		EndIf
		While Right(di,1)="0"
			di=Left(di,di.length-1)
		Wend
		If places
			If di="" di=".0"
		EndIf
		If sign=-1 si="-"+si
		Return si+di
	EndFunction	
	
EndType

Rem
bbdoc:
EndRem
Function CreateSpinner:TSpinner(x:Int,y:Int,width:Int,height:Int,group:TGadget,flags:Int=0)
	Return TSpinner.Create(x,y,width,height,group,flags)
EndFunction

Rem
bbdoc:
EndRem
Function SetSpinnerRange(spinner:TSpinner,minimum:Double,maximum:Double,accuracy:Int=1)
	spinner.SetRange_(minimum,maximum,accuracy)
EndFunction

Rem
bbdoc:
EndRem
Function SetSpinnerValue(spinner:TSpinner,value:Double)
	spinner.SetValue_(value)
EndFunction

Rem
bbdoc:
EndRem
Function SpinnerValue:Double(spinner:TSpinner)
	Return spinner.value
EndFunction

Edit: an a little changes to SetSpinnerRange...not very important, but...

Function SetSpinnerRange(spinner:TSpinner,minimum:Double,maximum:Double,accuracy:Int=1)
	spinner.SetRange_(minimum,maximum,accuracy)
	SetGadgetToolTip spinner.textfield,"Min: "+spinner.FloatToString(Minimum,3)+"~nMax: "+spinner.FloatToString(Maximum,3)
EndFunction

So the user can SEE what is the range...

JoshK

(Posted 2009) [#4]

I don't think you should set the tooltip like that. If someone wants a tooltip, they will specify one. Otherwise, you should not guess what the user might want.

Mark Tiffany

(Posted 2009) [#5]

Agreed, should at least have a check to make sure it isn't already set as it might be useful if you haven't bothered setting a tooltip...

degac

(Posted 2009) [#6]

Ok, this is a possible fix

Method SetToolTip(tt$)
		Local prev$=gettooltip()
		SetGadgetToolTip textfield,tt+"~n"+prev
End Method
	
Method GetToolTip$()
		Return textfield.Gettooltip()
End Method
...
Function SetSpinnerRange(spinner:TSpinner,minimum:Double,maximum:Double,accuracy:Int=1)
	spinner.SetRange_(minimum,maximum,accuracy)
	
	Local prev$=spinner.GetToolTip()
	If prev<>"" prev=prev+"~n"
	
	SetGadgetToolTip spinner.textfield,prev+"Min: "+spinner.FloatToString(Minimum,3)+"~nMax: "+spinner.FloatToString(Maximum,3)
EndFunction

So the user-tooltip is save.
In any case my was only a suggestion: if you have a window full of this controls I think is useful for the user know what he/she's changing..

JoshK

(Posted 2009) [#7]

I think if the programmer wants a tooltip they should specify one themselves. You could add a label below the minimum and maximum extents of the track bar.

JoshK

(Posted 2009) [#8]

Updated the code.