Load/Save User Files in HTML Target?

Strict

Import mojo

#If TARGET = "html5" Then
	Import dom.dom
	
	
	Extern
		Function log:Void(e:Event) = "window.console.log"
		Function log:Void(f:FileList) = "window.console.log"
		Function log:Void(f:File) = "window.console.log"
		
		Class File
			Field lastModified:int
			Field lastModifiedDate:String
			Field name:String
			Field size:int
			Field fileName:String
			Field fileSize:Int
			Field type:string
		End class
		
		Class FileList Extends DOMObject
			Field length:int
			Method item:File( index:int)
		End class
		
		Class customHTMLInputElement Extends HTMLInputElement = "HTMLInputElement"
			Field files:FileList
		End Class
		
	Public
	
		Class Listener Extends EventListener
			Method handleEvent:Int(e:Event)
				Local target:customHTMLInputElement = customHTMLInputElement(e.target)
				Select e.type
					Case "change"
						Local f:File = target.files.item(0)
						Print "new file: "+f.name+" - "+f.size+" bytes"
						
				End Select
				Return 1
			End Method
		End Class
		
		Function Init:Void()
		
			Local input:HTMLInputElement = HTMLInputElement(document.createElement("input"))
			input.type = "file"

			Local div:HTMLDivElement = HTMLDivElement(Element(document.getElementsByTagName("body").item(0)).getElementsByTagName("div").item(0))
			div.appendChild(input)
			
			Local listener:EventListener = New Listener()
			input.addEventListener("change",listener)
		End Function
#End If


Class FileApp Extends App
	Method OnCreate:Int()
		SetUpdateRate(30)
		
		Init()
		Return 0
	End Method
	
	
	Method OnUpdate:Int()
	
		Return 0
	End Method
	
	
	Method OnRender:Int()
		Cls(0,0,0)
		Return 0
	End method
End Class

Function Main:Int()
	New FileApp()
	Return 0
End function