os module to save to user's directory

Import mojo
Import os
Import brl


Class MyApp Extends App
	Field userDir:String
	Field fileSavePath:String
	Field configFilePath:String
	Field theInt:Int
	
	
	Method OnCreate()
	
		SetUpdateRate 30
		
		'USER DIRECTORY FOR SAVE FILES
		
		'-----------------------
		
		'Get user data path
		#If TARGET="glfw" Then
			
		'Construct this app's data paths
			If HostOS() = "macos"
				userDir = GetEnv("HOME")
				fileSavePath = userDir + "/Library/Application Support/MyFileTestApp"
				configFilePath = fileSavePath + "/test.dat"
			Elseif HostOS() = "winnt"
				userDir = GetEnv("APPDATA")
				fileSavePath = userDir + "\MyFileTestApp"
				configFilePath = fileSavePath + "\test.dat"
			Endif
			Print "filesave directory is :" + fileSavePath	
			Print "config file path is :" + configFilePath
			
		'See if directory exists, if not, create it
		'os.monkey has no DirExists function, so instead check for existence of default file
		'if default file not there, create directory and create default file
			Local file:=FileStream.Open(configFilePath,"r") 
			If Not file
				' Create New directory
				CreateDir(fileSavePath)	
				' Create blank file
				Local nfile:=FileStream.Open(configFilePath,"w")
				nfile.WriteInt 0
				nfile.Close
			Else file.Close
			Endif
		#Endif
		
    End
		
	Method OnUpdate()
	
			If KeyHit(KEY_LEFT) theInt -=1 
			
			If KeyHit(KEY_RIGHT) theInt +=1			
				
			If KeyHit(KEY_L)
				Print "attempting to open file"
				Local file:=FileStream.Open(configFilePath,"r")
				If Not file Then Return 
				theInt = file.ReadInt()
				Print "First int in file is :" + theInt
				file.Close	
			Endif
			
			If KeyHit(KEY_S)
				Print "attempting to save to file"
				Local file:=FileStream.Open(configFilePath,"w")
				If Not file Then Return 
				file.Seek(0)
				file.WriteInt theInt
				file.Close	
			Endif
	End
	
	Method OnRender()
	      Cls
	      DrawText "Left arrow to decreases theInt, Right arrow to increase",0,12
	      DrawText "L To load theInt's value, S to save it",0,24
		  DrawText "theInt = "+ theInt,0,36
	End

End		

Function Main()

	New MyApp
	
End