Mathy type gravity angle thingy hahah topic :)

Monkey Forums/Monkey Programming/Mathy type gravity angle thingy hahah topic :)

Paul - Taiphoz

(Posted 2015) [#1]

Not looked at any code for a while and some of my own code looks a little alien to me so please bare with me while I warm my brain up.

Ok so I have asteroids when travel along a given vector at a random but set speed, when the object is free moving it will continue on its course until hit by something or it exits the screen and I wrap it around and add a little randomness to its new vector.

I have gravity in my game and the way I have opted to deal with it is that each time an object feels the pull of gravity I alter its current vector to turn it a little more toward the gravity well or planet which works nice, I do this gravity pull only once every 100 ms or there abouts.

What I am now trying to do is when when I spawn some asteroids at their random x,y is to turn their gravity on, set their speed and then calculate the amount per 100 ms that I need to turn/gravity the object so that it orbits the planet at px,py

Having a little trouble calculating this tho so before I give us and move onto something else I thought I would see if anyone here has any ideas.

abakobo

(Posted 2015) [#2]

What math are you using? Formulas would be needed to understand your approach.

To have realistic orbits you have to use Newton's mecanics:

F=(G*Ma*Mb)/(D*D) and F=M.A

F is the intensity of the force (Newton)
G is the Gravity constant (optional for a game, but it's easier to work with "real" values then scale the image, it may need some change because we pull each xxms)
Ma is the mass of your asteroid a (Kg)
Mb is the mass of your asteroid b (the planet!) (Kg)
D is the distance between the center of the two asteoids (meter)
A is acceleration (meter/sec*sec)

The rotation of asteroids arenot gravity dependent but you can use the distance vector to make it turn "like the moon" or add the rotating speed if you want full simulation.

here's a code with my gravity example but the velocity for the orbit of rnd satelite is not yet calculated, I don't remeber the formula but will check... Do you want circular orbit or any orbits?

Import mojo

Class Test Extends App

		
	Field Xast#,Yast#,Xplan#,Yplan#,ScalePhys#,DistVectX#,DistVectY#,Grav#
	Field SpeedXast#,SpeedYast#,SpeedXplan#,SpeedYplan#,Distance#
	Field MassA#,MassB#,Force#

	
	Method OnCreate()
	
	SetUpdateRate 60
	
	Xast=320
	Yast=150
	Xplan=320
	Yplan=250
	
	DistVectX=0
	DistVectY=0
	
	'ScalePhys=1
	
	'initial speeds of ast(eroid) and plan(et)
	SpeedXast=3.2
	SpeedYast=0
	
	SpeedXplan=-0.015  'because i've not "fixed the planet"
	SpeedYplan=0.001
	
	'Their Mass
	
	MassA=10000000
	MassB=1569325056
	
	
	'in reality Grav is 6.67 e-11 so I tweaked here a bit. I should have used PhysScale and for example the mass of earth and moon
	Grav=0.0000007

		
		
	End
	
	
	
	Method OnUpdate()
	
	'Calculate the distance
	
	DistVectX=Xast-Xplan
	DistVectY=Yast-Yplan
	Distance=Sqrt( DistVectX*DistVectX + DistVectY*DistVectY )
	
	' now Normalize Vect Dist so it can be used for any purpose
	
	DistVectX=DistVectX/Distance
	DistVectY=DistVectY/Distance
	
	' calculate Force F=(G*Ma*Mb)/(D*D)  Newton Law  ----------------------------------------
	
	Force=(Grav*MassA*MassB)/(Distance*Distance)
	
	'Acceleration>Speed  F=M*A so A=F/M (and speed=speed+accel.)  Newton Law and Newton-Raphson numerical approach at 60fps-------------------------------
	
	SpeedXast-=DistVectX*Force/MassA
	SpeedYast-=DistVectY*Force/MassA
	SpeedXplan+=DistVectX*Force/MassB
	SpeedYplan+=DistVectY*Force/MassB
	
	'Speed>Position  

        Xast+=SpeedXast
	Yast+=SpeedYast
	Xplan+=SpeedXplan
	Yplan+=SpeedYplan


	'	If KeyHit( KEY_LMB ) ' launch rnd astro

	'	Endif

	End

	Method OnRender()
		
		Cls 45,0,85
		SetColor 0,128,255
		DrawCircle Xast,Yast,9
		SetColor 0,128,0
		DrawCircle Xplan,Yplan,42
		
	End

End

Function Main()

	New Test

End

Paul - Taiphoz

(Posted 2015) [#3]

I was trying to avoid fully calculating the gravity like that, what I am trying to solve in the most efficient way possible is Angle of change A from the vectors current angle so that I know how much to turn the object so that it maintains a circle around the central point, all my objects motions are dictated by the angle of its vector which then sets it's actual x and y velocities based on speed.

I might be trying to over simplify or possibly make life hard on myself lol ...

muddy_shoes

(Posted 2015) [#4]

If you literally just want the asteroids to go in a circular orbit then you can just set the velocity vector to be perpendicular to the line between the asteroid and the thing it's orbiting. Alternatively, if you want the motion to be stable across long periods and varying framerates etc., you could just treat speed*deltatime as an orbital arclength and calculate the new position exactly.

abakobo

(Posted 2015) [#5]

Yep if you just want circular orbits and you don't want it to interact with other gravity sensitive asteroids than your planet you don't really need physics. Just make it turn around when gravity is on and don't bother with forces...

Paul - Taiphoz

(Posted 2015) [#6]

Muddy I fkn love you :), I was already calculating that once on spawn it never once occurred to me to just reset the angle over time, that just removed 20 lines of code and replaced it with a new orbiting boolean and a single line to just reset the objects angle thanks dude.

abakobo

(Posted 2015) [#7]

Though you're not willing to use physics, i give the complement to the code in order to get circular orbit.

the speed for circular orbit is Sqrt(G*Mplanet/Distance) and is not dependent to the satelite Mass..

Here's the code. You can press Spacebar to launch a rnd satelite at circular orbit!

Import mojo

Class Test Extends App

		
	Field Xast#,Yast#,Xplan#,Yplan#,ScalePhys#,DistVectX#,DistVectY#,Grav#
	Field SpeedXast#,SpeedYast#,SpeedXplan#,SpeedYplan#,Distance#
	Field MassA#,MassB#,Force#

	
	Method OnCreate()
	
	SetUpdateRate 60
	
	Xast=320
	Yast=30
	Xplan=320
	Yplan=240
	
	DistVectX=0
	DistVectY=0
	
	'ScalePhys=1
	
	
	'Their Mass
	
	MassA=100
	MassB=1569312312
	
	
	'in reality Grav is 6.67 e-11 so I tweaked here a bit. I should have used PhysScale and for example the mass of earth and moon
	Grav=0.0000007
	
	'initial speeds of ast(eroid) and plan(et)
	
	SpeedXast=Sqrt(Grav*MassB/(Yplan-Yast)) 'Formula to get CIRCULAR ORBIT: v*v=G*Mplanet/Dist AND the vector must be parallel to the surface of the planet (perpendicular to the distance vector)
	SpeedYast=0
	
	SpeedXplan=0 
	SpeedYplan=0
	SpeedXast=Sqrt(Grav*MassB/(Yplan-Yast))
		
	End
	
	
	
	Method OnUpdate()
	
	'Calculate the distance
	
	DistVectX=Xast-Xplan
	DistVectY=Yast-Yplan
	Distance=Sqrt( DistVectX*DistVectX + DistVectY*DistVectY )
	
	' now Normalize Vect Dist so it can be used for any purpose
	
	DistVectX=DistVectX/Distance
	DistVectY=DistVectY/Distance
	
	' calculate Force F=(G*Ma*Mb)/(D*D)  Newton Law  ----------------------------------------
	
	Force=(Grav*MassA*MassB)/(Distance*Distance)
	
	'Acceleration>Speed  F=M*A so A=F/M (and speed=speed+accel.)  Newton Law and Newton-Raphson numerical approach -------------------------------
	
	SpeedXast-=DistVectX*Force/MassA
	SpeedYast-=DistVectY*Force/MassA
	SpeedXplan+=DistVectX*Force/MassB
	SpeedYplan+=DistVectY*Force/MassB
	
	'Speed>Position  

    Xast+=SpeedXast
	Yast+=SpeedYast
	Xplan+=SpeedXplan
	Yplan+=SpeedYplan


	If KeyHit( KEY_SPACE ) ' launch rnd astro
	
	
		Xast=320
		Yast=10+Rnd(180)
		Xplan=320
		Yplan=240		

		'Their Mass
		MassB=100000000+Rnd(100000000)
		
		Print("Mass of the planet")
		Print(MassB)
		
		'initial speeds of ast(eroid) and plan(et)
	
		SpeedXast=Sqrt(Grav*MassB/(Yplan-Yast)) 'Formula to get CIRCULAR ORBIT: v*v=G*Mplanet/Dist AND the vector must be parallel to the surface of the planet (perpendicular to the distance vector)
		SpeedYast=0
		SpeedXplan=0 
		SpeedYplan=0
		
		Print("Speed of astro")
		Print(SpeedXast)
	

	Endif

	End

	Method OnRender()
		
		Cls 45,0,85
		SetColor 0,128,255
		DrawCircle Xast,Yast,9
		SetColor 0,128,0
		DrawCircle Xplan,Yplan,42
	End

End

Function Main()

	New Test

End

Why0Why

(Posted 2015) [#8]

Hey abakobo, just wanted to say thanks for chiming in and I appreciate the example. It is great to have samples like that on the board!

Paul - Taiphoz

(Posted 2015) [#9]

Yeah Examples are amazing for some of us, its not that I am un willing to use real physics its more like its not needed and the rest of the code is'nt really setup to work that way.

abakobo

(Posted 2015) [#10]

more gravity fun for people who like simple BASIC but effective code example... (notice that function or class is not used (except for mojo and "Function Main" reqs...)

press space to add (several) satelite(s)!

;P

Import mojo
'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Class Test Extends App

		
	Field ScalePhys#,DistVectX#,DistVectY#,Grav#  ' Some of these should be Locals
	Field SpeedXast#,SpeedYast#,Distance#         '
	Field Force#                                  '
	Field nb_ast:Int
	
	Field Mass:Float[50]
	Field Xpos:Float[50]
	Field Ypos:Float[50]
	Field XposT:Float[50]
	Field YposT:Float[50]
	Field Xspd:Float[50]
	Field Yspd:Float[50]
	Field Xforce:Float[50]
	Field Yforce:Float[50]
	
	'------------------------------------------------------------------------------------------------
	Method OnCreate()
	
		SetUpdateRate 60
	
		'nb of interacting astros...
		nb_ast=1
		
		'in reality Grav is 6.67 e-11 so I tweaked here a bit. I should have used PhysScale and for example the mass of earth and moon
		Grav=0.0000007
	
		Xpos[1]=240
		Ypos[1]=240

		'The Mass of the planet
		Mass[1]=1500000000
	
		'initial speed of planet
		Xspd[1]=0
		Yspd[1]=0		
	End
	'----------------------------------------------------------------------------------------------------
	Method OnUpdate()
	
	If KeyHit( KEY_SPACE ) ' launch a rnd astro
	
		nb_ast+=1 'add one astro on the count
	
		'Initial position of satelite (same X than planet to easily get a parallel vector to the planet's surface (with a speed like (x,0))
		Xpos[nb_ast]=Xpos[1]
		Ypos[nb_ast]=5+Rnd(140)

		'The Mass
		Mass[nb_ast]=100+Rnd(10000000)
		
		'initial speed
		Xspd[nb_ast]=Sqrt(Grav*Mass[1]/(Ypos[1]-Ypos[nb_ast])) 'Formula to get CIRCULAR ORBIT: v*v=G*Mplanet/Dist AND the vector must be parallel to the surface of the planet (perpendicular to the distance vector)
		Yspd[nb_ast]=0  'see initial position	
	Endif
	
	Local i:Int
	Local j:Int
	
	For i=1 To nb_ast 'restet forces cause not locals ;)
	  Xforce[i]=0
	  Yforce[i]=0
	Next i

	For i=1 To nb_ast
	For j=1 To nb_ast
 
 
 	' This loop calculates all the forces between all stros and add them to each astro's Force vector
	If i<>j 'Could be optimized because it calculates 2 times the same thing...
 
		'Calculate the distance
	
		DistVectX=Xpos[i]-Xpos[j]
		DistVectY=Ypos[i]-Ypos[j]
		Distance=Sqrt( DistVectX*DistVectX + DistVectY*DistVectY )
	
		' now Normalize Vect Dist so it can be used for any purpose
	
		DistVectX=DistVectX/Distance
		DistVectY=DistVectY/Distance
	
		' calculate Force F=(G*Ma*Mb)/(D*D)  (Newton Law) 
	
		Force=(Grav*Mass[i]*Mass[j])/(Distance*Distance)
	
		Xforce[i]+=Force*DistVectX
		Yforce[i]+=Force*DistVectY
	
	Endif
	
	Next j	
	Next i

	'This loop moves the astros using the calculated Forces
	For i=1 To nb_ast 'From 2 if u don't want the planet to move on the screen

		
		'Acceleration>Speed  F=M*A so A=F/M (and speed=speed+accel.)  Newton Law and Newton-Raphson numerical method (dSpeed=accel and dPos=Speed differential equations)

		Xspd[i]-=Xforce[i]/Mass[i]
		Yspd[i]-=Yforce[i]/Mass[i]
	

		'Speed>Position     (Newton-Raphson num. method  (1 step=1 sec so it goes 60 faster (Grav is not good so it doesn't mean anything actualy...))
	
	    Xpos[i]+=Xspd[i]
		Ypos[i]+=Yspd[i]
	
	Next i

	End 'OnUpdate
	'---------------------------------------------------------------------------------------------
	Method OnRender()
		
		Local i:Int
		
		Cls 
		
		For i=1 To nb_ast
			SetColor 5+i*22,90+i*7,190+i*5
			DrawCircle Xpos[i],Ypos[i],23*Sqrt(Sqrt(Mass[i]))/Sqrt(Sqrt(1500000000))'Sqrt's to draw circle proportionnal to the mass with adapted scale (should be cubic root as it is volume but...)
		Next i
	End

End
'+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Function Main()

	New Test

End

k.o.g.

(Posted 2015) [#11]

@abakobo

is there any chance to contact you? i've done something similar, but have one question? please

abakobo

(Posted 2015) [#12]

Feel free to ask the question here or on a new topic.... i'd rather like to answer publicly so every one can get info's.. (as it is the philosophy of formus!)
If you want it to keep secret!? i've sent you an email...

ako

abakobo

(Posted 2015) [#13]

The email adress of your profile failed...

golomp

(Posted 2015) [#14]

Hi Paul,

Thank you a lot for the work you have done.

Golomp