Need Help Please...

Monkey Forums/Monkey Programming/Need Help Please...

Why0Why

(Posted 2012) [#1]

Hi All,

I have been experimenting with a Dungeon Raid style engine. This is a game where you match items by dragging your finger over a chain of similar items and you make the longest match possible. I am using a mouse on the HTML 5 version.

I have made a grid of 10x10 tiles and assigned random values between 1 and 4. The problem I am having is that I need it to only assign a match when the mouse is moved to the same value on an adjacent tile. I have been messing with this code for hours and changed lots of things around. It continues counting the values even if I drag over a different value. I have written debugging info at the bottom. I have experimented and commented out multiple things and tried different ways and I just can't get it to work.

Any help would be greatly appreciated. I feel it has to be something simple that I am missing, but I have wasted hours on this. Thanks in advance!

Import mojo


Class MyApp Extends App

Field GameGrid:Grid
field BoolToInt:int	

	Method OnCreate()
	
		SetUpdateRate( 60 )
		GameGrid = New Grid(10,10,32,32,50,50,0,0)
		
	End Method
	


	Method OnUpdate()
		
		
		if MouseDown(MOUSE_LEFT) Then
			GameGrid.CurrentCellValue=GameGrid.GetCurrentCell(MouseX,MouseY)
			if GameGrid.LastCellLocation<>GameGrid.Get1D(MouseX,MouseY,GameGrid.NumXCells) Then
				if GameGrid.LastCellValue=GameGrid.CurrentCellValue Then
					GameGrid.MatchList.AddLast(GameGrid.Get1D(MouseX,MouseY,GameGrid.NumXCells))
					GameGrid.Matching=True
					BoolToInt=True	
				EndIf
								
			Else
			'	GameGrid.Matching=False
			'	GameGrid.MatchList.Clear()
			'	BoolToInt=false
			EndIf
			GameGrid.LastCellValue=GameGrid.GetCurrentCell(MouseX,MouseY)
			GameGrid.LastCellLocation=GameGrid.Get1D(MouseX,MouseY,GameGrid.NumXCells)		
		EndIf
		
	End Method
	


	Method OnRender()
		' Cls 255, 255, 255
		If GameGrid.MatchComplete Then	
			GameGrid.Draw
			GameGrid.MatchComplete=False
		EndIf
			
		SetColor 0, 0, 255
		DrawText("The cell value is " + GameGrid.CurrentCellValue, 400,400,0,0)
		DrawText("MouseX="+MouseX,400,420,0,0)
		DrawText("MouseY="+MouseY,400,430,0,0)
		DrawText("1D Value="+GameGrid.Get1D(MouseX,MouseY,GameGrid.NumXCells),400,440,0,0)
		DrawText("Number Of Matches="+GameGrid.MatchList.Count,400,410,0,0)
		DrawText("Matching="+BoolToInt ,400,450,0,0)
	
	End Method
	

End Class

Class Grid
	Field NumXCells:Int
	Field NumYCells:Int
	Field CellWidth:Int
	Field CellHeight:Int
	Field xPad:Int
	Field yPad:Int
	Field StartX:Int
	Field StartY:Int
	Field EndX:Int
	Field EndY:Int
	Field CurrentCellValue:Int=100
	Field Contents:Int[][]
	Field MatchList:IntList
	Field LastCellLocation:Int=0
	Field LastCellValue:Int
	Field Matching:Bool=False
	Field MatchComplete:Bool=True
	
	Method New(xcells:Int,ycells:Int,cellw:Int,cellh:Int,x:Int,y:Int,padx:Int,pady:Int)
		Local i:Int
		Local j:Int
		Seed=Millisecs()
	
		NumXCells=xcells
		NumYCells=ycells
		CellWidth=cellw
		CellHeight=cellh
		StartX=x
		StartY=y
		xPad=padx
		yPad=pady
		EndX=StartX+(NumXCells*CellWidth)+(xPad*NumXCells)
		EndY=StartY+(NumYCells*CellHeight)+(yPad*NumYCells)
		Contents=AllocateArray(NumXCells+1,NumYCells+1)
		
		' Assign a random value from 1-4 to each cell for matching purposes
		For i = 1 to NumXCells
			For j  = 1 to NumYCells
				Contents[i][j]=Rnd(1,4)	
			Next
		Next
		MatchList = New IntList
	End
	
	Method Draw()
		Local x:Int
		Local y:Int
	
		SetColor 0, 0, 255
		DrawLine(StartX,StartY,EndX,StartY)
		DrawLine(StartX,StartY,StartX,EndY)
		DrawLine(EndX,StartY,EndX,EndX)
		DrawLine(StartX,EndY,EndX,EndY)
		
		For x = 1 to NumXCells
			For y  = 1 to NumYCells
				SetColor 0, 0, 0
				DrawLine(StartX,(y*CellHeight)+StartY,EndX,(y*CellHeight)+StartY)
				SetColor 255,255,255	
				DrawText(Contents[x][y],(StartX+(x*CellWidth)-CellWidth/2),(StartY+(y*CellHeight)-CellHeight/2),.5,.5)
			Next
			SetColor 0, 0, 255
			DrawLine((x*CellWidth)+StartX,StartY,(x*CellWidth)+StartX,EndY)
		Next
		
	End
	
	' Returns the value stored at the mouse position
	Method GetCurrentCell(x:Int,y:Int)
		Local currentX:Int
		Local currentY:Int
		
		currentX=((x-StartX)/CellWidth)+1
		currentY=((y-StartY)/CellHeight)+1
		
		' Check to be sure the mouse is over the Game Grid
		if currentX >0 And currentX<=NumXCells And currentY>0 And currentY<=NumYCells Then
			self.CurrentCellValue=Contents[currentX][currentY]
		Else
			self.CurrentCellValue=0
		EndIf
		
	End
	
	' Returns array position in 1D for easy storing in an intlist
	Method Get1D:Int(x:Int,y:Int,numxcells:Int)
		Local currentX:Int
		Local currentY:Int
		
		currentX=((x-StartX)/CellWidth)+1
		currentY=((y-StartY)/CellHeight)+1
	
		Return ((currentY*Self.NumXCells)+currentX)-numxcells
	End
	
	' Converts MouseX to the GameGrid's X Value
	Method aX(x:Int)
		Local currentX:Int
		
		currentX=((x-StartX)/CellWidth)+1
		Return currentX
		
	End
	
	' Converts MouseY to the GameGrid's Y Value
	Method aY(y:Int)
		Local currentY:Int
		
		currentY=((y-StartY)/CellHeight)+1
		Return currentY
		
	End
	
End

' Function to easily initialize a 2D array since Monkey uses an array of 1D arrays instead of traditional multi-dimensional arrays. From muddy_shoes on the Monkey Forums
Function AllocateArray:Int[][]( i:Int, j:Int)
    Local arr:Int[][] = New Int[i][]
	Local ind:Int
    For ind = 0 Until i
        arr[ind] = New Int[j]
    Next
    Return arr		
End


Function Main()

	New MyApp()
	
End Function

muddy_shoes

(Posted 2012) [#2]

It looks like you've hacked around with the code so much that you've kind of lost sight of things. It happens. The main issue is that you seem to think that GameGrid.GetCurrentCell() returns a value. It doesn't. It sets the internal CurrentCellValue field.

Try replacing your OnUpdate with this:

Method OnUpdate()

    if MouseDown(MOUSE_LEFT) Then
        'GameGrid.CurrentCellValue=
        GameGrid.GetCurrentCell(MouseX,MouseY)
        
        if GameGrid.LastCellLocation <> GameGrid.Get1D(MouseX, MouseY, GameGrid.NumXCells) Then
            
            if GameGrid.LastCellValue = GameGrid.CurrentCellValue Then
                GameGrid.MatchList.AddLast( GameGrid.Get1D(MouseX, MouseY, GameGrid.NumXCells) )
                GameGrid.Matching=True
                BoolToInt=True
            Else
                GameGrid.Matching=False
                GameGrid.MatchList.Clear()
                BoolToInt=false
            End
        EndIf
        GameGrid.LastCellValue = GameGrid.CurrentCellValue '.GetCurrentCell(MouseX,MouseY)
        GameGrid.LastCellLocation = GameGrid.Get1D(MouseX, MouseY, GameGrid.NumXCells)		
    EndIf

End Method

I'd then recommend taking a break before coming back and looking over the code again and doing a bit of a clean up.

AdamRedwoods

(Posted 2012) [#3]

It looks like you've hacked around with the code so much that you've kind of lost sight of things. It happens.

coding "tilt"

Why0Why

(Posted 2012) [#4]

Thanks very much! It was driving me crazy. I am taking a break until tomorrow :)