Asynchronous loading best practice

BlitzMax Forums/BlitzMax Programming/Asynchronous loading best practice

Robb	(Posted 2012) [#1]

Just wondering if anyone can suggest the best way of implementing asynchronous loading into a Blitzmax app.

I don't intend to be streaming environments into a game as it is played, rather just display animated screens whilst the level resources (xml, images and sounds) are loaded.

To me the simple option seems like I should display the animation in the main app thread and wait for a separate thread to load in the resources.

Is this the standard approach in Blitzmax?
Alternatively, would it better to implement an incremental loading class using bankstreams (such as Beaker's 'nibbler' in the code archives).

I'm sure each method has its pros and cons but I thought I'd see what the community opinion was.

BlitzSupport

(Posted 2012) [#2]

I don't know about the best way, but this is one way...


' SAVE INTO "BlitzMax\samples\threads" BEFORE RUNNING!

' -----------------------------------------------------------------------------
' MAKE SURE "Threaded Build" IS CHECKED IN THE Program -> Build Options menu!
' -----------------------------------------------------------------------------





' -----------------------------------------------------------------------------
' Loading screen...
' -----------------------------------------------------------------------------

AppTitle = "Multi-threaded loading screen demo..."

' -----------------------------------------------------------------------------
' This is used to simulate slower loading in the LoadImages thread...
' -----------------------------------------------------------------------------

Global TestDelay = 1000 ' Simulating more/larger images, 3D models, etc...

' -----------------------------------------------------------------------------
' Array setup...
' -----------------------------------------------------------------------------

Global images:Int = 6			' Number of images to be loaded

Global image:TImage [images]		' Image handles for loading thread

Global imagename:String [images]	' Filenames

	imagename [0] = "bluboing.png"
	imagename [1] = "bluegem.png"
	imagename [2] = "boing.png"
	imagename [3] = "dead.png"
	imagename [4] = "greengem.png"
	imagename [5] = "redgem.png"

' -----------------------------------------------------------------------------
' Set up display...
' -----------------------------------------------------------------------------

Graphics 640, 480
SetClsColor 32, 96, 128
SetMaskColor 255, 0, 255
AutoMidHandle True

' -----------------------------------------------------------------------------
' Start the LoadImages thread...
' -----------------------------------------------------------------------------

thread:TThread = CreateThread (LoadImages, Null)

' -----------------------------------------------------------------------------
' This is the loading screen! Some movement and colours while images load...
' -----------------------------------------------------------------------------

r = 0; g = 255; b = 127

' -----------------------------------------------------------------------------
' Do this routine until the thread has finished its work...
' -----------------------------------------------------------------------------

While ThreadRunning (thread) ' Important!

	Cls

	r = r + 8; If r > 255 Then r = 0
	g = g - 4; If g > 255 Then g = 0
	b = b + 2; If b > 255 Then b = 0

	SetColor 0, 0, 0	
	DrawRect MouseX (), MouseY (), 32, 32

	SetColor r, g, b
	DrawRect MouseX (), MouseY (), 30, 30

	SetColor 0, 0, 0
	DrawText "Slow-ding, please wait...", 20, 20
	SetColor 255, 255, 255
	DrawText "Slow-ding, please wait...", 18, 18

	Flip

Wend

' -----------------------------------------------------------------------------
' Right, the thread has finished!
' -----------------------------------------------------------------------------

' Just re-setting colours, 'scuse me...

r = 255; g = 255; b = 255
SetColor r, g, b

' -----------------------------------------------------------------------------
' Yay... into the main game! Woo! Fun!
' -----------------------------------------------------------------------------

Repeat

	Cls
	
	x = 0
	y = 0

	SetRotation ang#; ang = ang + 1; If ang > 360 Then ang = 0
	
	' Draw all images in array...
	
	For p = 0 To images - 1
		DrawImage image [p], x, y
		x = x + 96
		y = y + 96
	Next

	SetRotation 0

	SetColor 0, 0, 0	
	DrawRect MouseX (), MouseY (), 32, 32
	SetColor 255, 255, 255
	DrawRect MouseX (), MouseY (), 30, 30
	
	SetColor 0, 0, 0	
	DrawText "All done! We're in-game now! Fun, fun, fun...", 20, 20
	SetColor 255, 255, 255
	DrawText "All done! We're in-game now! Fun, fun, fun...", 18, 18

	Flip
	
Until KeyHit (KEY_ESCAPE)

End

' -----------------------------------------------------------------------------
' The threaded image loading function...
' -----------------------------------------------------------------------------

' No mutexes are needed here since the global arrays are only accessed by
' the main program before and after this thread is finished...

Function LoadImages:Object (data:Object)

	' Iterate through the global Map...
	
	For p = 0 To images - 1
	
		' Load images into global image [] array...

		image [p] = LoadImage (imagename [p])
		
		' Fake delay to simulate loading bigger images for this demo!
		
		Delay TestDelay
		
	Next

End Function

I seem to recall we found loading images directly in the thread like this was fine, but this came from an older example that loaded pixmaps in the thread to play it safe, then called LoadImage on each afterwards. Pretty sure that's not actually necessary.

The "nibbler" thing is very clever though -- hadn't seen that before:

Media file 'Nibbler' [bmax]

Last edited 2012

kfprimm

(Posted 2012) [#3]

I believe I have read that it is not safe to do rendering (or messing with the video card) on any thread but the main.

I'd suggest you do as BlitzSupport's example does, but instead of loading the images, just load them as pixmaps (they are totally graphics API independent), and then feed them into LoadImage after everything is in memory and the loading thread as has finished.

Last edited 2012

BlitzSupport

(Posted 2012) [#4]

load them as pixmaps (they are totally graphics API independent), and then feed them into LoadImage after everything is in memory and the loading thread as has finished

@kfprimm: That's what I used to do (see here), but it was pointed out elsewhere (by Gfk I believe) that LoadImage doesn't actually touch the graphics card -- you can confirm this by looking at "max2d.mod/image.bmx".

It's only when you actually call DrawImage that it's uploaded to the graphics card, via TImage.Frame (). The example above only calls DrawImage in the main thread; using LoadImage in the child thread is fine as long as you don't try to draw.

Robb	(Posted 2012) [#5]

Thanks for the replies.

Seems like I'll go with the threaded option. I was aware that graphics could only be drawn on the main thread, but it is nice to know that it is safe to load timages on the secondary one!