Wildcard Fuzzy String Compare Globbing

Monkey Forums/Monkey Code/Wildcard Fuzzy String Compare Globbing

Pharmhaus

(Posted 2015) [#1]

This is a function I wrote to compare strings with wildcards.
It passes the tests from *here* and some others too so it's probably OK. If you find any bugs feel free to report and I'll fix them.

Strict

Function Main:Int()
	'DebugStop
	Print WildCard("g*ks", "geeks")'Yes
	Print WildCard("ge?ks*", "geeksforgeeks")'Yes
	Print WildCard("g*k", "gee")'No
	Print WildCard("*pqrs", "pqrst")'No
	Print WildCard("abc*bcd", "abcdhghgbcd")'Yes
	Print WildCard("abc*c?d", "abcd")'No
	Print WildCard("*c*d", "abcd")'Yes
	Print WildCard("*??c*d", "abccd")'Yes
	
	Print "----"
	
	Print WildCard("*_pX?.*", "Circle_hole_pX3.BMP")' yes
	Print WildCard("Circl*_pX?.*", "Circle_hole_pX3.BMP")' yes
	Print WildCard("y*n", "yessir") 'No
	Print WildCard("????????", "ABC") 'No
	Print WildCard("bl?h.*", "blah.jpg") 'yes
	
	Print "----"
	
	Print WildCard("a*bc", "abbc") 'yes
	Print WildCard("a*b", "a") 'no
	Print WildCard("a*?b", "axb") 'yes
	Print WildCard("a**b", "axb") 'yes
	Print WildCard("*", "") 'yes
	Print WildCard("*??c*d", "abcd")'Yes
	Print WildCard("*.dc", "hello.dc/peter.dc") 'yes
	Return 0
End


'Summary: Wildcard function for strings. use * for 0 or more symbols and ? for a single symbol
Function WildCard:Int(wildCard:String, myString:String, caseSensitive:Bool = True)
	Local wi:Int ' wildcard index
	Local si:Int ' string index
	Local ss:Int ' backtrack position when a mismatch occured
	
	If caseSensitive = False Then
		wildCard = wildCard.ToLower()
		myString = myString.ToLower()
	EndIf
	
	While wi < wildCard.Length And (si < myString.Length or myString.Length = 0)
		If wildCard[wi] = 42 Then' check for *
			ss = wi ' remember position to restore when we make a false decision
			
			While wi < wildCard.Length And wildCard[wi] = 42 ' eat multiple *
				wi += 1
			Wend
			
			If wi = wildCard.Length Then
				Return 1
			Else
				While wi < wildCard.Length And wildCard[wi] = 63 ' fix for *???
					wi += 1
					si += 1
				Wend
				
				If wi = wildCard.Length Then Exit
			EndIf
			
			While si < myString.Length And wildCard[wi] <> myString[si] ' normal *
				si += 1
			Wend
		ElseIf wildCard[wi] = 63 or wildCard[wi] = myString[si] ' eat normal ?
			wi += 1
			si += 1
			If si < myString.Length and wi >= wildCard.Length Then 'backtrack for *.txt etc.
				wi = ss
			EndIf
		Else
			If wi < wildCard.Length Then ' start again
				wi = ss ' when multiple choices can be made for a symbol we might pick the wrong one
			Else
				Return 0
			EndIf
		EndIf
	Wend
	
	If wi = wildCard.Length And si = myString.Length Then ' check if both string and wildcard are finished
		Return 1
	EndIf
	
	Return 0
End

Pharmhaus

(Posted 2015) [#2]

Still had some bugs.
I updated the above code.