How do you get pub.freeprocess to read i/o ??

Framework brl.standardio
Import pub.freeprocess

Local temp_process:TProcess = CreateProcess("cmd.exe /c ~qipconfig~q")
Local temp_read:String

Print "started"
While temp_process.status()
	temp_read = temp_process.pipe.readline()
	Print "read = @"+temp_read+"@"
Wend
temp_process.close()
temp_process.terminate()
temp_process = Null
Print "ended"

SuperStrict

Framework brl.standardio
Import pub.freeprocess

?Win32

	'Lets use OO for the hell of it, although you can use CreateProcess() if you prefer
	'There is only 1 flag available - HIDECONSOLE that is supposed to hide console output ;-) but it doesn't make much difference either way on my Windows machine
	Local temp_process:TProcess = TProcess.Create("net start THIS_SERVICE_DOESNT_EXIST",HIDECONSOLE)
	
	Print ""
	Print "IPConfig Status: " + temp_process.Status()	'Show that the program is running
	Print "================================"
	
	While temp_process.Status()	'Checks to see if the process is still running
		
		'Temp variable that stores output from the pipe before it is converted to a string
		Local tmpBytes:Byte[]
		'Check if the pipe contains any data that hasn't been read and if so, load data into variable array, and convert array to string
		If temp_process.pipe.ReadAvail() Then tmpBytes = temp_process.pipe.ReadPipe();Print String.FromBytes( Varptr tmpBytes[0], tmpBytes.length )
		
	Wend
	

		
	'Terminate process manually (the fact that is has escaped the above loop means it has already closed but put it in as an example)
	temp_process.Close()
	'This is a quick way you can terminate all processes without bothering to loop through them all (again not needed)
	TProcess.TerminateAll()
	
	Print "================================"
	Print "IPConfig Status: " + temp_process.Status()	'Show that the program has ended
	Print ""

?MacOs

	Print "Mac OS X doesn't have IpConfig."

?Linux

	Print "Linux doesn't have IpConfig."

?

SuperStrict

Framework brl.standardio
Import pub.freeprocess

Local temp_process:TProcess = CreateProcess("ipconfig /?",HIDECONSOLE)
Local temp_read:String, avail:Int

Print "started"
Repeat
	' loop until data available.  In practice of course you would be doing other things.
	Repeat 
		avail = temp_process.pipe.readavail()
		If temp_process.status()=0 Then Exit
	Until avail>0

	Print "Status "+temp_process.status()
	Print "Avail "+avail
 	
	If avail=0 Then Exit

	' get available data
	Repeat
			temp_read  = temp_process.pipe.readline()

			Print temp_process.pipe.bufferpos +" read >"+temp_read

	Until temp_process.pipe.bufferpos<=0
Forever
temp_process.close()
temp_process.terminate()
temp_process = Null
Print "ended"

Import pub.freeprocess

Type tproc Extends TProcess
	Method close:Int()
		super.close()
		terminate()
	End Method

	Method avail:Int()
		Return err.bufferpos Or err.readavail() Or pipe.bufferpos Or pipe.readavail()
	End Method
	
	Method read:String()
		If err.bufferpos > 0 Or err.readavail() > 0 Return err.ReadLine().Replace("~r","").Replace("~n","")
		If pipe.bufferpos > 0 Or pipe.readavail() > 0 Return pipe.ReadLine().Replace("~r","").Replace("~n","")
	End Method

	Method readpipe:String()
		If pipe.bufferpos > 0 Or pipe.readavail() > 0 Return pipe.ReadLine().Replace("~r","").Replace("~n","")
	End Method
	
	Method readerr:String()
		If err.bufferpos > 0 Or err.readavail() > 0 Return err.ReadLine().Replace("~r","").Replace("~n","")
	End Method
	
	Method pipeavail:Int()
		Return pipe.bufferpos Or pipe.readavail()
	End Method
	
	Method erravail:Int()
		Return err.bufferpos Or err.readavail()
	End Method
	
	Method Eof:Int()
		If status() = 1 Return False
		If pipe.readavail() > 0 Return False
		If err.readavail() > 0 Return False
		If pipe.bufferpos > 0 Return False
		If err.bufferpos > 0 Return False
		Return True
	End Method

	Function Create:TProc(ncmd:String,nflags:Int)
		Local temp_proc:TProc
		Local infd,outfd,errfd	
		
		'do mac speciffic stuff
		?MacOS
		If FileType(ncmd)=2
			ncmd :+ "/Contents/MacOS/" + StripExt(StripDir(ncmd))
		EndIf
		?
		
		'create the proc object
		temp_proc = New TProc
		
		'setup the proc
		temp_proc.name = ncmd
		
		'attempt to start the process
		temp_proc.handle = fdProcess(ncmd,Varptr(infd),Varptr(outfd),Varptr(errfd),nflags)
		If Not temp_proc.handle Return Null
		
		'creat teh process pipes
		temp_proc.pipe = TPipeStream.Create(infd,outfd)
		temp_proc.err = TPipeStream.Create(errfd,0)
		
		'add process to process list
		If Not ProcessList ProcessList = New TList
		ProcessList.AddLast temp_proc
		
		'return the proc object
		Return temp_proc
	End Function
End Type

Function CreateProc:tproc(ncmd:String,nhidden:Int = True)
	Return tproc.create(ncmd,nhidden)
End Function

Local temp_proc:tproc = CreateProc("net start MOO_MOO_MOO")
While temp_proc.eof() = False
	If temp_proc.avail() Print "read: " + temp_proc.read()
Wend
temp_proc.close()

Local temp_proc:tproc = CreateProc("net start MOO_MOO_MOO")
While temp_proc.eof() = False
	If temp_proc.pipeavail() Print "pipe: " + temp_proc.readpipe()
	If temp_proc.erravail() Print "err: " + temp_proc.readerr()
Wend
temp_proc.close()