Loading screen with diddy framework

Monkey Forums/Monkey Programming/Loading screen with diddy framework

hobo	(Posted 2012) [#1]

Hello all,

Trying to use the diddy framework to display a loading screen and then load all my assets before moving onto my titlescreen.

I thought the idea would be to straight away display the loading image in Render after loading the image in OnCreate

Then activate loading the remaining assets in OnUpdate.

Once all are loaded I can then move onto the titlescreen.

However what seems to happen is by using OnUpdate/OnRender in the MyGame class I can't seem to move onto titlescreen and according to debug seems to sit and keep running OnUpdate/OnRender in MyGame.

Probably something obvious I'm missing but any help would be appreciated. Or if anyone has an example of a loading method using the diddy screen framework?

Some Pseudocode of what i'm doing before moving onto titlescreen:


Class MyGame Extends DiddyApp
	
        Field fGfxLoadingScreen:GameImage
	
        Method OnCreate:Int()
		
		Super.OnCreate()
		SetScreenSize(640, 480)
		SetUpdateRate UPDATE_RATE
		TDeltaTimer.init()
		
		images.Load("loadingscreen.png", "", False)
		fGfxLoadingScreen = game.images.Find("loadingscreen")
				
		Return 0
	End

        Method OnRender() 
		fGfxLoadingScreen.Draw(0, 0)
		Return 0
        End

        Method OnUpdate()
		
               Select(loadingstate)
                   case 0

                        LoadSounds()
		        LoadImages()
			
                        gameScreen = New GameScreen()
		        titleScreen = New TitleScreen()
                        loadingstate = 1
                   case 1               
                        titleScreen.PreStart()	
              End
  	End

        Method LoadSounds:Void()
           'Load My Sounds Here
	End
	
	Method LoadImages:Void()
	    'Load My Images Here

	End

	
End

Amon	(Posted 2012) [#2]


Strict

Import diddy

Function Main:Int()
	game = new MyGame()
	Return 0
End Function

Global logoScreen:LogoScreen
Global titleScreen:TitleScreen
Global gameScreen:GameScreen

Class MyGame extends DiddyApp
	Method OnCreate:Int()
		Super.OnCreate()
		LoadImages()
		logoScreen = New LogoScreen
		titleScreen = New TitleScreen
		gameScreen = New GameScreen
		game.Start(logoScreen)
		return 0
	End
	
	'***********************
	'* Load Images
	'***********************
	Method LoadImages:Void()
		' create tmpImage for animations
		Local tmpImage:Image
		
		images.Load("your_logo_.png", "Mlogo", True, False)
	End
End

Class LogoScreen Extends Screen
	Field Mlogo:GameImage
	Field timer:Int
	Field fade:Int
	Method New()
		name = "Logo"
	End
	
	Method Start:Void()
		timer = Millisecs()
		fade = 0
	End
	
	Method Render:Void()
		Cls
		If Millisecs() <= timer + 3000
			Mlogo.Draw(SCREEN_WIDTH2, SCREEN_HEIGHT2, 0, 0.5, 0.5, 0)
		Else
			fade = 1
		EndIf
	End
	
	Method Update:Void()
		If fade = 1
			' triggers a fade out and configures the gameScreen so that it will auto fade in
			FadeToScreen(titleScreen)
		End
	End
End

Class TitleScreen Extends Screen
	Method New()
		name = "Title"
	End
	
	Method Start:Void()
		' game.Start forces an autofade, so we don't need to manually fade in anymore
	End
	
	Method Render:Void()
		Cls
		DrawText "TITLE SCREEN!", SCREEN_WIDTH2, SCREEN_HEIGHT2, 0.5, 0.5
		DrawText "Click to Play!", SCREEN_WIDTH2, SCREEN_HEIGHT2 + 20, 0.5, 0.5
		DrawText "Escape to Quit!", SCREEN_WIDTH2, SCREEN_HEIGHT2 + 40, 0.5, 0.5
	End
	
	Method Update:Void()
		If MouseHit(MOUSE_LEFT)
			' triggers a fade out and configures the gameScreen so that it will auto fade in
			FadeToScreen(gameScreen)
		End
		
		If KeyHit(KEY_ESCAPE)
			' fading to Null is the same as fading to game.exitScreen (which exits the game)
			FadeToScreen(Null)
		End
	End
End

Class GameScreen Extends Screen
	
	Method New()
		name = "Game"
	End
	
	Method Start:Void()

	End
	
	Method Render:Void()
		Cls

		FPSCounter.Draw(0,0)
	End
	
	Method Update:Void()
		If KeyHit(KEY_ESCAPE)
			FadeToScreen(titleScreen)
		End
	End
	
	Method PostFadeOut:Void()
		Super.PostFadeOut()
	End
End

hobo	(Posted 2012) [#3]

Thanks Amon, that's a massive help.