Slider Issues?

BlitzMax Forums/BlitzMax Programming/Slider Issues?

Caton

(Posted March) [#1]

Import MaxGui.Drivers
cpwin=CreateWindow("Control Panel",0,0,320,240)
CreateLabel("X",1,3,12,12,cpwin)
sli=CreateSlider(117,0,16,20,cpwin,SLIDER_STEPPER)
While Not AppTerminate()
WaitEvent()
Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	End Select
DebugLog(SliderValue(sli))
Wend
End

It seems to start five and only go to 10. and how can I get it to use cont up by float instead of int.

Just found out you must use the range function but how to use cont by floats like 0.5

degac

(Posted March) [#2]

Hi

you need to use SetSliderRange(min, max) and SetSliderValue(value) to determine the limits and the starting value

' createslider.bmx

Import MaxGui.Drivers

Strict 

Local window:TGadget=CreateWindow("My Window",0,0,240,240,,WINDOW_TITLEBAR)


Local stepper:TGadget
stepper=CreateSlider(100,120,24,24,window,SLIDER_STEPPER)
Local lbl_stepper:Tgadget=CreateLabel("Value:  ---",10,120,80,24,window)
			

SetSliderRange stepper,0,9
SetSliderValue stepper,0


While WaitEvent()
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_GADGETACTION
			Select EventSource()
				Case stepper
						SetGadgetText lbl_stepper,"Value: "+SliderValue(stepper)
			
			End Select
		
		Case EVENT_WINDOWCLOSE
			End
	End Select
Wend

Stepper values are always (internally) as Integer.
You should need to change the range and manage the SliderValue() in a different way

Import MaxGui.Drivers

Strict 

Local window:TGadget=CreateWindow("My Window",0,0,240,240,,WINDOW_TITLEBAR)


Local stepper:TGadget
stepper=CreateSlider(150,120,30,30,window,SLIDER_STEPPER)
Local lbl_stepper:Tgadget=CreateLabel("Value:  ---",10,120,120,30,window)
			

SetSliderRange stepper,0,99 '<--- see the new range
SetSliderValue stepper,0

While WaitEvent()
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_GADGETACTION
			Select EventSource()
				Case stepper
						
						SetGadgetText lbl_stepper,"Value #" +Float(SliderValue(stepper))/10 '<--- see this count
			
			End Select
		
		Case EVENT_WINDOWCLOSE
			End
	End Select
Wend

cps	(Posted March) [#3]

I assume you have come across the image freezing as you drag the scroll bar. There is a really good thread on using event hooks for scrolling, that gets round this problem. The following is based on that thread.
NOTE: This is based on work done by others in the forum, on a thread that I can't remember the name of.
'Current.JPG' is a 1200 by 900 pixel image. If your image is a different size set the variables 'CanvasWidth' and 'CanvasHeight' to match your image size.

SuperStrict
Import MaxGui.Drivers
Local Temp1%=0; Local Temp2%=0
Local MyDir$=CurrentDir()
Local Pix:TPixmap=LoadPixmap(Mydir+"\current.jpg")
Local MyWindow:TGadget=CreateWindow("Scrolling Canvas Example",  100, 10, 400,430)
Local MyPanel:TGadget=CreatePanel(30, 20, 320, 240, MyWindow, PANEL_ACTIVE|PANEL_BORDER)
Local CanvasHeight:Int=900
Local CanvasWidth:Int=1200
Local But1:Tgadget=CreateButton("xval",300,300,50,30,Mywindow)
Local MyCanvas:TGadget=CreateCanvas(0, 0, CanvasWidth, CanvasHeight, MyPanel)
Local VScroller:TGadget=CreateSlider(GadgetWidth(MyPanel)+30, 20, 20, GadgetHeight(MyPanel), MyWindow, SLIDER_VERTICAL)
Local HScroller:TGadget=CreateSlider(30,GadgetHeight(MyPanel)+20, GadgetWidth(MyPanel), 20, MyWindow, SLIDER_HORIZONTAL)
SetSliderRange VScroller, GadgetHeight(MyPanel), CanvasHeight
SetSliderRange HScroller, GadgetWidth(MyPanel), CanvasWidth
ActivateGadget MyCanvas
SetGraphics CanvasGraphics(MyCanvas)
SetAlpha(1) 
SetMaskColor 255,255,255' adjust for best images !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
Cls
Flip
DrawPixmap Pix,0,0
Flip
Local zz:hookcon =New hookcon ' scroll bars
zz.initilise(HScroller,VScroller,MyCanvas)
AddHook EmitEventHook, hookcon.FilterEvent, zz' scroll bars
CreateTimer 60
Repeat
	Delay 10 ' allow other apps some cycles to minimize CPU use
	PollEvent
  	Select EventID()
 	Case EVENT_WINDOWCLOSE
     	End
	Case EVENT_TIMERTICK
		RedrawGadget(MyCanvas)	
	Case EVENT_GADGETPAINT
		zz.DoDraw()		
  	 Case EVENT_MOUSEDOWN
		Select EventData()
			Case 1' left click
				Print "X = "+EventX()+"   Y = "+EventY()		
				'Temp1=GameHex.GetHexNum(EventX(),EventY())' temp1 = Hex number				
			Case 2' right click(not on a mac)
				Temp1=EventX()+zz.getpicx(); Temp2=EventY()+zz.getpicy()
				Print "X = "+Temp1+"   Y = "+Temp2									
		End Select			
	Case EVENT_GADGETACTION
		Select EventSource()
			Case But1 Print zz.getpicx()	
		End Select	
   	End Select
   	SetStatusText MyWindow, "ImgX="+zz.getpicx()+", ImgY="+zz.getpicy()
Forever

Type hookcon' hook for scroll bars to move image in the canvas
	Global Gad:TGadget[3]' number of gadgets in use
	Global PicX%; Global PicY%' x and y for image in canvas displacement
	Method initilise(Tv0:Tgadget,Tv1:Tgadget,Tv2:Tgadget)
		Gad[0]=Tv0'Hscroll
		Gad[1]=Tv1'Vscroll
		Gad[2]=Tv2'canvas that contains the game board
		PicX=0; PicY=0' x and y displacement of image/board due to scroll bars	
	End Method
Function FilterEvent:Object(iId:Int,tData:Object,tContext:Object)
  		Local Event:TEvent=TEvent(tData)
  		If Event.source=Gad[0] And Event.ID=EVENT_GADGETACTION
			PicX=event.data 
			DoDraw()		   
    	 	Return Null
  		Else If Event.source=Gad[1] And Event.ID=EVENT_GADGETACTION
    	   	PicY=event.data     
			DoDraw()		
     		Return Null
		Else
	 		Return tData
		EndIf
	End Function
	Function DoDraw()
			SetGraphics CanvasGraphics(Gad[2])
  			SetGadgetShape Gad[2],-PicX, -PicY,GadgetWidth(Gad[2]),GadgetHeight(Gad[2])	
			Flip
	End Function
	Method GetPicX%()' get curent X displacement
		Local T1%=PicX; Return T1
	End Method
	Method GetPicY%()
		Local T1%=PicY; Return T1' get curent Y displacement
	End Method
End Type

Have fun cps