Code archives/Audio/freeaudio streaming

' freestream16.bmx

' stereo 16 bit streaming example

Strict

Import pub.freeaudio

Const FRAG=1024

Print "freestream is free streaming..."

fa_Init(0)	' brl.freefreeaudio usually does this

Local buffer:Int[FRAG*8]
Local writepos

Local sound
Local channel

sound=fa_CreateSound( FRAG*8,16,2,44100,buffer,$80000000)
Print "Sound:"+sound

channel=fa_PlaySound( sound, FA_CHANNELSTATUS_STREAMING ,0)
Print "PlaySound:"+channel

Local streaming
Local lfo#
Local osc1#

While True
'	Print "Status:"+fa_ChannelStatus( channel )	
	Local readpos=fa_ChannelPosition( channel )
	Local write=readpos+FRAG*4-writepos
	Local frags=write/FRAG	
	While frags>0	
		Print "Write to "+writepos
		Local pos=writepos Mod (FRAG*8)
		For Local f=0 Until frag				
			Local t=writepos+f	
			lfo=Sin(0.001*t)
			osc1=Sin(t*(lfo+2))

 		Local l16=$ffff & Int(1000*lfo*osc1)
 		Local r16=$ffff & Int(2000*Sin(t))
	
			buffer[pos+f]=L16|(R16 Shl 16)

		Next
		writepos:+FRAG
		frags:-1
	Wend
	
	If Not streaming And writepos>=FRAG*4
		fa_SetChannelPaused( channel, False )
		streaming=True
	EndIf
	
	Print "."	

	Delay 50
Wend

' freestreamogg.bmx
' streaming stereo 16 bit OGG decoder to freeaudio 

Strict

Import pub.freeaudio
Import pub.oggvorbis

Type TAudioStream
	Const FRAG=8000

	Field buffer:Int[FRAG*8]
	Field writepos
	
	Field sound
	Field channel
	Field streaming
	
	Method PlayStereo16(freq)
		sound=fa_CreateSound( FRAG*8,16,2,freq,buffer,$80000000)
		Print "Sound:"+sound		
		channel=fa_PlaySound( sound, FA_CHANNELSTATUS_STREAMING ,0)
		Print "Channel:"+channel
		streaming=False
	End Method
	
	Method Poll()
		Local readpos=fa_ChannelPosition( channel )
		Local write=readpos+FRAG*4-writepos
		Local frags=write/FRAG	

		While frags>0	
			Print "Write to "+writepos
			Local pos=writepos Mod (FRAG*8)
			Local res=ReadBuffer(Byte Ptr(buffer)+pos*4,FRAG*4)
			Print "ReadBuffer="+res
			writepos:+FRAG
			frags:-1
		Wend
			
		If Not streaming And writepos>=FRAG*4
			fa_SetChannelPaused( channel, False )
			streaming=True
		EndIf
	End Method

	Method ReadBuffer%(buffer:Byte Ptr,bytes)
	End Method
End Type

Type TOggStream Extends TAudioStream
	
	Field source:Object
	Field stream:TStream
	Field ogg:Byte Ptr

	Field samples
	Field channels
	Field freq
	Field size

	Method Open( url:Object )
		source=url
		stream=ReadFile(url)
		ogg=Decode_Ogg(stream,readfunc,seekfunc,closefunc,tellfunc,samples,channels,freq)
		size=samples*2*channels		
		PlayStereo16(freq)
	End Method
		
	Method ReadBuffer%(buffer:Byte Ptr,bytes)	
		If Not ogg Return		
		If bytes>size bytes=size
		If bytes=0 Return 0
		Local err=Read_Ogg( ogg,buffer,bytes )
		If err Return -1
		size:-bytes
'		If size=0 Open source
		Return bytes
	End Method

	Function readfunc( buf@Ptr,size,nmemb,src:Object )
		Local bytes=TStream(src).Read(buf,size*nmemb)
		Return bytes/size
	End Function
	
	Function seekfunc( src_obj:Object,off0,off1,whence )
		Local off
		Local src:TStream=TStream(src_obj)
		off=off0	'WARNING 32 bit BADNESS
		Local res=-1
		Select whence
			Case 0
				res=src.Seek(off)			'SEEK_SET
			Case 1
				res=src.Seek(src.Pos()+off)	'SEEK_CUR
			Case 2
				res=src.Seek(src.Size()+off)	'SEEK_END
		End Select
		If res>=0 Return 0
		Return -1
	End Function
	
	Function closefunc( src:Object )
	End Function
	
	Function tellfunc( src:Object )
		Return TStream(src).Pos()
	End Function

End Type

fa_Init(0)	' brl.freefreeaudio usually does this

Local ogg:TOggStream

ogg=New TOggStream

ogg.Open("bouncy.ogg")

Print "ogg.size="+ogg.size+" ogg.channels="+ogg.channels+" ogg.freq="+ogg.freq

Print "freestream is free streaming..."

While True
	ogg.Poll
	Print "."	
	Delay 50
Wend

ogg$ = "xyz.ogg"
sound:TSound = LoadSound (ogg$)
PlaySound sound
Delay 5000