Pivot picking bug

BlitzMax Forums/MiniB3D Module/Pivot picking bug

Difference

(Posted 2008) [#1]

Using the lastest version, 0.51 - 10/05/08
In class tPick

in function

Function Pick:TEntity(ax:Float,ay:Float,az:Float,bx:Float,by:Float,bz:Float,radius:Float=0.0)

the line

pick=C_Pick(c_col_info,c_line,radius,c_col,c_tform,tree,ent.pick_mode)

crashes with a "Unhandled Exeption:Unhandled memory Exeption Error", when the picked entity is an Pivot.

Pickmode is set with EntityPickMode(2) on an entity that contains one pivot( parent), and one mesh (child).

Difference

(Posted 2009) [#2]

Bump

Here is code reproduce in ver 0.531
Pick where the box used to be, to see it crash.

A quick fix in tPick:

If ent.pick_mode=0 Or ent.Hidden()=True Or piv.class$="Pivot" Then Continue

But then pivots are unpickable

'Import "../minib3d.bmx"
Import sidesign.minib3d
Strict

Local width=640,height=480,depth=16,mode=0

Graphics3D width,height,depth,mode

Local cam:TCamera=CreateCamera()
PositionEntity cam,0,0,-15

Local light:TLight=CreateLight()
RotateEntity light,45,0,0

Local marker:TMesh=CreateSphere()
ScaleEntity marker,0.2,0.2,0.2
EntityColor marker,255,0,0

Local sphere:TMesh=CreateSphere()
EntityRadius sphere,1
EntityPickMode sphere,1
PositionEntity sphere,-10,0,0

Local mesh:TMesh=LoadMesh("media/teapot.b3d")
EntityPickMode mesh,2
ScaleEntity mesh,4,4,4

Local box:TPivot=CreatePivot()
'FitMesh box,-2,-1,-1,4,2,2
EntityBox box,-2,-1,-1,4,2,2
EntityPickMode box,2
PositionEntity box,10,0,0

' used by fps code
Local old_ms=MilliSecs()
Local renders
Local fps

While Not KeyDown(KEY_ESCAPE)		

	If KeyHit(KEY_ENTER) Then DebugStop

	' control camera
	MoveEntity cam,KeyDown(KEY_D)-KeyDown(KEY_A),0,KeyDown(KEY_W)-KeyDown(KEY_S)
	TurnEntity cam,KeyDown(KEY_DOWN)-KeyDown(KEY_UP),KeyDown(KEY_LEFT)-KeyDown(KEY_RIGHT),0
	
	TurnEntity mesh,0,1,0

	' if mousedown then perform camerapick
	Local pick:TEntity
	If MouseDown(1)
	
		' reset entity colors
		EntityColor sphere,255,255,255
		EntityColor mesh,255,255,255
		EntityColor box,255,255,255

		pick:TEntity=CameraPick(cam,MouseX(),MouseY())
		
		If pick<>Null
			EntityColor pick,255,255,0
			PositionEntity marker,PickedX(),PickedY(),PickedZ()
		EndIf
	
	EndIf

	RenderWorld
	renders=renders+1

	' calculate fps
	If MilliSecs()-old_ms>=1000
		old_ms=MilliSecs()
		fps=renders
		renders=0
	EndIf
	
	Text 0,0,"FPS: "+fps
	
	If pick<>Null
		Text 0,20,"Picked!"
	Else
		Text 0,20,"Not Picked"
	EndIf

	Flip

Wend
End

Difference

(Posted 2009) [#3]

Btw: Pickmode 3, does not have this problem.

SLotman

(Posted 2009) [#4]

On TPick.bmx where you see:

	
pick=C_Pick(c_col_info,c_line,radius,c_col,c_tform,tree,ent.pick_mode)
			
If pick
	picked_ent=ent
EndIf

make it:

		
If tree<>Null Then
   pick=C_Pick(c_col_info,c_line,radius,c_col,c_tform,tree,ent.pick_mode)		
   If pick 
      picked_ent=ent
   EndIf
End If

It should work. Don't know if pivots are picked or not, but at least your sample doesn't crash anymore here...

Difference

(Posted 2009) [#5]

Thanks Slottman for finding the reason.
Looking into it, I now suggest a slightly different fix.

In tPick.bmx, Function Pick()

change If TMesh(ent)<>Null section slightly, by adding an elseif

This will allow pivot box picking and fix the crash:

			If TMesh(ent)<>Null
				TMesh(ent).col_tree.TreeCheck(TMesh(ent)) ' create collision tree for mesh if necessary
				tree=TMesh(ent).col_tree.c_col_tree
			ElseIf ent.pick_mode = 2	' skip pivots with pickmode 2
				Continue
			EndIf