Looking for help from other programmers

; Memory! - CS_TBL 2010
;
; 
; 12 icons, individual size in this particular image appears to be 120x101
Global icons=12
Global image=LoadAnimImage("c:\Bplus\vector-icons.png",120,101,0,icons)
Global tablewidth=6 ; table size should be the amount of icons*2
Global tableheight=4
Global imw=ImageWidth(image)
Global imh=ImageHeight(image)
Global opencards
Global clicks

SeedRnd MilliSecs()

window=CreateWindow("Match",48,48,imw*tablewidth,imh*tableheight,0,1+32)
Global canvas=CreateCanvas(0,0,ClientWidth(window),ClientHeight(window),window)

; make back of a card ******************************************************************************
Global cardback=CreateImage(imw,imh)
SetBuffer ImageBuffer(cardback)
	ClsColor 160,128,128:Cls
	For t=0 To 1023
		r#=Rnd(.75,1.25)
		Color 160*r,128*r,128*r
		Rect Rnd(imw),Rnd(imh),4,4
	Next
	Color 224,224,224
	Rect 0,0,2,imh
	Rect 0,0,imw,2
	Rect 0,imh-2,imw,2
	Rect imw-2,0,2,imh
	
; make back of the table ***************************************************************************
Global tableback=CreateImage(64,64)
SetBuffer ImageBuffer(tableback)
For t=0 To 63
	r#=Rnd(-.2,.2)
	Color 192+32*r,128+32*r,32+32*r
	Line 0,t,63,t
Next

; the deck o' cards ********************************************************************************
Dim table(tablewidth*tableheight)



	
SetBuffer DesktopBuffer()

Resettable
Update

Repeat
	WaitEvent()
	Game
	If EventID()=$803 Exit
Forever
SetBuffer DesktopBuffer()
End

Function Game()
	x=EventX()/imw
	y=EventY()/imh
	
	If EventID()=$201 ; mousedown
		clicks=clicks+1
		If table(x+y*tablewidth)<0
			table(x+y*tablewidth)=table(x+y*tablewidth)*-1
			opencards=opencards+1
			If opencards=2
				opencards=0
				Update
				If Check()=0
					Notify "W000t!  All this in "+clicks+" clicks! Next plz.."
					ResetTable
				EndIf
				Delay 2000
				
			EndIf
		EndIf
		Update
	EndIf
End Function

Function Check()
	
	While Not found
		If table(i)>0 found=1	
		i=i+1
	Wend
	card1=i-1
	found=0
	
	While Not found
		If table(i)>0 found=1	
		i=i+1
	Wend
	card2=i-1
	
	If table(card1)=table(card2) ; match!
		table(card1)=0
		table(card2)=0
	Else ; no match ._.
		table(card1)=table(card1)*-1
		table(card2)=table(card2)*-1
	EndIf
	
	For t=0 To tablewidth*tableheight-1
		total=total+table(t)
	Next
	
	Return total
End Function

Function Update()
	SetBuffer CanvasBuffer(canvas)
		TileImage tableback
		For y=0 To tableheight-1
			For x=0 To tablewidth-1
				Select Sgn(table(x+y*tablewidth))
					Case -1 DrawBlock cardback,x*imw,y*imh
					Case  1 DrawBlock image,x*imw,y*imh,table(x+y*tablewidth)-1
				End Select
			Next
		Next
	FlipCanvas canvas
End Function

Function Resettable()
	i=1
	clicks=0
	For y=0 To tableheight*tablewidth-1 Step 2
		table(y+0)=-i
		table(y+1)=-i
		i=i+1
	Next
	Shuffletable
End Function

Function Shuffletable()
	For t=0 To (tablewidth*tableheight)*30
		i1=Rnd(tablewidth*tableheight-1)
		i2=Rnd(tablewidth*tableheight-1)
		s=table(i1)
		table(i1)=table(i2)
		table(i2)=s
	Next
End Function