Irrlicht 1.8.1 for Blitz

; A EXAMPLE OF PUTTING THINGS TOGETHER(Castle with Clouds above!)
;; Converted to Blitzplus and Irrlicht 1.8.1 by AquaLung (2013)

;; ////////////////////////////////////////////////////////////////////////////
;; Includes for extension libraries
Include "bIrrlicht.bp"

;; ////////////////////////////////////////////////////////////////////////////
;; global variables

; irrlicht objects
Global BSPMesh%
Global BSPNode%

; irrlicht objects
Global Terrain%
Global TerrainNode%
Global TerrainTexture0%
Global TerrainTexture1%
Global Camera%
Global CameraNode%
Global CloudTexture%
Global CloudNode%
Global X#
Global Y#
Global Z#
Global TerrainHeight#


;; ////////////////////////////////////////////////////////////////////////////
; start the irrlicht interface
iIrr3D( 800, 600, 32, False )

; send the window caption
iAppTitle( "Example 05: BSP Map" )

; first we add the pk3 archive to our filing system. once we have done this
; we can open any of the files in the archive as if they were in the current
; working directory
iAddZipFile( "./media/map-20kdm2.pk3", IRR_IGNORE_CASE, IRR_IGNORE_PATHS )

; load the BSP map from the archive as a mesh object. any polygons in the mesh
; that do not have textures will be removed from the scene!
BSPMesh = iLoadOctreeMesh( "20kdm2.bsp" )

; add the map to the scene as a node. when adding the mesh this call uses a 
; mechanism called an octtree that if very efficient at rendering large amounts
; of complext geometry most of which cant be seen, using this call for maps
; will greatly improve your framerates
BSPNode = iAddOctreeMeshNode( BSPMesh )

; add a first person perspective camera into the scene that is controlled with
; the mouse and the cursor keys. if however you capture events when starting
; irrlicht this will become a normal camera that can only be moved by code
Camera = iCreateFPSCamera(0,100.0,0.5,-1,0,0,0,0.0)

; the clipping distance of a camera is a distance beyond which no triangles are
; rendered, this speeds the scene up by not showing geometry that is in the
; distance and too small to see however our terrain is so huge we need to
; extend this distance out
iCameraRange( Camera, 12000, 1.0 )


; reposition and rotate the camera to look at a nice part of the map
iPositionNode( Camera, 1750, 149, 1369 )
iRotateNode( Camera, 4, -461.63, 0 )


; load the cloud image in as a video texture
CloudTexture = iLoadTexture( "./media/cloud4.png" )

; add the clouds to the scene
; the first parameter is the level of detail, higher values add more structure
; to the cloud when it is closer to the camera
; the second parameter sets the number of child clouds created higher values
; create more structure
; the third parameter defines how many clouds are created
CloudNode = iCreateClouds( CloudTexture, 3, 1, 500 )

; switch the fog on the clouds to prevent the clouds popping up in the distance
iNodeMaterialFlag( CloudNode, IRR_EMF_FOG_ENABLE, True )

; raise the clouds into the sky
iPositionNode( CloudNode, 0,2700,0 )

; slowly rotate the clouds to simulate drift across the sky
iRotationAnimator( CloudNode, 0, 0.01, 0 )

; add a fog to the scene to gently fade the clouds out in the distance
iCameraFog ( 128,128,255, IRR_EXPONENTIAL_FOG, 0.0,4000.0, 0.5 )

; hide the mouse pointer
iHideMouse()

; erase the canvas with sky-blue Before rendering
iCameraCLSColor( 128, 255, 255 )

; -----------------------------------------------------------------------------
; while the irrlicht environment is still running
While iRun() And (Not iKeyHit( KEY_ESCAPE ))
    ; begin the scene
    iBeginScene()

    ; draw the scene
    iDrawScene()

    ; end drawing the scene and display it
    iEndScene()
Wend

; -----------------------------------------------------------------------------
; Stop the irrlicht engine and release resources
iEndIrr3D()


End