Shake Detection

Monkey Forums/Monkey Code/Shake Detection

NoOdle

(Posted 2011) [#1]

As the title says, this will detect a shake.

Import mojo

Class MyApp Extends App

	Field r : Int
	Field g : Int
	Field b : Int
	
	Field shakeCnt : Int = 0
	Field shakeStart : Int

	'number of shakes to detect	
	Field shakeMax : Int = 4
	
	'time in millisecs that shake has to occur withing
	Field shakeTmr : Int = 1500
	
	'minimum velocity of the movement to detect
	Field shakeVel : Float = 2.0

	
	Method OnCreate()
		SetUpdateRate 60
	End
	
	
	Method OnUpdate()
	
		'if time has elapsed, reset timer and shake count
		If Millisecs() - shakeStart > shakeTmr
			Self.shakeCnt = 0
			Self.shakeStart = Millisecs()
		Endif
		
		'if accel has has been detected
		If Abs( AccelX ) > Self.shakeVel Or Abs( AccelY ) > Self.shakeVel Or Abs( AccelZ ) > Self.shakeVel
			
			'increment shake count
			Self.shakeCnt = Self.shakeCnt + 1
			
			'if shake count has reached 4
			If Self.shakeCnt > Self.shakeMax
			
				'reset the shake count and the timer
				Self.shakeCnt = 0
				Self.shakeStart = Millisecs()

				'do something
				Self.r = Rnd( 0, 255 )
				Self.g = Rnd( 0, 255 )
				Self.b = Rnd( 0, 255 )

			Endif
		Endif
	End
	

	Method OnRender()
		Cls Self.r, Self.g, Self.b
	End
End

Function Main()
	New MyApp
End

matt	(Posted 2011) [#2]

Thanks for this. I'll try it out soon.

NoOdle

(Posted 2011) [#3]

Its very basic, it could be improved by checking if the last shaken velocity was in the opposite direction, but this seems to work fine.

matt	(Posted 2011) [#4]

It might be more useful as an importable module/class?

NoOdle

(Posted 2011) [#5]

yea it probably would, need to work on a gesture module soon but too busy trying to finish my current game. If only I had more me's! :P