Simple Button Class

Monkey Forums/Monkey Code/Simple Button Class

AdamRedwoods

(Posted 2011) [#1]

This is for basic, simple needs.
I know there are some snazzy button classes out there, but I don't know where I saw them.

This uses an image's width, height (no rotation) for the click extents. If you draw in on the OnRender(), then it's active. You don't draw it, it's not active.

I'm sure I could enhance this by extending the Image Class, but for now, it's fine.

USEAGE:

''pseudocode

Class Game Extends App

  OnCreate()
    button:CButton = New CButton
    button.SetFlashColor(250,150,150) ''optional

  OnUpdate()
    CButton.OnUpdate() ''always needed

    if button.isClick
       DoSomething()
    endif

  OnRender()
     CButton.OnRender() ''always needed

     button.Draw(anyimage,x,y,0,scalex,scaley)

     If button.LastButtonPressed()
        DrawImage(popup_menu,x,y)

simplebutton.monkey


Class CButton
	''notes:
	''- does not calculate rotated bounding box
	''- Flash color is not so great for HTML5
	''
	Global objlist:List<CButton> = New List<CButton>
	Global drawcycle:Int =0 '' this will tell us if there's been a render call
	Field img:Image
	
	Field enabled:Int ''enabled last time this was drawn
	Field x:Int, y:Int, w:Int, h:Int, hx:Int, hy:Int
	Field isDown:Int
	Field isClick:Int 
	Global clickCount:Int =0 ''global so we can reset it, only tracks the same button pressed repeatedly
	
	Private
	
	Global b:CButton
	Field internalClick:Int =0
	Field visible:Int
	Field flashcolor:Int=0
	Field showFlash:Int =0
	Field fr:Int, fg:Int, fb:Int
	Field clickhold:Int=0
	Global draglock:Int=0
	Global pressedbutton:CButton
	
	Public
	
	Function GetLastButton:CButton()
		Return pressedbutton
	End
	
	Method LastButtonPressed:Int()
		If Self = pressedbutton Then Return 1
		Return 0
	End
	
	Function ResetClicks()
		clickCount =0
	End
	
	Method New()
		enabled = 1
		visible=0
		
		objlist.AddLast(Self)
	End
	
	Method SetFlashColor(r:Int=255, g:Int=255, b:Int=255)
		''if target html5, consider using images for better performance
		flashcolor = 1
		fr = r
		fg = g
		fb = b
	End
	
	Function OnRender()
		drawcycle=1	
	End
	
	Function OnUpdate()
		''Notes: does not allow drag and click
		Local td:Int = TouchDown()
		Local tx:Int = TouchX()
		Local ty:Int = TouchY()
		Local anybutton:Int=0 ''disables drag and click
		
		For b = Eachin objlist
			''a click is a quick, one-time event

			If draglock Exit
			
			If Not td Then b.clickhold=0 Else If b.isClick Then b.clickhold = 1
			b.isClick =0
			
			''down is a holding process, can trigger a few cycles
			b.isDown=0
			If b.enabled And b.visible And td
				If tx>=b.x And tx<=(b.x+b.w)
					If ty>=b.y And ty<= (b.y+b.h)
						b.isDown =1
						If Not b.clickhold Then b.isClick = 1
						anybutton = 1
						b.showFlash=1
					Endif

				Endif
			Endif
			If (b.isClick)
				b.PlaySound()
				b.clickCount = b.clickCount+1
				
				If pressedbutton <> b
					clickCount =1
				Endif
				pressedbutton = b
			Endif
			If(drawcycle)
				b.visible=0
				If Not b.isDown Then b.showFlash=0
			Endif
		Next
		
		If Not anybutton And td
			draglock = 1
		Else
			draglock = 0
		Endif
		
		drawcycle =0
	End
	
	Method PlaySound()
		''fill in with SetSound()
	End
	
	Method SetSound()
		''fill in
	End
	
	Method Draw(img:Image, ix:Int, iy:Int, rot:Float=0, sx:Float=1.0, sy:Float=1.0)
		If Not img Return
		Local mx:Float[] = GetMatrix()
		drawcycle =1
		
		If flashcolor And (showFlash)
			'cr = GetColor()
			SetColor fr,fg,fb	
		Endif
		showFlash =0
		
		DrawImage img,ix,iy,rot,sx,sy
		
		x = ix+mx[4]-img.HandleX()
		y = iy+mx[5]-img.HandleY()
		If x<0 Then x=0
		If y<0 Then y=0
		
		If sx<>1.0 Or sy<>1.0
			w = img.Width * sx
			h = img.Height * sy
		Else
			w = img.Width
			h = img.Height	
		Endif
		visible = 1
		
		If flashcolor
			SetColor 255,255,255
		Endif
	End
	
	''Link is used to flash the button color of another image
	Method Link(img:Image, ix:Int, iy:Int, rot:Float=0, sx:Float=1.0, sy:Float=1.0)
		If Not img Return
		If flashcolor And isDown
			'cr = GetColor()
			SetColor fr,fg,fb	
		Endif

		
		DrawImage img,ix,iy,rot,sx,sy
		
		If flashcolor
			SetColor 255,255,255
		Endif

	End
	
End