Fluffoidz

	Method Bounce(target:TBouncySprite)
		If Not self.DisableCollisions And Not target.DisableCollisions
			Local vx1:Float = self.velocityX()
			Local vy1:Float = self.velocityY()
			Local vx2:Float = target.velocityX()
			Local vy2:Float = target.velocityY()
			
			Local dx:Float = self.x - target.x
			Local dy:Float = self.y - target.y
			
			Local distance:Float = Sqr((dx * dx) + (dy * dy))
			' Unit vector in the direction of the collision
			Local ax:Float = dx / distance
			Local ay:Float = dy / distance
			' Projection of the velocities in these axes
			Local va1:Float = (vx1 * ax) + (vy1 * ay)
			Local vb1:Float = (-vx1 * ay) + (vy1 * ax)
			Local va2:Float = (vx2 * ax) + (vy2 * ay)
			Local vb2:Float = (-vx2 * ay) + (vy2 * ax)
			' New velocities in these axes (after collision): ed<=1, For elastic collision ed=1
			Local ed:Float = 1.0
			Local vaP1:Float = va1 + (1 + ed) * (va2 - va1) / (1 + (self.mass * self.scale) / (target.mass * target.scale))
			Local vaP2:Float = va2 + (1 + ed) * (va1 - va2) / (1 + (target.mass * target.scale) / (self.mass * self.scale))
			' Undo the projections
			vx1 = (vaP1 * ax) - (vb1 * ay)
			vy1 = (vaP1 * ay) + (vb1 * ax)
			vx2 = (vaP2 * ax) - (vb2 * ay)
			vy2 = (vaP2 * ay) + (vb2 * ax)
					
			self.velocity = Sqr((vx1 * vx1) + (vy1 * vy1))
			
			If self.velocity > self.MaxVelocity
				self.velocity = self.MaxVelocity
			EndIf
			
			If vy1 <> 0
				self.direction = ATan(vx1 / vy1)
			Else
				self.direction:+180
			EndIf
				
			If (vx1 < 0 And vy1 < 0) Or (vx1 < 0 And vy1 > 0)
				self.direction:+180
			EndIf
			
			' Ensure direction is between 0 and 360
			self.CorrectDirection()
			
			target.velocity = Sqr((vx2 * vx2) + (vy2 * vy2))
			
			If target.velocity > self.MaxVelocity
				target.velocity = self.MaxVelocity
			EndIf
			
			If vy2 <> 0
				target.direction = ATan(vx2 / vy2)
			Else
				target.direction:+180
			EndIf
		
			If (vx2 < 0 And vy2 < 0) Or (vx2 < 0 And vy2 > 0)
				target.direction:+180
			EndIf
			
			' Ensure direction is between 0 and 360
			target.CorrectDirection()
			
			If self.velocity + target.velocity + distance < self.CollisionRadius() + target.CollisionRadius()
				Local modV:Float = (self.CollisionRadius() + target.CollisionRadius() - self.velocity - target.velocity - distance) / 2
				'self.velocity:+(modV + self.MinVelocity)
				'target.velocity:+(modV + target.MinVelocity)
				self.x:+(modV*Cos(self.direction))
				self.y:+(modV*Sin(self.direction))
				
				target.x:+(modV*Cos(target.direction))
				target.y:+(modV*Sin(target.direction))
			EndIf
			
			self.SkipMovement = True
			target.SkipMovement = True		
		EndIf
		
		self.CollisionCount:+1
		target.CollisionCount:+1
	End Method