Blitzmax + LUA

BlitzMax Forums/BlitzMax Programming/Blitzmax + LUA

Cocopino

(Posted 2015) [#1]

Hi!

I am trying to interact with my program by changing a separate LUA file. This example program will load a lua script from a file named "script.lua" once I press F5:

Strict

Type TDemo
	Method SayHello:String(name:String)
		Notify "Hello " + name + "! Peace be with you..."
	End Method
	
	Method LoadLuaSource:String(file:String)

		If FileType(file) <> 1 Return ""
		
		Local fs:TStream = OpenStream(file, True, False)
		Local source:String = fs.ReadString(FileSize(file))
		fs.Close()
		Return source
		
	End Method
	
End Type

Local demo:TDemo = New TDemo
LuaRegisterObject(demo, "Demo")
Local luaFile:String = "script.lua"

Graphics(1024, 768)
While Not KeyHit(KEY_ESCAPE)

	If KeyHit(KEY_F5)
	
		Local source:String = demo.LoadLuaSource(luaFile)
		
		Local class:TLuaClass = TLuaClass.Create(source)
		Local instance:TLuaObject = TLuaObject.Create(class, Null)
			
		If instance = Null
			Local debuginfo:String = "???"
			Notify("Error: " + debuginfo, True)
		Else
			instance.Invoke "hello", Null
			instance.Invoke "goodbye", Null
		EndIf
		
	End If

	Cls()
	SetColor(255, 255, 255)
	DrawText("Press F5 to load script.lua", 10, 10)
	Flip(1)

Wend
End

script.lua:

function hello()
	print(Demo.SayHello('Fredward'))
end

function goodbye()
	print(Demo.SayHello('Stingray Sam'))
end

Now, that this even works at all is pretty magical to me :)
But if I create a typo/error in script.lua, I can only see the error in the debugger. Is there a way to catch the error and display it to the user (e.g. in a MessageBox/Notify)?

Thanks!

Cocopino

(Posted 2015) [#2]

I "hacked" brl.maxlua to achieve the above:

...
Type TLuaClass
	Method GetLuaState:Byte Ptr()
		Return LuaState()
	End Method
...
End Type

In Method lua_pushchunk() I disabled line

'lua_pop L,1

to keep the error on the stack

Now I can use


If instance = Null
	Local debuginfo:String = lua_tostring(class.GetLuaState(), -1)
	Notify("Error: " + debuginfo, True)

PhotonTom

(Posted 2015) [#3]

I've not used brl.maxlua but I find Pub.lua and lugi (http://www.blitzbasic.com/Community/posts.php?topic=85902) to be a very good combination.

For example using Pub.lua you can get compile errors using:

Result = lua_pcall(Lua, Inputs, Outputs, 0)
If (Result <> 0) then
	Print("Lua Runtime Error: ~n" + luaL_checkstring(Lua, - 1) )
EndIf

Cocopino

(Posted 2015) [#4]

Thanks, I will look into that!