Weird graphical bugs on procedural mesh :/

Community Forums/General Help/Weird graphical bugs on procedural mesh :/

neoshaman

(Posted 2016) [#1]

I'm programming the base of a terrain engine but the code is having some inexplicable bugs I don't understand:

here is the main body

Include "function library.bb"

Graphics3D 800,600,0,2
SetBuffer BackBuffer()

;------------------------------------------- scene
cam = CreateCamera ()
PositionEntity cam, 0,1,-25

l1 = CreateLight (1)
RotateEntity l1, 45,45,0

plane = CreatePlane ()
PositionEntity plane, 0,-8,0
EntityColor plane, 64,32,16

center = CreateSphere (3)
PositionEntity center, 0,0,0
ScaleEntity center, 1,1,1
EntityColor center, 255,0,0

tt = CreateSphere (3)
PositionEntity tt, 0,0,0
ScaleEntity tt, 1,1,1
EntityColor tt, 0,64,0

plan = makeplane(3,3)
tex=LoadTexture( "testure.jpg" )
EntityTexture plan,tex
PositionEntity center, -4,0,0

WireFrame 0;True
;------------------------------------------- loop

While Not KeyDown(1)
	controlentity(cam)

	;refresh
	UpdateWorld 1
	RenderWorld 1

;*****************************************************
	;showjoystate()
	Text 0,0, "x: "+EntityX(cam) +"  y: "+EntityY(cam) +"  z: "+EntityZ(cam)
	Text 0,20, CountVertices (GetSurface (plan,1))
	Text 0,40, CountTriangles (GetSurface (plan,1))
;*****************************************************




	VWait:Flip False
	
Wend
ClearWorld

I'm doing nothing fancy but the first bug is that the sphere tt seems to be parented to the procedural plane (declared AFTER it) for no good reason at all. He has the same coordinate than the sphere declared above yet it's not at the same place :/ wat?

Now the plane is procedurally generated using this included function:


Function makePlane(size_x,size_y, tilesize=1, axis=1, center=1)
	
	size_x = size_x+1
	size_y = size_y+1
	
	; row enumeration (size_x)
	size_total = size_x * size_y -1
	
	plane = CreateMesh()
	surface = CreateSurface (plane)
		
	;center = 0 -> corner, center = 1 -> center offset	
	offset = 0
	offset_u = 0
	offset_v = 0
	
	For i=0 To size_total -1;
;Stop
	;generate vertex position, depend on axis x=0, y=1, z=2
		x# = offset + ( i Mod size_x )	*tilesize
		y# = offset + ( i/size_x )		*tilesize
		z# = offset
		
		u# = offset_u + x / tilesize / (size_x-1) ;
		v# = offset_v + y / tilesize / (size_x-1) ;
		w# = 0
	
		AddVertex (surface, x,y,z,  u,v,w)
	
	;generate triangle
		
		w1 = i
		w2 = i+1
		w3 = i+size_x +1
		w4 = i+size_x 
		
		If i Mod size_x = size_x-1 Then Goto skip
		If i => size_total-size_x Then Goto skip
					
		AddTriangle (surface, w1,w3,w2)
		AddTriangle (surface, w1,w4,w3)
	
		.skip	
		
	Next	
	
	UpdateNormals plane
	
	Return plane

End Function

Nothing fancy, but worse I made a prototype of the same code without function and it has worked flawlsessly until now. I'm totally at loss because now the final corner is folded on it's back with the first vertices :/

https://www.dropbox.com/s/sg5tx6afmkcon7i/Capture%20d%27%C3%A9cran%202016-11-24%2022.27.08.png?dl=1

grable

(Posted 2016) [#2]

makePlane has a -1 on Y when calculating the total size, which is probably a mistake.

And there looks to be a typo when your positioning the procedural plane, using "center" instead of "plan".

neoshaman

(Posted 2016) [#3]

Wow that was fast ... Thanks it is solved!

Yep :/ how did I miss that for 3 days straight I don't know, I'm ashamed of myself

RustyKristi

(Posted 2016) [#4]

Yep :/ how did I miss that for 3 days straight I don't know, I'm ashamed of myself

Don't sweat it neoshaman, nobody is perfect.. :-)