Renderworld is destroying my meshes

BlitzMax Forums/MiniB3D Module/Renderworld is destroying my meshes
JBR	(Posted 2009) [#1]
Try this, hold down the RightShift and watch the bottom right for inconsistent triangles.

I'm doing a shadow render from above and then a normal one for the scene. I don't alter the alien mesh but the second render messes up.

Help!
Strict
Import sidesign.minib3d

Graphics3D 1024,768,32,0
'---------------------------------------------------------------------------------------------------------------------------------------------------------------------------
'CONSTANTS
'-------------------
Const C_PA_Width:Int	= 180		' maxes out triangles
Const C_PA_Depth:Int	= 180

Const C_Nodes_Max:Int = 360

'----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
'CAMERA STUFF
'------------------------
Global G_Camera:TCamera	= CreateCamera()
Global G_Camera_Pivot:TPivot	= CreatePivot()

Global G_Camera_Z#		= 158.0
Global G_Camera_Y#		= 387.0
Global G_Camera_X# 	= C_PA_Width/2
Global G_Camera_Angle#	= 116

PositionEntity 	G_Camera_Pivot, C_PA_Width/2, C_PA_Depth/2, 0	' position pivot
EntityParent 	G_Camera, G_Camera_Pivot					' make parent the pivot
CameraZoom	G_Camera, 3.5

Global G_Shadow_Camera:TCamera	= CreateCamera()
	CameraProjMode( G_Shadow_Camera, 2 )					' orthogonal
	CameraClsColor( G_Shadow_Camera, 255,255,255 )			' cls colour black
	CameraZoom G_Shadow_Camera    , 1/(Float(C_PA_Width)/2)	' don't know why
	CameraViewport( G_Shadow_camera, 0,0,512,512 )			' set the viewport for texture size

	TurnEntity G_Shadow_Camera, 180,0,0
	PositionEntity G_Shadow_Camera, C_PA_Width/2, C_PA_Depth/2, 128	' just a high height


cameraclsmode( G_Camera, True, True )
cameraclsmode( G_Shadow_Camera, True, True )

Global G_Texture1:TTexture = CreateTexture( 512, 512, 1+256 )
Global G_Texture2:TTexture = CreateTexture( 512, 512, 1+256 )

ScaleTexture G_Texture2, 1.0, -1.0

	BEGINMAX2D()
		SetClsColor(0,0,0)
		Cls
		SetColor( 255,255,255 )
		DrawOval( 0,0, 512,512 )
	ENDMAX2D()
	BackBufferToTex( G_Texture1 )
'----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
'GLOBALS
'---------------
Global G_Wave_X# = 0.0
Global G_Wave_Y# = 0.0

Global G_TLX:Float = 0.0	' the Top_Left x,y
Global G_TLY:Float = 0.0

Global G_PA_Mesh:TMesh = CreateMesh:TMesh()
Global G_Sea_Surf:TSurface = CreateSurface:TSurface( G_PA_Mesh )			' the sea

	EntityFX( G_PA_Mesh, 2+4 )
	EntityTexture( G_PA_Mesh, G_Texture1, 0, 0 )
	EntityTexture( G_PA_Mesh, G_Texture2, 0, 1 )


init_PA_Mesh()			' creates the vertices & triangles for this mesh (ground and sea)


'-----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
'INITIALISE
'---------------
Global G_MC_ANG# = 0.0
Global G_MC_RWX# =  90.0
Global G_MC_RWY# = 90.0
Global G_MC_INCX# = 0.0
Global G_MC_INCY# = 0.0



Local v0,v1,v2 : Int



Global G_MyCraft_Mesh:TMesh = CreateMesh:TMesh()
Global G_MyCraft_Surf:TSurface = CreateSurface:TSurface( G_MyCraft_Mesh )
EntityFX G_MyCraft_Mesh, 2+4+16+32

v0 = AddVertex( G_MyCraft_Surf, -4, -4, 0 )
v1 = AddVertex( G_MyCraft_Surf,  4,  0, 0 )
v2 = AddVertex( G_MyCraft_Surf, -4,  4, 0 )

AddTriangle( G_MyCraft_Surf, v0,v1,v2 )
VertexColor G_MyCraft_Surf, v0, 127,127,0, 0.5

v0 = AddVertex( G_MyCraft_Surf,  -4,  0, 3 )
v1 = AddVertex( G_MyCraft_Surf,   4,  0, 0 )
v2 = AddVertex( G_MyCraft_Surf,  -4,  0, 0 )

AddTriangle( G_MyCraft_Surf, v0,v1,v2 )
VertexColor G_MyCraft_Surf, v0, 127,0,0


'--------------------------
'--------------------------










'---------------------------------------------------------------------------------------------------------------------------
Global A_Plot_Data:Int[ 1024*1024 ]			' 1024 alien plot data
	For Local i:Int=0 To 1024*1024-1
		A_Plot_Data[i] = $ffffffff
	Next
'--------------------------------------------------------------------------------------------------------------------------

Type T_Alien
	Field num		:Int
	Field rwx		:Float
	Field rwy		:Float
	Field angle 	:Float
	Field plot_num	:Int
	Field mesh		:TMesh
	Field surf		:TSurface
End Type

'------------------------------------------------------------------------------------------------------------------------------

Global A_Alien:T_Alien[64]
	For Local i:Int=0 To 63
		A_Alien:T_Alien[i] = New T_Alien
		A_Alien[i].num = 0
		A_Alien[i].rwx# = Rnd(0,180)
		A_Alien[i].rwy# = Rnd(0,180)
		A_Alien[i].angle# = Rnd(0,360)
		A_Alien[i].plot_num = 0
		A_Alien[i].mesh = CreateMesh:TMesh()
		A_Alien[i].surf = CreateSurface:TSurface(A_Alien[i].mesh)
		EntityFX A_Alien[i].mesh, 2+4
	Next

'------------------------------------------------------------------------------------------------------------------------------
Function plott_aliens()
	For Local a:Int = 0 To 63
		If A_Alien[a].num <> -1 Then
			
			Local plot_index:Int = A_Alien[a].plot_num * 1024		' 1024 shorts handled by BMAX
			
			ClearSurface(A_Alien[a].surf)
			
			Local rwx:Float = A_Alien[a].rwx
			Local rwy:Float = A_Alien[a].rwy
			
			Local cos_a:Float = Float(Cos(A_Alien[a].angle))
			Local sin_a:Float = Float(Sin(A_Alien[a].angle))

			For Local y:Float = -15.5 To 15.5
				For Local x:Float = -15.5 To 15.5
				
					Local pix:Int = 1'A_Plot_Data:Int[ plot_index ]
					'plot_index = plot_index + 1
					
					If pix <> 0 Then	' we have a live pixel
					
						Local rot_x:Float = rwx + (x*cos_a) - (y*sin_a)			' = rw coords of the rotated pixel
						Local rot_y:Float = rwy + (x*sin_a) + (y*cos_a)
						
						Local dist:Float = Sqr( (G_MC_RWX# - rot_x)*(G_MC_RWX# - rot_x) + (G_MC_RWY# - rot_y)*(G_MC_RWY# - rot_y) )
						
						If dist < 90.0 Then
							
							Local h:Float = 13.0 '+ Max( sea_height( rot_x, rot_y ), ground_height(rot_x, rot_y ) )
						
							Local v0:Int = AddVertex( A_Alien[a].surf, x-0.5, y-0.5, 		h )
							Local v1:Int = AddVertex( A_Alien[a].surf, x+0.5, y-0.5, 		h )
							Local v2:Int = AddVertex( A_Alien[a].surf, x+0.5, y+0.5, 		h )
							Local v3:Int = AddVertex( A_Alien[a].surf , x-0.5, y+0.5, 	h )
							
							AddTriangle( A_Alien[a].surf, v0,v1,v2 )
							AddTriangle( A_Alien[a].surf, v0,v2,v3 )
							
							VertexColor A_Alien[a].surf, v0, 255,0,0
							
						EndIf
					EndIf
				Next
			Next
			RotateEntity( A_Alien[a].mesh, 0,0, A_Alien[a].angle )
			PositionEntity( A_Alien[a].mesh, A_Alien[a].rwx-G_TLX#, A_Alien[a].rwy-G_TLY#, 0.0 )
			A_Alien[a].angle = A_Alien[a].angle '+ 0.5
		EndIf
	Next
End Function









'-----------------------------------------------------------------------------------
' MAIN LOOP


Repeat
	adjust_camera()
	
	G_Wave_X# = G_Wave_X# + 1
	G_Wave_Y# = G_Wave_Y# + 3

	'----------- do mycraft first
	If KeyDown(KEY_Z) Then G_MC_ANG# = G_MC_ANG# - 1.0
	If KeyDown(KEY_X) Then G_MC_ANG# = G_MC_ANG# + 1.0
	If KeyDown(KEY_RSHIFT) Then
		G_MC_INCX# = G_MC_INCX# + 0.1 * Cos(G_MC_ANG#)
		G_MC_INCY# = G_MC_INCY# + 0.1 * Sin(G_MC_ANG#)
	EndIf
	
	G_MC_RWX# = G_MC_RWX# + G_MC_INCX#
	G_MC_RWY# = G_MC_RWY# + G_MC_INCY#
	
	G_MC_INCX# = G_MC_INCX# * .95
	G_MC_INCY# = G_MC_INCY# * .95


	G_TLX# = G_MC_RWX# - (C_PA_Width/2)
	G_TLY# = G_MC_RWY# - (C_PA_Depth/2)


	PositionEntity G_MyCraft_Mesh, G_MC_RWX# - G_TLX#, G_MC_RWY# - G_TLY#, sea_height#( G_MC_RWX#, G_MC_RWY# )+16
	RotateEntity G_MyCraft_Mesh, 0,0,G_MC_ANG#





	For Local y:Int = 0 To 30
		For Local x:Int = 0 To 30
	
			Local h# = sea_height#( (x*6+G_TLX#) , (y*6+G_TLY#) )

			G_Sea_Surf.VertexCoords( y*31+x,                     x*6, y*6, h# )
			G_Sea_Surf.VertexColor(  y*31+x,                        0,0,255+63*(h#-3.0) )
		
		Next
	Next

'	SHADOWS then ACTUAL SCENE

	plott_aliens()	

	HideEntity G_Camera
	HideEntity G_PA_Mesh
	ShowEntity G_Shadow_Camera
	AmbientLight 0,0,0
		RenderWorld
		BackBufferToTex( G_Texture2 )
		
	HideEntity G_Shadow_Camera
	ShowEntity G_Camera
	ShowEntity G_PA_Mesh
	
'	plott_aliens()

	AmbientLight 127,127,127
		RenderWorld

	Flip

Until KeyHit(KEY_ESCAPE)

FlushKeys()
WaitKey()
End







'-------------------------------------------------------------------------
Function adjust_camera()
	If KeyDown(KEY_NUM4) Then G_Camera_Z# = G_Camera_Z# + 1		' height
	If KeyDown(KEY_NUM1) Then G_Camera_Z# = G_Camera_Z# - 1

	If KeyDown(KEY_NUM5) Then G_Camera_Y# = G_Camera_Y# +1		' distance away
	If KeyDown(KEY_NUM2) Then G_Camera_Y# = G_Camera_Y# -1

	If KeyDown(KEY_NUM6) Then G_Camera_Angle# = G_Camera_Angle# + 1	' angle
	If KeyDown(KEY_NUM3) Then G_Camera_Angle# = G_Camera_Angle# - 1

	RotateEntity	G_Camera_Pivot,0,0,0	' get pivot back to start so we can safely move the camera
	
	RotateEntity	G_Camera, G_Camera_Angle#, 0, 0
	PositionEntity	G_Camera, G_Camera_X#, G_Camera_Y#, G_Camera_Z#, True		' relative to 0,0,0

End Function
'----------------------------------------------------------------------
Function init_PA_Mesh()
	For Local y:Int = 0 To 30													' then the sea
		For Local x:Int = 0 To 30
			G_Sea_Surf.AddVertex( 0, 0, 0,        Float(x)/30.0, Float(y)/30.0 )
		Next
	Next
	For Local y:Int = 0 To 30-1
		For Local x:Int = 0 To 30-1
			Local a:Int = (x+0)+((y+0)*(30+1))
			Local b:Int = (x+1)+((y+0)*(30+1))
			Local c:Int = (x+1)+((y+1)*(30+1))
			Local d:Int = (x+0)+((y+1)*(30+1))
			G_Sea_Surf.AddTriangle( a,b,c )
			G_Sea_Surf.AddTriangle( a,c,d )
		Next
	Next
End Function
'----------------------------------------------------------------------------------------------------
'-----------------------------------------------------------------------------------------------------
Function sea_height:Float( rwx:Float, rwy:Float )					' can be any rw coords

	Return 3.0+(1.25*Cos(rwx#+G_Wave_X#)+ 1.25*Sin(rwy#+G_Wave_Y#) )

End Function
'-------------------------------------------------------------------------------------------------------
Thanks
Jim
JBR	(Posted 2009) [#2]
Initially I thought is was my HD4850 card but I got a replacement from Dell and just the same. I also tried an HD4350 but just the same.

If you do test it can you say what GC you use.

Thanks
Jim